Topic: Change plotter name in page setups

[Dave M]

We recently renamed the server where our plotters reside.  Is it possible with AutoLISP to create a find and replace so that the plotter name could be updated without manually modifying each page setup?

Thanks,

Dave

[ronjonp]

Not tested, but something like this should work:

Code: [Select]

(defun foo (name)
  (vlax-map-collection
    (vla-get-plotconfigurations (vla-get-activedocument (vlax-get-acad-object)))
    '(lambda (x) (vla-put-configname x name))
  )
)
(foo "xxx.pc3")

[ronjonp]

Here's a better solution  . As long as your printer names are the same as before, this should update the paths accordingly. I tested it very little...

Code: [Select]

(defun c:fixprinterserverlocation (/ _stripath _getnetworkprinters name printers)
  (defun _stripath (path / n )
    (if (setq n (vl-string-position (ascii "\\") path 0 t))
      (strcase (substr path (+ 2 n)))
      path
    )
  )
  (defun _getnetworkprinters (/ i name out p ws)
    (if (and (setq ws (vlax-get-or-create-object "WScript.Network"))
     (setq p (vlax-invoke ws 'enumprinterconnections))
     (setq i (vlax-invoke p 'count))
)
      (repeat i
(if (wcmatch (setq name (vla-item p (setq i (1- i)))) "\\\\*")
  (setq out (cons (cons (_stripath name) name) out))
)
      )
    )
    out
  )
  (_getnetworkprinters)
  (if (setq printers (_getnetworkprinters))
    (vlax-for x (vla-get-plotconfigurations (vla-get-activedocument (vlax-get-acad-object)))
      (if (setq name (cdr (assoc (_stripath (vla-get-configname x)) printers)))
(vla-put-configname x name)
      )
    )
  )
  (princ)
)
(c:fixprinterserverlocation)
*Updated code above ... some typos and localized variables 

[Dave M]

Thanks ronjop,

I will give it a try as soon as I get a chance

Dave

[alloy mold design]

it is wanderful!

[ronjonp]

it is wanderful!