TheSwamp

CAD Forums => CAD General => Topic started by: Mark on August 25, 2016, 11:06:32 AM

Title: Configure Angular Dim
Post by: Mark on August 25, 2016, 11:06:32 AM

Is it possible to configure a angular dimension so that the text is radial?

Thanks

Title: Re: Configure Angular Dim
Post by: alanjt on August 25, 2016, 12:08:54 PM

?

Code: [Select]

(defun c:test (/ AT:MakeReadable ss i d)

  (defun AT:MakeReadable (ang)
    ;; Make angle readable
    ;; Alan J. Thompson, 12.14.10 / 11.02.11
    (cond ((> ang (* pi 2.)) (AT:MakeReadable (- ang pi)))
          ((minusp ang) (AT:MakeReadable (+ ang pi)))
          ((if (and (> ang (/ pi 2.)) (<= ang (* pi 1.5)))
             (+ ang pi)
             ang
           )
          )
    )
  )


  (if (setq ss (ssget "_:L" '((0 . "DIMENSION"))))
    (repeat (setq i (sslength ss))
      (setq o (vlax-ename->vla-object (ssname ss (setq i (1- i)))))
      (if (eq (vla-get-objectname o) "AcDb2LineAngularDimension")
        (vla-put-textrotation
          o
          (AT:MakeReadable
            (angle
              (vlax-get o 'textposition)
              (apply
                'inters
                (reverse
                  (cons
                    nil
                    (mapcar
                      (function (lambda (prop) (vlax-get o prop)))
                      '(ExtLine1EndPoint ExtLine1StartPoint ExtLine2EndPoint ExtLine2StartPoint)
                    )
                  )
                )
              )
            )
          )
        )
      )
    )
  )
  (princ)
)

Title: Re: Configure Angular Dim
Post by: Mark on August 25, 2016, 02:36:37 PM

That works great. :)

Title: Re: Configure Angular Dim
Post by: alanjt on August 29, 2016, 11:41:16 AM

Quote from: Mark on August 25, 2016, 02:36:37 PM

That works great. :)

Good deal. :)