Topic: Enum Symbol Arithmetic Possible?

[Lee Mac]

Just a quick one,

I was trying to create a quick toggle, using this kind of arrangement:

Code: [Select]

(vlax-put-property obj (1- (abs (vlax-get-property obj))))

But even using such functions as "read" or "eval" in this arrangement, I cannot get the symbol (such as :vlax-true) into its enum form.

Can this be done?

[CAB]

So you are stuck with this?

Code: [Select]

(vlax-put-property obj (if (= (vlax-get-property obj) :vlax-true):vlax-false :vlax-true))

[ronjonp]

or maybe something like

Code: [Select]

(vlax-put-property obj (if (zerop (vlax-get-property obj))-1 0))
no acad available to test on so just wingin it

[Lee Mac]

So you are stuck with this?

Code: [Select]

(vlax-put-property obj (if (= (vlax-get-property obj) :vlax-true):vlax-false :vlax-true))

Exactly, but you know me - I like the elegant solutions

[Lee Mac]

or maybe something like

Code: [Select]

(vlax-put-property obj (if (zerop (vlax-get-property obj))-1 0))
no acad available to test on so just wingin it

Sorry Ron

Code: [Select]

; error: bad argument type: numberp: :vlax-false


[ronjonp]

or maybe something like

Code: [Select]

(vlax-put-property obj (if (zerop (vlax-get-property obj))-1 0))
no acad available to test on so just wingin it

Sorry Ron

Code: [Select]

; error: bad argument type: numberp: :vlax-false


DOH 

[MP]

for academia:

Code: [Select]

(progn

    (setq layer
        (vla-item   
            (vla-get-layers
                (vla-get-activedocument
                    (vlax-get-acad-object)
                )
            )
            "0"
        )
    )
   
    (setq property 'lock)
   
    (vlax-put layer property
        (if (zerop (vlax-get layer property))
           -1
            0
        )   
    )
   
)
however, in practice it's of little value imo

[Lee Mac]

Gotcha - cheers Michael 

[Lee Mac]

For those interested in how I used it:

Code: [Select]

(defun c:dtog nil
  (vl-load-com)

  (vla-StartUndoMark
    (cond (*doc*) ((setq *doc* (vla-get-ActiveDocument
                                 (vlax-get-acad-object))))))

  (vlax-for obj (vla-get-Block (vla-get-ActiveLayout *doc*))
                 
    (if (vl-position
          (vla-get-ObjectName obj)
          '("AcDbRotatedDimension" "AcDb2LineAngularDimension"
            "AcDbAlignedDimension" "AcDb3PointAngularDimension" "AcDbArcDimension"))
     
      (mapcar
        (function
          (lambda (x)
            (vlax-put obj x (1- (abs (vlax-get obj x))))))
       
        '(ExtLine1Suppress ExtLine2Suppress))))

  (vla-EndUndoMark *doc*)
  (princ))


[JohnK]

NOT!
I'm positive, that joke will be funny when you get to the code part. And if it isnt, blame the 90's.

A little obscure but seeing as its just for academia.

Using MP's example.

Code: [Select]

(progn

    (setq layer
        (vla-item  
            (vla-get-layers
                (vla-get-activedocument
                    (vlax-get-acad-object)
                )
            )
            "0"
        )
    )
    
    (setq property 'lock)
    
    (vlax-put layer property
     
;;;        (if (zerop (vlax-get layer property))
;;;           -1
;;;            0
;;;        )
  (~ (vlax-get layer property))
    )
)

[Lee Mac]

Haha! Very nice Se7en..!