Topic: How do I get a tablestyle object from activedocument?

[mkweaver]

The Acad 2008 help file says that the tablestyle object is contained in the document object.  However, there is nothing under the document object about tablestyles.  How do I get a tablestyle from the document object?

Thanks,
Mike Weaver

[Marco Jacinto]

Try looking in the dictionaries collection, look for  "acad_tablestyle".

Saludos

Marco Jacinto

[mkweaver]

Found it.  Here's a quick routine to get a table style if it exists, or create a new one if it doesn't exist

Suggestions welcome:

Code: [Select]

;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;;;  Routine: GetOrCreateTableStyle ;;;
;;;  Purpose: Create or retrieve a tablestyle object - specific to Acad 2008, may have to be ;;;
;;; modified for later versions of acad. ;;;
;;;  Arguments: Doc - document object ;;;
;;; StyleName - string, the name of the tablestyle ;;;
;;;  Returns: IAcadTableStyle2 for the specified stylename ;;;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
(defun GetOrCreateTableStyle (doc StyleName / dict newstyle stylecount stylelist tablestyle tablestyles)
  (setq
    doc (if doc doc (vla-get-activedocument(vlax-get-acad-object)))
    dict (vla-get-dictionaries doc)
    tablestyles (vla-item dict "acad_tablestyle")
    StyleCount (vla-get-count tablestyle)
    )
  (vlax-for TableStyle TableStyles
    (setq StyleList (cons (cons (vla-get-name TableStyle) TableStyle) StyleList))
    )
  (if (assoc StyleName StyleList)
    (cdr (assoc StyleName StyleList))
    (progn
      (setq
NewStyle (vla-addobject tablestyles StyleName "AcDbTableStyle")
)
      (vla-put-name NewStyle StyleName)
      NewStyle
      )
    )
  )

[T.Willey]

There is a mis-typing here

Code: [Select]

    StyleCount (vla-get-count tablestyle)
Forgot the 's' on tablestyles

Why not just see if the style exists in the dictionary, and if not create?  Like

Code: [Select]

(if
(vl-catch-all-error-p
(setq StyleObject
(vl-catch-all-apply
'vla-Item
(list
tablesstyles
StyleName
)
)
)
)
(progn
(setq StyleObject (vla-AddObject tablestyles StyleName "AcDbTableStyle"))
(vla-put-Name StyleObject StyleName)
)
)
Then just return StyleObject