Topic: Display a string in a list box

[psuchewinner]

I need to turn the following string:
(P22353 P22160 P22798 P20945)

into a list that looks like this: (so that I can display it in a list box)
("P22353" "P22160" "P22798" "P20945")

Can anyone help?

As i understand it, I can only display a list in a list box and the only way to get a linebreak/feed is to group each line item on within separate quotation marks.

I want to send all of my dialog selections as defaults to the registry and I am not having luck writing the quoted text to the registry.

[Kerry]

I assume the first value is meant to be a string ..

Perhaps try something like this ;

(SETQ InitialValue '("P22353 P22160 P22798 P20945") )

(kdub:parsestring (car InitialValue) " ")

;;->> ("P22353" "P22160" "P22798" "P20945")

Code: [Select]

;;;------------------------------------------------------------------
;;;------------------------------------------------------------------
;;;
(DEFUN kdub:parsestring (searchstring delimiter / templist index found)
    (SETQ index (VL-STRING-SEARCH delimiter searchstring))
    (WHILE index
        (SETQ templist     (CONS
                               (IF (= (SETQ found (SUBSTR searchstring 1 index)) delimiter)
                                      nil
                                      found
                               )
                               templist
                           )
              searchstring (SUBSTR searchstring (+ (STRLEN delimiter) index 1))
              index        (VL-STRING-SEARCH delimiter searchstring)
        )
    )
    (IF (> (STRLEN searchstring) 0)
        (SETQ templist (CONS searchstring templist))
    )
    (REVERSE templist)
)


;;;------------------------------------------------------------------
;;;------------------------------------------------------------------
;;;

[psuchewinner]

Thanks,
That look like it is exactly what I needed.  I will let you know after I get a chance to break it down and test it.  Gotta love this place!

[psuchewinner]

That is EXACTLY what I have been trying to do!  Can you explain how it works, add some comments to the code or something?  For some reason, I have an extremely hard time figuring out these types of functions.

 Thanks alot for the help.  I racked my brain yesterday for about 4 hours looking for this solution.

[gile]

Hi,

It's a little too late, but I had some routine doing the same thing

(str2lst "a b c" " ") -> ("a" "b" "c")
(str2lst "1,2,3" ",") -> ("1" "2" "3")
(mapcar 'read (str2lst "1,2,3" ",")) -> (1 2 3)

Code: [Select]

(defun str2lst (str sep / pos)
  (if (setq pos (vl-string-position (ascii sep) str))
    (cons (substr str 1 pos)
  (str2lst (substr str (+ 2 pos)) sep)
    )
    (list str)
  )
)
and the opposite function

(lst2str '(1 2 3) ",") -> "1,2,3"
(lst2str '("a" "b" "c") " ") -> "a b c"

Code: [Select]

(defun lst2str (lst sep)
  (if (cadr lst)
    (strcat (vl-princ-to-string (car lst))
    sep
    (lst2str (cdr lst) sep)
    )
    (vl-princ-to-string (car lst))
  )
)