Topic: Get IP address

[Andrea]

Hi all,..

I know there is some code to find the IP address.
but there is some others ( just sharing).

Code: [Select]



(defun c:getip ( / WMI CSERV EXQ gip)
 (vl-load-com)
  (setq WMI (vlax-create-object "WbemScripting.SWbemLocator"))
  (setq CSERV (VLAX-INVOKE WMI 'ConnectServer "." "\\root\\cimv2" nil nil nil nil nil nil))
  (setq EXQ (vlax-invoke CSERV 'ExecQuery "Select * From Win32_NetworkAdapterConfiguration Where IPEnabled = true")) 
  (vlax-for item EXQ
  (setq gip (vlax-get item 'IPAddress))
  )   
(vlax-release-object wmi)
(vlax-release-object CSERV)
(vlax-release-object EXQ)
gip
)



(defun c:getip2 ( / IP Domain dhcpSubnet TheIP)
 (vl-load-com)
  (foreach guid (vl-registry-descendents (setq loc "HKEY_LOCAL_MACHINE\\SYSTEM\\CurrentControlSet\\Services\\TCPIP\\Parameters\\Interfaces\\"))
    (if (and
          (setq Domain (vl-registry-read (strcat loc guid) "DhcpDomain"))
          (setq IP (vl-registry-read (strcat loc guid) "DhcpIPAddress"))
          (not (vl-registry-read (strcat loc guid) "DhcpNetworkHint"))
          (setq dhcpSubnet (vl-registry-read (strcat loc guid) "DhcpSubnetMask"))
          (= dhcpSubnet "255.255.255.0")
        )
    (setq TheIP IP)
    )
    )
  theIP
 )

[highflyingbird]

I wrote a very similar one:

Code - Auto/Visual Lisp: [Select]

1. (defun GetIP (/ SWbemLocator Service IPSet lst IP Address)
2.   (setq SWbemLocator (vlax-create-object "WbemScripting.SWbemLocator"))        
3.   (setq Service (vlax-invoke SWbemLocator 'ConnectServer))
4.   (setq IPSet (vlax-invoke Service 'InstancesOf "Win32_NetworkAdapterConfiguration"))
5.   (setq lst nil)
6.   (vlax-for IP IPSet
7.     (if (setq Address (vlax-get IP 'IPAddress ))
8.       (setq lst (cons Address lst))
9.     )
10.   )
11.   (vlax-release-object IPSet)
12.   (vlax-release-object Service)
13.   (vlax-release-object SWbemLocator)
14.  
15.   (reverse lst)
16. )

[highflyingbird]

If you have registered  the DynamicWrapper ,you can use this:

Code - Auto/Visual Lisp: [Select]

1. (vl-load-com)
2. ;;;function :Get the ip address and more details.
3. (defun C:IP (/ wrap pTable pSize ret i size count IPAddress InterfaceIndex SubnetMask BroadCast ReassemblySize lst)
4.   (setq wrap (vlax-create-object "DynamicWrapperX"))
5.   (vlax-invoke wrap 'Register "MSVCRT" "calloc" "i=ll" "r=p")
6.   (vlax-invoke wrap 'Register "MSVCRT" "free" "i=p")
7.   (vlax-invoke wrap 'Register "iphlpapi" "GetIpAddrTable" "i=ppl" "r=l")
8.   (vlax-invoke wrap 'Register "ws2_32" "inet_ntoa" "i=p" "r=s")
9.  
10.   ;;memory allocate
11.   (setq pTable (vlax-invoke wrap 'calloc 1 28))
12.   (setq pSize (vlax-invoke wrap 'calloc 1 4))
13.   (vlax-invoke wrap 'numput 0 pSize)
14.  
15.   ;;the first test
16.   (setq ret (vlax-invoke wrap 'GetIpAddrTable pTable pSize 0))
17.  
18.   ;;get the buffer
19.   (setq size (vlax-invoke wrap 'NumGet pSize))
20.   (vlax-invoke wrap 'free pTable)
21.   (setq pTable (vlax-invoke wrap 'calloc 1 size))
22.  
23.   ;;the second test
24.   (setq ret (vlax-invoke wrap 'GetIpAddrTable pTable pSize 0))
25.  
26.   ;;Get the details
27.   (setq Count (vlax-invoke wrap 'NumGet pTable))
28.   (setq i 0)
29.   (setq lst nil)
30.   (repeat Count
31.     (setq IPAddress  (vlax-invoke wrap 'Numget pTable (+ i 4)))
32.     (setq InterfaceIndex (vlax-invoke wrap 'NumGet pTable (+ i 8)))
33.     (setq SubnetMask (vlax-invoke wrap 'NumGet pTable (+ i 12)))
34.     (setq BroadCast (vlax-invoke wrap 'NumGet pTable (+ i 16)))
35.     (setq ReassemblySize (vlax-invoke wrap 'NumGet pTable (+ i 20)))
36.     (setq lst (cons (list InterfaceIndex
37.                           ;(vlax-invoke wrap 'inet_ntoa IPAddress)
38.                           ;(vlax-invoke wrap 'inet_ntoa SubnetMask)
39.                           ;(vlax-invoke wrap 'inet_ntoa BroadCast)
40.                           (inet_ntoa IPAddress)
41.                           (inet_ntoa SubnetMask)
42.                           (inet_ntoa BroadCast)
43.                           ReassemblySize
44.                     )
45.                     lst
46.               )
47.     )
48.     (setq i (+ i 24))
49.   )
50.  
51.   ;;release objects  and free memory
52.   (vlax-invoke wrap 'free pSize)
53.   (vlax-invoke wrap 'free pTable)
54.   (vlax-release-object wrap)
55.   (reverse lst)
56. )
57.  
58. (defun inet_ntoa (n / x l)
59.   (setq x n)
60.   (repeat 4
61.     (setq l (cons (logand x 255) l))
62.     (setq x (lsh x -8))
63.   )
64.   (reverse l)
65. )

[ahankhah]

highflyingbird,
I registered DynamicWrapper, but had no success getting "DynamicWrapperX" object (mentioned in the 4th line of code):

(setq wrap (vlax-create-object "DynamicWrapperX"))

and it returns nil.

What is wrong with my effort?