Print Page - Lisp for Coloring entities by Elevation in RGB Colors (Gradient)

Code Red => AutoLISP (Vanilla / Visual) => Topic started by: yasser.mahran on March 09, 2016, 09:05:38 AM

Title: Lisp for Coloring entities by Elevation in RGB Colors (Gradient)
Post by: yasser.mahran on March 09, 2016, 09:05:38 AM

Hey all, I was searching for a lisp that would do the following: Color entities (polylines/lines) according to their elevation in RGB Gradient manner, what so far I came with is a lisp that would color point clouds but I couldn't use, and some non-free tools like EzySurf (Extra) and Carlson Civil but both use ACI Index, therefore options are limited, and so elevations, What I need is a one that could color entitis in RGB colors, let's say I have a set of polylines, minimum has zero elevation, maximum is 45, so I need the color of the lowest one to be (0,0,0)-Absolute Black, and the color of the highest to be (255,255,255) i.e absolute white, and the ones between to be gradient of both? and thanks in advance!

Title: Re: Lisp for Coloring entities by Elevation in RGB Colors (Gradient)
Post by: ChrisCarlson on March 09, 2016, 09:49:26 AM

Need some more information, will you really have more than 255 different elevations? You list a min. elevation, is there a maximum?

Title: Re: Lisp for Coloring entities by Elevation in RGB Colors (Gradient)
Post by: yasser.mahran on March 09, 2016, 09:57:24 AM

Actually I have more than 255, contour line every 0.5 m for 180 meters, that would be 180*2=360 elevations, but since maximum is 255, it will be just fine, maximum elevation is 45 cm (180 m)

Title: Re: Lisp for Coloring entities by Elevation in RGB Colors (Gradient)
Post by: Lee Mac on March 09, 2016, 10:02:14 AM

