Topic: Selection sets in Visual Lisp

[Red Nova]

Hi guys.

Not so good with Visual lisp, so need a little help here
How to I convert from something like this

Code - Auto/Visual Lisp: [Select]

1. '(#<VLA-OBJECT IAcadBlockReference 000002ca284f79f8> #<VLA-OBJECT IAcadBlockReference 000002ca284f9668> #<VLA-OBJECT IAcadBlockReference 000002ca284f8488>)

this

Code - Auto/Visual Lisp: [Select]

1. '#<VLA-OBJECT IAcadSelectionSet 000002ca2af35f78>

and also how to convert vice versa.
Also please tell me how to call each version properly.
Do I understand it properly that '#<VLA-OBJECT IAcadSelectionSet 000002ca2af35f78> is the actual selection set in Visual lisp and the other list is the list of entities that it contains?

Thank you

[kpblc]

Try to create named selection set and then add objects to it. It seems like this:

Code - Auto/Visual Lisp: [Select]

1. (vl-load-com)
2.  
3. (defun test (obj-lst / adoc name selset)
4.   (setq adoc (vla-get-activedocument (vlax-get-acad-object))
5.         name "TempSelSet"
6.         ) ;_ end of setq
7.   (vl-catch-all-apply (function (lambda () (vla-delete (vla-item (vla-get-selectionsets adoc) name))))
8.                       ) ;_ end of vl-catch-all-apply
9.   (setq selset (vla-add (vla-get-selectionsets adoc) name))
10.   (vla-additems selset
11.                 (vlax-make-variant
12.                   (vlax-safearray-fill (vlax-make-safearray vlax-vbobject (cons 0 (1- (length obj-lst)))) obj-lst)
13.                   ) ;_ end of vlax-make-variant
14.                 ) ;_ end of vla-additems
15.   ) ;_ end of defun
16.  

[Red Nova]

kpblc,

Thanks. Couldn't make it work yet.
What should obj-lst be in the input?

P.S. привет маестро

[kpblc]

I mean that obj-lst is list of objects you want to add to selection set.
What is the reason to work with selection set? Maybe there is another way exist to solve your problem
--
ЗЫ - Привет!

[Grrr1337]

And the reverse process - from SS vla-object to a list of vla-objects:

Code - Auto/Visual Lisp: [Select]

