Topic: Test Points

[A_LOTA_NOTA]

If I had the user pick to points using....

Code: [Select]

(setq Pt1 (getpoint "\nSpecify first corner: "))
  (setq Pt2 (getcorner Pt1 "Specify opposite corner: "))
How could I test to see if the window was taller then it is wide?

[T.Willey]

Code: [Select]

(setq xDist (abs (- (car Pt1) (car Pt2))))
(setq yDist (abs (- (cadr Pt1) (cadr Pt2))))
(if (> xDist yDist)
 (prompt "\n Longer than taller.")
 (prompt "\n Taller than longer.")
)


[CAB]

Tim you forgot one.

Code: [Select]

(cond
 ((= xDist yDist)
  (prompt "\n Window is just right."))
 ((> xDist yDist)
  (prompt "\n Longer than taller."))
 (t
  (prompt "\n Taller than longer."))
)

[T.Willey]

Tim you forgot one.

Code: [Select]

(cond
 ((= xDist yDist)
  (prompt "\n Window is just right."))
 ((> xDist yDist)
  (prompt "\n Longer than taller."))
 (t
  (prompt "\n Taller than longer."))
)

Oh Alan...... At least correct me the correct way. 

Code: [Select]

(cond
 ((equal xDist yDist 0.000001)
  (prompt "\n Window is just right."))
 ((> xDist yDist)
  (prompt "\n Longer than taller."))
 (t
  (prompt "\n Taller than longer."))
)   Good one though......

[CAB]

Never meant for it to be used, just a vehicle for some lame humor. No correction intended.

[T.Willey]

Never meant for it to be used, just a vehicle for some lame humor. No correction intended.

I took it as such, and I needed it today.  Thanks. 

[gile]

Hi,

Just for fun, using grread, grvecs and grtext to display the result in real time on the status line

Code: [Select]

((lambda ()
   (setq pt1 (getpoint "\nFirst corner: "))
   (princ pt1)
   (princ "\nOpposite corner: ")
   (while (and (setq gr (grread T 4 0)) (/= (car gr) 3))
     (redraw)
     (setq pt2 (cadr gr)
   xd  (abs (- (car pt1) (car pt2)))
   yd  (abs (- (cadr pt1) (cadr pt2)))
     )
     (grvecs (list (list (car pt1) (cadr pt1))
   (list (car pt2) (cadr pt1))
   (list (car pt2) (cadr pt1))
   (list (car pt2) (cadr pt2))
   (list (car pt2) (cadr pt2))
   (list (car pt1) (cadr pt2))
   (list (car pt1) (cadr pt2))
   (list (car pt1) (cadr pt1))
     )
     )
     (cond
       ((< xd yd) (grtext -1 "Taller than longer"))
       ((< yd xd) (grtext -1 "Longer than taller"))
       (T (grtext -1 "Perfect square"))
     )
   )
   (grtext)
   (princ pt2)
   (princ)
 )
)