Topic: How do you deal with the "return" and "break,continue,goto" problems?

[highflyingbird]

Sometimes we need flow of program can break in a special point,or change the direction.for other language,we can use "return" or "break" or "goto"(it's not always bad thing,it's useful too),but for LISP, it's a little difficult.I must use a lot of cond,if ,or some other statements ,it makes program hard to understand and complicated.
How do you deal with them?Could you give your suggestions? Thanks very much.

[roy_043]

You probably know about the while-loop:

Code: [Select]

(defun c:LoopTest ( / answer)
  (while (/= answer "Yes")
    (initget "Yes No")
    (setq answer (getkword "\nExit this while loop? [Yes/No] <No>: "))
  )
  (princ)
)

[dgorsman]

Thats why for anything more complex than couple of lines I do a program flow outline first, then write up the comments in the LSP file, then code around the comments.  A lot of LSP is self-documenting (well, sort-of...) but its still a lot easier to add comments now than trying to figure it out again a year later.

Instead of massively nested (if...) and (cond...) structures, make separate functions out of the enclosed contents.  This improves readability and consistency through code re-use.  When stepping through code to find problems you can simply step over the function call once you have determined its working properly.

[JohnK]

I develop pseudo code along with any complicated program i create.

Example (cut and pasted from one of the files i was maintaining at the moment):

Code: [Select]

<snip>
                          find layer
                                  locate layer in drawing
                                  { switch
                                        case: if layer !exist
                                              {
                                                      find layer file
                                                              parse layer file
                                                              create layer
                                              }
                                        case: else
                                              {
                                                      { switch
                                                        case: layer locked { unlock }
                                                      }

                                                      set layer current
                                              }
                                  }
<snip>


[TimSpangler]

Well commented code.......

[highflyingbird]

Thanks for all the advice,thanks very much.
I saw a code below:

Code: [Select]

(defun Fsxm-Apply ($Sym $Lst / $$ return $rt)
  (defun Return (var) (setq Return nil) (setq $$ var) (exit))
  (setq $rt (vl-catch-all-apply $Sym $Lst))
  (if Return
    $rt
    $$
  )
)It can deal with "return",looks very good.

[Kerry]

What does that code do 'bird ??

The Return function is never called, so what is it doing ??

[highflyingbird]

I show you an example:

Code: [Select]

(defun c:test()
  (fsxm-apply 'func '((1 2 3 4 7 9 5 6 7 8 9)))
)
;;
(defun func (lst / i)
  (setq i 0)
  (foreach n lst
    (if (= n 5)
      (return  i)
    )
    (setq i (1+ i))
  )
  nil
)you maybe notice that ,the last result returns the right position of an element in a list.
 
Generally speaking ,"foreach " means every element,but in this case ,it's broken by  (return ....), and it will not exit the program,just returns from this function and returns a value.

[gile]

Hi,

By my side, I often use a 'boolean variable' in a while loop :

Code: [Select]

(setq lst '(1 2 3 4 7 9 5 6 7 8 9))

(setq loop T
      len  (length lst)
      n    0
)
(while (and (< n len) loop)
  (if (= (nth n lst) 5)
    (setq loop nil)
    (setq n (1+ n))
  )
)

[Kerry]

I show you an example:
< .. >

Thanks, seeing all the code makes a difference

[gile]

Appologies, my exemple is a "break" like statement.

[roy_043]

@ highflybird: That's very clever! Pity it will only work with the apply-construction.

[highflyingbird]

Hi,

By my side, I often use a 'boolean variable' in a while loop :
....

You are right. I often use this way.  but sometimes, we wish we can return a value from any place,any time,like C++,so  if  there are a lot of statements after "while",this way isn't convinient.
Use  (exit) can make the sentences more simple,more readable.

[highflyingbird]

@ highflybird: That's very clever! Pity it will only work with the apply-construction.

yes,a little pity.