TheSwamp
Code Red => AutoLISP (Vanilla / Visual) => Topic started by: Kate M on October 18, 2007, 03:16:26 PM
-
I'm trying to help somebody on the adesk forums, and got thrown by what I assume is an easy problem
;;Revcloud from spline
(defun C:RS ()
(command "_.spline")
(command "_.revcloud" "o" "l" "n")
(princ)
)
How do I let the spline command finish before moving on to the revcloud, assuming I don't know how many points there will be in the spline?
(I was all proud of myself for writing it out in lisp, then realized it wasn't any different from the same steps in a macro...<sigh>... :oops:)
-
;;Revcloud from spline
(defun C:RS ()
(command "_.spline")
(while (> (getvar "CmdActive") 0)
(command pause)
)
(command "_.revcloud" "o" "l" "n")
(princ)
)
Also since you are making it available for international use (the underscore before the commands) why not carry that throughout the command calls.
;;Revcloud from spline
(defun C:RS ()
(command "_.spline")
(while (> (getvar "CmdActive") 0)
(command pause)
)
(command "_.revcloud" "_o" "_l" "_n")
(princ)
)
-
Sweet. This place rocks. :-D
-
haha, i found your post!
thanks so much for this easy fix!!
-
I thought you said it didn't work?
-
go read my *edited* reply in autodesk forums....
-
Don't see any edits from the newsreader side...whatever, glad it works. :-)
Welcome to the swamp!
-
yeah, sorry...
definite props to you Kate for finding exactly what I wanted!
oh, and kudos for the guy who also thought of exactly the same thing I did and wrote something about it!
-
okay so I'm really happy that this works, but can I get a little picky too?
awesome! :-D
How would I also have it go straight to the CLOUD layer, and automatically turn ortho and osnap OFF, then return to them being on if they were in the first place?
FYI: I'm gonna be also be making a button or right-click function out of this, any qualms?
-
FWIW, I have this macro button for adding text... Don't use it too much anymore, but I still have it.
^C^C(setq oldlayer (getvar "clayer"));-LA;S;TEXT;;DText;J;ML;\;\(setvar "clayer" oldlayer);
I'm not sure if I understand completely what you're trying to do, though.
-
FWIW, I have this macro button for adding text... Don't use it too much anymore, but I still have it.
^C^C(setq oldlayer (getvar "clayer"));-LA;S;TEXT;;DText;J;ML;\;\(setvar "clayer" oldlayer);
I'm not sure if I understand completely what you're trying to do, though.
so are you saying you have a qualm with me using the revspline function as a button?
I don't understand your reply sir, unless you posted in the wrong topic, then I understand completely. :ugly:
-
Just thought I'd throw it in there in response to this...
How would I also have it go straight to the CLOUD layer, and automatically turn ortho and osnap OFF, then return to them being on if they were in the first place?
I can come back to it tomorrow, but my wife just beckoned... I've gotta jet!
-
Quick & dirty...with the caveats that layer CLOUD must exist, and I left out the ortho part. Mainly because I like polar so much better, and I couldn't figure out how to turn it off with a variable.
;;Revcloud from spline
(defun C:RS (/ user_layer user_os)
(setvar user_layer (getvar "clayer"))
(setvar "clayer" "CLOUD")
(setvar user_os (getvar "osmode"))
(setvar "osmode" 0)
(command "_.spline")
(while (> (getvar "CmdActive") 0)
(command pause)
)
(command "_.revcloud" "o" "l" "n")
(setvar "clayer" user_layer)
(setvar "osmode" user_os)
(princ)
)
I think M-dub is trying to teach you how to fish. (See the "About this Forum" sticky.) :wink:
However, I am learning to fish myself, so this is practice for me. We'll make you write the next one yourself. :-D
-
CLOUD layer would definitely exist, as that our company's standard C/S/A layers are dumped into every dwg we create.
this is great y'all.
I love fishing! Only I forgot to bait the hook. :|
-
Kate,
Ortho = OrthoMode system variable.
-
Quick & dirty...with the caveats that layer CLOUD must exist, and I left out the ortho part. Mainly because I like polar so much better, and I couldn't figure out how to turn it off with a variable.
;;Revcloud from spline
(defun C:RS (/ user_layer user_os)
(setvar user_layer (getvar "clayer"))
(setvar "clayer" "CLOUD")
(setvar user_os (getvar "osmode"))
(setvar "osmode" 0)
(command "_.spline")
(while (> (getvar "CmdActive") 0)
(command pause)
)
(command "_.revcloud" "o" "l" "n")
(setvar "clayer" user_layer)
(setvar "osmode" user_os)
(princ)
)
I think M-dub is trying to teach you how to fish. (See the "About this Forum" sticky.) :wink:
However, I am learning to fish myself, so this is practice for me. We'll make you write the next one yourself. :-D
Command: rs
; error: bad argument type: (or stringp symbolp): nil
I have no idea what this means... but I could take a stab at it.
it's a PICNIC = problem in chair, not in computer :-o
-
make sure the layer exist, first.... before using setvar "clayer"
-
it does exist.
-
T.Willey,
Funny you should use a `>' type of check; have you every had any problems with that? The reason I ask is because ive always just checked for a regular command, something like:
(eq (logand (getvar "CMDACTIVE") 1) 1)
have you every used this type of process in a transparent command before? Now you have me thinking about this? I think I might have to run an experiment or two.
Kate,
You might want to think about accounting for an error or two.
QUICK HINTS:
1. Have a look around for my osnap `toggle' procedure.
2. Be carefull with that (setvar 'clayer ...process.
-
:)
Rename:
(setvar user_layer (getvar "clayer"))
To:
(setq user_layer (getvar "clayer"))
and...
(setvar user_os (getvar "osmode"))
to
(setq user_os (getvar "osmode"))
-
T.Willey,
Funny you should use a `>' type of check; have you every had any problems with that? The reason I ask is because ive always just checked for a regular command, something like:
(eq (logand (getvar "CMDACTIVE") 1) 1)
have you every used this type of process in a transparent command before? Now you have me thinking about this? I think I might have to run an experiment or two.
Kate,
You might want to think about accounting for an error or two.
QUICK HINTS:
1. Have a look around for my osnap `toggle' procedure.
2. Be carefull with that (setvar 'clayer ...process.
I have seen other code posted like that John, but my math isn't what is used to be, and I understand the '>' way better. :-) As much as I can recall, I have never had a problem with using it this way. I can check my personal code and see if I have any in there like that, and try and remember if that piece of code as ever error'ed from me.
-
I have seen other code posted like that John, but my math isn't what is used to be, and I understand the '>' way better. :-) As much as I can recall, I have never had a problem with using it this way. I can check my personal code and see if I have any in there like that, and try and remember if that piece of code as ever error'ed from me.
*lol* cool. It was just that your test got me thinking about its use in a transparent command (vlax-add-cmd).
-
great. now my acad won't open!
BTW- I put the lsp in the startup, so that tells me I have to change something. Just before, I did this:
Replaced
(setvar user_layer (getvar "clayer"))
to:
(setq user_layer (getvar "clayer"))
and...
(setvar user_os (getvar "osmode"))
to
(setq user_os (getvar "osmode"))
So now how do I get my ACAD back up and running?
-
Whatever you did.... UNdo it.
I highly recommend that whenever you go and edit a file of such importance as the acad startup routines, that you create a backup. Just copy the original (after you fix it, of course) and rename it to acad.lsp.bak or something like that... I usually keep the original name and file extension, and just add a .bak to the end...
This way if you really bork something up and don't know why... you can just recopy the backup over the borked file.
-
well, I did save the orginal *working* lisp routine. So I wrote over the corrupted one, and still nothing. My ACAD will not open now. I could get into a lot of trouble with my office manager if she finds out what I did!
Please help, I promise I won't bork anything up again!!
-
What's the last thing you did before it stopped working?
-
What do you mean your acad wont start?
BTW, did you edit this file in MS Word?
-
Nothing in the routine should have ruined your Acad. This is just a simple routine to speedup some button pushing.
Standard IT response.... Did you try rebooting?? ... Crazy thing is.. it works most of the time.
-
Also, specifically what 'doesnt work' ?
Does nothing happen when you double click the startup icon, or select it from the start menu or whatever method you use?
Does the application open and report an error? If so, what does the error say, specifically?
-
Okay, just before it quit opening, I changed the strings like LE suggested. And so, since the lisp routine was already in startup suite, I simply restarted ACAD (clicked icon, AND clicked on a dwg). Or tried to at least...
It simply stops at regen... and hangs. I eventually have to hit Ctrl+Alt+Delete to end application, then window pops up stating that AutoCad stopped responding.
I'll be back shortly, gonna reboot computer.
-
What do you mean your acad wont start?
BTW, did you edit this file in MS Word?
no, I always use notepad....
-
great. now my acad won't open!
BTW- I put the lsp in the startup, so that tells me I have to change something. Just before, I did this:
Replaced
(setvar user_layer (getvar "clayer"))
to:
(setq user_layer (getvar "clayer"))
and...
(setvar user_os (getvar "osmode"))
to
(setq user_os (getvar "osmode"))
So now how do I get my ACAD back up and running?
No idea, what you end up doing ?
Remove the lisp from there... (what it is for you the startup?)
So, you double-click on the ACAD.EXE and does not open it?
-
Well the items LE suggested would have NO affect on anything like that, but just to be safe, delete the procedure anyways.
After that, start up acad and change the profile to something else and open a drawing.
-
Nothing in the routine should have ruined your Acad. This is just a simple routine to speedup some button pushing.
Standard IT response.... Did you try rebooting?? ... Crazy thing is.. it works most of the time.
hahaha... worked. weird.
In my office: standard IT response - where's the IT guy when you need him?
in other words, we don't have an IT. Just an office manager that knows a little bit about networking, that's all.
thanks for the suggestion, I've never really encountered a situation where all I had to do was reboot.
-
and.... can you post/or/upload your code (the file) here.... maybe is something in there.
-
okay so back to bizness....
I want the routine to:
set layer to CLOUD
turn off ortho
and turn off osnap
finish the routine, then set ortho and osnap back to what they were, whether on or off.
-
here's what I got so far:
-
and.... can you post/or/upload your code (the file) here.... maybe is something in there.
I think it was a gliche or something... our server has been acting up today (it's stormy weather here today).
-
and.... can you post/or/upload your code (the file) here.... maybe is something in there.
I think it was a gliche or something... our server has been acting up today (it's stormy weather here today).
Must, be something like that... that routine is a very simple one...
-
so what's the code for turning ortho off?
(setq user_ortho (getvar "orthomode"))
(setvar "orthomode" 0)???
Or am I not understanding something right?
-
will this work?
;;Revcloud from spline
(defun C:RS (/ user_layer user_os user_ortho)
(setq user_layer (getvar "clayer"))
(setvar "clayer" "CLOUD")
(setq user_os (getvar "osmode"))
(setvar "osmode" 0)
(setq user_ortho (getvar "orthomode"))
(setvar "orthomode" 0)
(command "_.spline")
(while (> (getvar "CmdActive") 0)
(command pause)
)
(command "_.revcloud" "o" "l" "n")
(setvar "clayer" user_layer)
(setvar "osmode" user_os)
(setvar "orthomode" user_ortho)
(princ)
)
-
will this work?
;;Revcloud from spline
(defun C:RS (/ user_layer user_os user_ortho)
(setq user_layer (getvar "clayer"))
(setvar "clayer" "CLOUD")
(setq user_os (getvar "osmode"))
(setvar "osmode" 0)
(setq user_ortho (getvar "orthomode"))
(setvar "orthomode" 0)
(command "_.spline")
(while (> (getvar "CmdActive") 0)
(command pause)
)
(command "_.revcloud" "o" "l" "n")
(setvar "clayer" user_layer)
(setvar "osmode" user_os)
(setvar "orthomode" user_ortho)
(princ)
)
OMG! It did work!!
I CAN FISH! YAY!!
-
You even added your new variable to the local variable list, nice! Soon you will be giving others advice on how to fix their routines.
-
well, I did learn somethin afterall...
lol.
awesome! Thanks so much for the help y'all! Especially Kate M.
I love this forum!
-
You even added your new variable to the local variable list, nice! Soon you will be giving others advice on how to fix their routines.
That was actually a guess. Honestly.
I do know a little about programming. Only robotics programming though, so I do understand how to look at the code (or language) and eventually figure it out. Just I don't know anything about VLisp, VBA, or AutoLISP.
But today was a start....
-
Once you start, you won't want to stop. You will see all these little things that you do, and could be automated to save a couple of keystrokes per usage, and you will automate it. Happened to us all! And each one of us had to start somewhere.
Welcome to the Swamp Robert!
-
so what's the code for turning ortho off?
(setq user_ortho (getvar "orthomode"))
(setvar "orthomode" 0)???
Or am I not understanding something right?
Try this on for size. There are several variations of this but this one will serve you good for now.
[ http://www.theswamp.org/index.php?topic=51.0#top ]
-
I hate rehashing an OLD thread... but this is where I got started in the swamp... thanks to Kate :wink:
but, I have another question about this lisp routine.
Often when I use it, I'm in the middle of the routine and if I find that i've messed up the spline, I hit ESC - all my osnap settings reset - grrrr!
how do I write an error function, to the affect that I can make sure my osnap settings never reset. dang I hate that!
-
I'd suggest doing a search here for "error handler". There's lots of information. The first thread returned (started by alanjt) should point you in the right direction. CAB's routine in post #2 would do what you want. You'd need to change variable names -- you use 'user_os' while CAB has used 'useros'. You'd also want to reset clayer and orthomode. CAB's routine resets cmdecho, which you don't have in your routine.
Martin
-
thanks for the reply.
i'll go looky...
-
okay... plz help a lispidiot...
do I paste this code just anywhere within my revspline.lsp routine using notepad like this...
(defun C:RS (/ user_layer user_os user_ortho)
(setq user_layer (getvar "clayer"))
(setvar "clayer" "Dimensions")
(setq user_os (getvar "osmode"))
(setvar "osmode" 0)
(setq user_ortho (getvar "orthomode"))
(setvar "orthomode" 0)
(command "_.spline")
(while (> (getvar "CmdActive") 0)
(command pause)
)
(command "_.revcloud" "o" "l" "n")
(setvar "clayer" user_layer)
(setvar "osmode" user_os)
(setvar "orthomode" user_ortho)
(princ)
)
(defun *error* (msg)
(if (not
(member msg '("console break" "Function cancelled" "quit / exit abort" "")))
(princ (strcat "\nError: " msg))
) ; if
(and user_layer (setvar "clayer" user_layer))
(and user_os (setvar "osmode" user_os))
(and user_ortho (setvar "orthomode" user_ortho))
(princ)
) ; end error function
or what?
-
Just my two bobs worth....but place your error handler above the main code...I will continue to look at your code and get back to you.
-
Just a minor thought........but why are you trying to capture variables that are not being changed in the lisp....
Everything seems to hinge around this line of code.......
(command "_.revcloud" "o" "l" "n")
I haven't tested it, so I can't really say, just seems odd. What are you trying to do?
-
when i draw the spline I don't want to have to manually turn off ortho, osnaps, and change the layer.
i want to make sure ortho is automatically turned off, well that's self-explanatory - it's supposed to be a spline. I want osnaps turned off because I'm working around alot of details and can't stand to snap to things i don't want to snap to. I like for what I do to be fully automated.
Like when I right click, on pick 'Linear Dimension' (custom menu) it automatically puts it on Dimensions layer... get it? same thing when I click 'Dynamic Text' - automatically goes to Text layer, and so on...
And after the lisp routine has finished, and has made the spline into a revcloud, I want to be sure all my snap settings revert back to where they where before I invoked the command. Because acad's stupid .revcloud lisp resets all osnap settings!
-
Do a search for CAB's PL2CLOUD.
-
Do a search for CAB's PL2CLOUD.
that doesn't help me.
I already have a lisp that does *mostly* what I need it to do... I just wanted to make it better with an error function.
besides, you can already make a revcloud out of an already existing polyline, by simply clicking REVCLOUD, right click - or from cmd line, choose Object, then pick the pline.
But I liked better the idea of freehanding a spline into a shape around all my revisions without the "boxy" look. Plus, if I need to make rev's to the rev... I can simply right click on the cloud, turn it back into a spline, edit it however I want, then turn it back into a cloud.
-
Simple example
(defun c:Test (/ oOs)
(defun *error* (msg)
Man work gets in the way again.... see Alan posted something before I could get back and finish this..... :cry:
-
Or what. 8-)
(defun C:RS (/ *error* user_layer user_os user_ortho)
;; always localize this routine!!!!!
(defun *error* (msg)
(if (not
(member msg '("console break" "Function cancelled" "quit / exit abort" "" nil)))
(princ (strcat "\nError: " msg))
)
(and user_layer (setvar "clayer" user_layer))
(and user_os (setvar "osmode" user_os))
(and user_ortho (setvar "orthomode" user_ortho))
(princ)
) ; end error function
(setq user_layer (getvar "clayer"))
(setvar "clayer" "Dimensions")
(setq user_os (getvar "osmode"))
(setvar "osmode" 0)
(setq user_ortho (getvar "orthomode"))
(setvar "orthomode" 0)
(command "_.spline")
(while (> (getvar "CmdActive") 0)
(command pause)
)
(command "_.revcloud" "o" "l" "n")
(*error* "")
(princ)
)
-
AWESOME!!
:love:
-
Glad I could be of service. :-)
-
...and exactly what do you mean by "always localize this routine"?
I can't necessarily run this routine from my lap :-)
lol. all my routines are in the support folder...
-
He means to localize the error routine.
(defun c:Main (/ *error*)
(defun *error* (msg)
)
)
Above has the error routine localized.
(defun c:Main ()
(defun *error* (msg)
)
)
Above does Not have the error routine localized.
-
oh.. heh.
why won't this thread DIE already!? gah!
-
oh.. heh.
why won't this thread DIE already!? gah!
CAB was trying to edumacate you and you brought up the question? :-P
-
...and exactly what do you mean by "always localize this routine"?
I can't necessarily run this routine from my lap :-)
lol. all my routines are in the support folder...
When you don't localize the error function it takes over for the built in lisp error handler and stays that way until you (setq *error* nil) or another error handler which is not localized steps on this one.
So it is good practice to clean up after yourself environmentally speaking.
Although that error handler should not cause any problems many error routines attempt to reset environmental variables with program variables that have been clobbered & therefor you get the dreaded message "An error occurred inside the error handler"
It's midnight so I hope I was clear. ZZZzzzzz....
-
thanks for the more *detailed* explanation... it was clear.
but I did understand T.Willey's explanation too... so it's all good 8-)