Topic: Coordinates arrorheads dimensios

[Lupo76]

I need to get the coordinates of the arrows of an entity DIMENSION.
I found the DXF codes 10-11-13 and 14, but only 10 corresponds to one of the arrows.
How can I obtain the coordinates of the other arrow?

[ribarm]

It's not LISP, but who knows, maybe it'll help...

http://adndevblog.typepad.com/autocad/2015/10/getting-points-of-intersection-between-dimension-line-and-extension-lines-of-a-dimension.html

M.R.

[ronjonp]

On an AcDbAlignedDimension, 13 & 14 seem to be the DXF codes you need.

[PKENEWELL]

The point your wanting to obtain is not stored in the entity and must be calculated. This is different depending on the type of dimension.

for linear or aligned dimensions - try the following:

Code: [Select]

(defun C:test (/ pjk-Massoc el dpt ali dis ep1 ep2 dan pt1 pt2 pt)

   (defun pjk-Massoc (el dxf)
      (vl-remove-if 'null
         (mapcar (function (lambda (x)(if (= (car x) dxf) x nil))) el)
      )
   )

   (setq el  (entget (car (entsel "\nSelect A Linear/Aligned Dimension: ")))
         dpt (cdr (assoc 10 el))
         ali (member "AcDbRotatedDimension" (mapcar 'cdr (pjk-Massoc el 100)))
         dis (cdr (assoc 42 el))
         ep1 (cdr (assoc 13 el))
         ep2 (cdr (assoc 14 el))
         dan (if ali (cdr (assoc 50 el)) (angle ep1 ep2))
         pt1 (inters
                dpt
                (polar dpt dan dis)
                ep1
                (polar ep1 (+ dan (/ pi 2)) dis)
                nil
             )
         pt2 (inters
                dpt
                (polar dpt dan dis)
                ep2
                (polar ep2 (+ dan (/ pi 2)) dis)
                nil
             )
         pt  (trans (if (= pt1 dpt) pt2 pt1) 0 1)
   )
   (command "._line" "_non" pt)
)


[PKENEWELL]

I have corrected my code in the previous post. I had the aligned vs. rotated dimension code backwards. i.e. "rotated" dimensions always have an "aligned" code 100, but "aligned" dimensions do not have a "rotated" code 100 in them. Sorry for the mistake. 

[Lupo76]

I have corrected my code in the previous post. I had the aligned vs. rotated dimension code backwards. i.e. "rotated" dimensions always have an "aligned" code 100, but "aligned" dimensions do not have a "rotated" code 100 in them. Sorry for the mistake. 

Perfect!
it is just what I wanted!
Thank you.

[PKENEWELL]

Perfect!
it is just what I wanted!
Thank you.

No problem. Glad I was able to help!