This old code will get you started for polylines: Elevation Colour Map (http://www.cadtutor.net/forum/showthread.php?72778-altitude-by-color-hypsomtric-gradient&p=497017&viewfull=1#post497017)

Title: Re: Lisp for Coloring entities by Elevation in RGB Colors (Gradient)
Post by: yasser.mahran on March 09, 2016, 10:19:53 AM

that code is fine, however I was looking for something that would allow more elevations, I actually have more than 255, PLUS I need the colors to be GRADIENT between two colors, this code is similar to "color contours by elevation" function in Carlson Civil tools, What I was looking for is something that would give the following result: (http://i.stack.imgur.com/C31CQ.png), see? coloring in a Gradient manner

Title: Re: Lisp for Coloring entities by Elevation in RGB Colors (Gradient)
Post by: ronjonp on March 09, 2016, 10:26:28 AM

You could try this .. welcome to TheSwamp :)

Code - Auto/Visual Lisp: [Select]

(defun c:clrelev (/ _dxf co i mx n out ss)
  (vl-load-com)
  (defun _dxf (code ename)
    (if (and ename (= (type ename) 'ename))
      (cdr (assoc code (entget ename '("*"))))
    )
  )
  (if (setq ss (ssget ":L" (list '(0 . "lwpolyline,line"))))
    (progn
      (setq co (vla-getinterfaceobject
                 (vlax-get-acad-object)
                 (strcat "AutoCAD.AcCmColor." (substr (getvar "acadver") 1 2))
               )
      )
      (foreach x (vl-remove-if 'listp (mapcar 'cadr (ssnamex ss)))
        (setq out (cons (list x
                              (if (= "LINE" (_dxf 0 x))
                                (apply 'max (list (last (_dxf 10 x)) (last (_dxf 11 x))))
                                (_dxf 38 x)
                              )
                        )
                        out
                  )
        )
      )
      (if (zerop (setq mx (apply 'max (mapcar 'cadr out))))
        (print "Largest Elevation is Zero...")
        (progn
          (setq i (/ 255. mx))
          (foreach x out
            (if (minusp (cadr x))
              (print "Negative Elevation")
              (progn
                (setq n (fix (* i (cadr x))))
                (if (not (vl-catch-all-error-p (vl-catch-all-apply 'vla-setrgb (list co n n n))))
                  (vl-catch-all-apply 'vla-put-truecolor (list (vlax-ename->vla-object (car x)) co))
                )
              )
            )
          )
        )
      )
    )
  )
  (princ)
)

Title: Re: Lisp for Coloring entities by Elevation in RGB Colors (Gradient)
Post by: yasser.mahran on March 09, 2016, 12:41:20 PM

EXCELLENT! Can you just be more generous and give hints about how someone could play with color values so that it the gradient can be used between any two colors? I mean (n n n) is the color, ain't it? anyways, million thanks!

Title: Re: Lisp for Coloring entities by Elevation in RGB Colors (Gradient)
Post by: Lee Mac on March 09, 2016, 01:23:32 PM

Here's another, adjust the colour ranges to suit (RGB values between 0-255):

Code - Auto/Visual Lisp: [Select]

(defun c:zmap ( / cma cmi del elv enx idx lst pct rng sel zmn zmx )
    (setq cmi '(255   0   0) ;; Minimum colours
          cma '(255 255   0) ;; Maximum colours
          zmx 0.0
          zmn 0.0
    )
    (if (setq sel (ssget "_:L" '((0 . "LINE,LWPOLYLINE"))))
        (progn
            (repeat (setq idx (sslength sel))
                (setq enx (entget (ssname sel (setq idx (1- idx))))
                      elv (if (= "LINE" (cdr (assoc 0 enx)))
                              (max (cadddr (assoc 10 enx)) (cadddr (assoc 11 enx)))
                              (cdr (assoc 38 enx))
                          )
                      lst (cons (list enx elv) lst)
                      zmx (max zmx elv)
                      zmn (min zmn elv)
                )
            )
            (setq rng (mapcar '- cma cmi)
                  del (- zmx zmn)
            )
            (if (equal 0.0 del 1e-8)
                (princ "\nNo change in elevation.")
                (foreach itm lst
                    (setq pct (/ (- (cadr itm) zmn) del))
                    (entmod
                        (append (car itm)
                            (list
                                (cons 420
                                    (apply 'LM:rgb->true
                                        (mapcar '(lambda ( a b ) (+ a (* b pct))) cmi rng)
                                    )
                                )
                            )
                        )
                    )
                )
            )
        )
    )
    (princ)
)
 
;; RGB -> True  -  Lee Mac
;; Args: r,g,b - [int] Red, Green, Blue values
 
(defun LM:RGB->True ( r g b )
    (logior (lsh (fix r) 16) (lsh (fix g) 8) (fix b))
)
 
(princ)

Colour Conversion function from here (http://lee-mac.com/colourconversion.html#rgbtru).

Title: Re: Lisp for Coloring entities by Elevation in RGB Colors (Gradient)
Post by: ronjonp on March 09, 2016, 01:33:02 PM

Quote from: yasser.mahran on March 09, 2016, 12:41:20 PM

EXCELLENT! Can you just be more generous and give hints about how someone could play with color values so that it the gradient can be used between any two colors? I mean (n n n) is the color, ain't it? anyways, million thanks!

The (n n n) represents (Red Green Blue) each with a value of 0-255. Look at the graphic below to see how the number change colors.

Title: Re: Lisp for Coloring entities by Elevation in RGB Colors (Gradient)
Post by: dgorsman on March 09, 2016, 05:38:35 PM

In order to establish a gradient between two RGB colors you can do a linear interpolation between each of the three values (R, G, B) based on the number of steps needed. For example, if the (R) value changes from 10 to 200, and you need 50 steps, then each step changes the (R) value by (200 - 10)/50 or 3.8. RGB colors are integers so there will have to be some kind of rounding or truncation applied to the final value.

Title: Re: Lisp for Coloring entities by Elevation in RGB Colors (Gradient)
Post by: yasser.mahran on March 10, 2016, 03:28:25 AM

Thanks Lee! it works perfectly, amd thanks Ron for clarifying, yup I know about RGB, i is probably the increment, wonderful script, a lot of people were looking for it, now we can create elevation maps with autocad, and Yes dgorsman, I know values won't be exact, but rounded will be just fine!