1. (defun oSS->oL ( oSS / oL )
2.   (and
3.     (eq 'VLA-OBJECT (type oSS))
4.     (vlax-property-available-p oSS 'Name)
5.     (not (vl-catch-all-error-p (vl-catch-all-apply 'vla-item (list (vla-get-SelectionSets (vla-get-ActiveDocument (vlax-get-acad-object))) (vla-get-Name oSS)))))
6.     (vlax-for o oSS (setq oL (cons o oL)))
7.   ); and
8.   oL
9. ); defun oSS->oL

[Red Nova]

Thanks guys.
Actually I already found a way around my problem. However, I am continuing out of curiosity.

I could make function from Grrr1337 work, but still not getting how to deal with function from kpblc

Code - Auto/Visual Lisp: [Select]

1. (defun kpblc (obj-lst / adoc name selset)
2.   (vl-load-com)
3.   (setq adoc (vla-get-activedocument (vlax-get-acad-object))
4.         name "TempSelSet"
5.         ) ;_ end of setq
6.   (vl-catch-all-apply (function (lambda () (vla-delete (vla-item (vla-get-selectionsets adoc) name))))
7.                       ) ;_ end of vl-catch-all-apply
8.   (setq selset (vla-add (vla-get-selectionsets adoc) name))
9.   (vla-additems selset
10.                 (vlax-make-variant
11.                   (vlax-safearray-fill (vlax-make-safearray vlax-vbobject (cons 0 (1- (length obj-lst)))) obj-lst)
12.                   ) ;_ end of vlax-make-variant
13.                 ) ;_ end of vla-additems
14.   ) ;_ end of defun
15.  
16.  
17. (defun oSS->oL ( oSS / oL )
18.   (vl-load-com)
19.   (and
20.     (eq 'VLA-OBJECT (type oSS))
21.     (vlax-property-available-p oSS 'Name)
22.     (not (vl-catch-all-error-p (vl-catch-all-apply 'vla-item (list (vla-get-SelectionSets (vla-get-ActiveDocument (vlax-get-acad-object))) (vla-get-Name oSS)))))
23.     (vlax-for o oSS (setq oL (cons o oL)))
24.     ); and
25.   oL
26.   ); defun oSS->oL
27.  
28.  
29.  
30. (defun c:test2 (/ sel blkselection vlablkselection)
31.   (vl-load-com)
32.  
33.   (setq blkselection (ssget '((0 . "INSERT")(66 . 1))))
34.   (setq vlablkselection (LM:ss->vla blkselection))
35.   (setq sel (vla-get-activeselectionset (vla-get-ActiveDocument (vlax-get-acad-object))))
36.  
37.   (oSS->oL sel);works fine
38.   (setq sel (kpblc vlablkselection));doesn't work
39.   )
40.  

[ribarm]

Where did you find variable lst defined?

Have you tried :

Code - Auto/Visual Lisp: [Select]

1. (setq sel (kpblc vlablkselection))
2.  

[Red Nova]

Where did you find variable lst defined?

Have you tried :

Code - Auto/Visual Lisp: [Select]

1. (setq sel (kpblc vlablkselection))
2.  

Yes, I have tried that.
I corrected my code on previous post.

[roy_043]

@Grrr1337:
I understand what you are doing there: working around the missing ObjectName property. But the selection set object has some unique methods, checking for those would be more straightforward.

[ribarm]

Have you tried :

(defun kpblc (obj-lst / adoc name selset)
  (vl-load-com)
  (setq adoc (vla-get-activedocument (vlax-get-acad-object))
        name "TempSelSet"
        ) ;_ end of setq
  (vl-catch-all-apply (function (lambda () (vla-delete (vla-item (vla-get-selectionsets adoc) name))))
                      ) ;_ end of vl-catch-all-apply
  (setq selset (vla-add (vla-get-selectionsets adoc) name))
  (vla-additems selset
                (vlax-make-variant
                  (vlax-safearray-fill (vlax-make-safearray vlax-vbobject (cons 0 (1- (length obj-lst)))) obj-lst)
                  ) ;_ end of vlax-make-variant
                ) ;_ end of vla-additems
  selset
  ) ;_ end of defun

[Grrr1337]

@Grrr1337:
I understand what you are doing there: working around the missing ObjectName property. But the selection set object has some unique methods, checking for those would be more straightforward.

Initially I thought about what you wrote, Roy - since the missing ObjectName property.
But in order to keep the subfoo simplier - I've decided to avoid them and just errortrap with the vla-item method.


Ofcourse one could follow your suggestion -

Code - Auto/Visual Lisp: [Select]

1. ; (CheckIfvlaSS (vla-get-ActiveSelectionSet (vla-get-ActiveDocument (vlax-get-acad-object)))) >> T
2. ; (CheckIfvlaSS (vlax-ename->vla-object (car (entsel)))) >> nil
3. (defun CheckIfvlaSS ( SS )
4.   (and
5.     (eq 'VLA-OBJECT (type SS))
6.     (vl-every '(lambda (x) (vlax-property-available-p SS x))
7.       '(Application Count Name)
8.     )
9.     (vl-every '(lambda (x) (vlax-method-applicable-p SS x))
10.       '(AddItems Clear Delete Erase Highlight Item RemoveItems Select SelectAtPoint SelectByPolygon SelectOnScreen Update)
11.     )
12.   ); and
13. ); defun

[Red Nova]

Have you tried :

(defun kpblc (obj-lst / adoc name selset)
  (vl-load-com)
  (setq adoc (vla-get-activedocument (vlax-get-acad-object))
        name "TempSelSet"
        ) ;_ end of setq
  (vl-catch-all-apply (function (lambda () (vla-delete (vla-item (vla-get-selectionsets adoc) name))))
                      ) ;_ end of vl-catch-all-apply
  (setq selset (vla-add (vla-get-selectionsets adoc) name))
  (vla-additems selset
                (vlax-make-variant
                  (vlax-safearray-fill (vlax-make-safearray vlax-vbobject (cons 0 (1- (length obj-lst)))) obj-lst)
                  ) ;_ end of vlax-make-variant
                ) ;_ end of vla-additems
  selset
  ) ;_ end of defun

Thanks. Silly me ))

[roy_043]

@Grrr1337:
You are going a bit overboard there. Checking one unique method should be enough. Note that I disagree with the error-checking in your oSS->oL function. But that has been discussed before.