Topic: Attribute values not showing

[WPerciful]

I used entmod and entupd to modify the attribute values in our titleblock.  It modifyed the values but you can't see them in the block.  If you double click on the block to edit the values they are all there.

Why does it have the values but not show them?

[Tharwat]

Can you post your codes or just the part that is related to attributed values ?

[WPerciful]

Code: [Select]

(defun updateborder ( ent passed / e d o n )
(setq e  ent
d (entget e)
o (assoc 1 d)
n (cons 1 passed)
d  (subst n o d)
)
(entmod d)
(entupd e)
)

[Kerry]

Just a guess
Is the ent the border insert or the attribute

add something like
(print (cdr (assoc 0 ent)))
to that code block.

and add
(redraw ent 4)
after the entupd

[Tharwat]

Try this simple code and let me know if this works.

Code - Auto/Visual Lisp: [Select]

1. (defun c:test (/ s n e)
2.   (princ "\n Select Attributed block :")
3.   (if (setq s (ssget "_+.:S:E" '((0 . "INSERT") (66 . 1))))
4.     (progn
5.       (setq n (ssname s 0))
6.       (while (and (setq n (entnext n))
7.                   (/= (cdr (assoc 0 (setq e (entget n)))) "SEQEND")
8.              )
9.         (if (eq (cdr (assoc 0 e)) "ATTRIB")
10.           (entmod (subst '(1 . "Example") (assoc 1 e) e))
11.         )
12.       )
13.     )
14.   )
15.   (princ)
16. )
17.  

s .

[Lee Mac]

Try:

Code: [Select]

(defun updateborder ( ent str / enx )
    (if (= "ATTRIB" (cdr (assoc 0 (setq enx (entget ent)))))
        (if (entmod (subst (cons 1 str) (assoc 1 (reverse enx)) enx))
            (entupd ent)
            (prompt "\nModification failed.")
        )
        (prompt "\nObject is not an Attribute Reference.")
    )
)

[WPerciful]

Thank you everyone.

I don't know why but I'm getting this error:

Code: [Select]

<Bad Entity name: FFB27180>

[Tharwat]

I don't know why but I'm getting this error:

Code: [Select]

<Bad Entity name: FFB27180>

Can you upload a sample drawing ?

[WPerciful]

I have hundreds of drawings like the GF-9303-R100.dwg.  They were created using the wrong border. 

I have  a routine that to get the attribute values, delete the border, and insert the new one and I was going to use a script to process them.  But I get the bad entity error.

Thank you for all of your help!

[WPerciful]

I don't know what but the ename's don't match.

Code: [Select]

(setq sse (ssname (ssget "x" '((0 . "INSERT")(2 . "STERLING_TB"))) 0)
e (car (entsel))
)

[Lee Mac]

I have  a routine that to get the attribute values, delete the border, and insert the new one and I was going to use a script to process them.

If the attribute tags are the same, you can import the definition of the updated block into the drawing and simply change the name of the old block reference to that of the new block definition (that is, if it is different - if its the same, the old block definition will be redefined and the block reference will already use the new definition).

ATTSYNC will then sort out the attribute positions whilst retaining the original values (providing the tags are the same, as noted).

[WPerciful]

Inside the titleblock is our logo block (TSI_LOGO_OLD).  I only need to replace that bock from within the titleblock by a function so that I can batch process them.

[Lee Mac]

Inside the titleblock is our logo block (TSI_LOGO_OLD).  I only need to replace that bock from within the titleblock by a function so that I can batch process them.

Try this hastily written code:

Code: [Select]

(defun replacelogoblock ( / doc dwg new old par )
    (setq par "STERLING_TB"  ;; parent block
          old "TSI_LOGO_OLD" ;; old block name
          new "TSI_LOGO_NEW" ;; new block name
    )
    (setq doc (vla-get-activedocument (vlax-get-acad-object)))
    (cond
        (   (= 4 (logand 4 (cdr (assoc 70 (tblsearch "layer" (getvar 'clayer))))))
            (princ "\nCurrent layer locked.")
        )
        (   (not (tblsearch "block" old))
            (princ (strcat "\n" old " not present in drawing."))
        )
        (   (not (tblsearch "block" par))
            (princ (strcat "\n" par " not present in drawing."))
        )
        (   (not (or (tblsearch "block" new)
                     (and (setq dwg (findfile (strcat new ".dwg")))
                          (progn
                              (vla-delete
                                  (vla-insertblock
                                      (vla-get-modelspace doc)
                                      (vlax-3D-point 0 0)
                                      dwg 1.0 1.0 1.0 0.0
                                  )
                              )
                              (tblsearch "block" new)
                          )
                      )
                 )
             )
             (princ (strcat "\n" new ".dwg not found."))
        )
        (    t
             (vlax-for obj (vla-item (vla-get-blocks doc) par)
                 (if
                     (and
                         (= "AcDbBlockReference" (vla-get-objectname obj))
                         (=  (strcase old)
                             (if (vlax-property-available-p obj 'effectivename)
                                 (strcase (vla-get-effectivename obj))
                                 (strcase (vla-get-name obj))
                             )
                         )
                         (vlax-write-enabled-p obj)
                     )
                     (vla-put-name obj new)
                 )
             )
             (vla-regen doc acallviewports)
        )
    )
    (princ)
)
(vl-load-com) (princ)
Change block names as required.

[WPerciful]

 

That did it!

Thank you!!

[Lee Mac]

You're welcome!