Topic: getpoint & relative coordinates

[Kate M]

I'm trying to get AutoCAD to draw a rectangle by defining two points (with getpoint)and using those coordinates to get the corners. All is well, except...I can't use "@" in setting the second point. I know that the value used for the relative entry is stored in "lastpoint" but it doesn't seem to be related to the return value of getpoint. (setq lastpoint pt1) doesn't work. Here's what I've got...

Code: [Select]

(defun c:wd ( / pt1 pt2 pt3 pt4)
  (setq pt1 (getpoint "\nSelect First Corner: ")) ;Gets first point
  (setq pt3 (getpoint "\nSelect Second Corner: ")) ;Gets third point
  (setq pt2 (list (car pt1) (cadr pt3))) ;Sets second point
  (setq pt4 (list (car pt3) (cadr pt1))) ;Sets fourth point

  (command "pline" pt1 pt2 pt3 pt4 "c") ;Draws a rectangular polyline
  (command "line" pt1 pt3 "") ;Draws first diagonal
  (command "line" pt2 pt4 "") ;Draws second diagonal
(princ)
) ;end defun

I know this should be simple...Any thoughts?

[ronjonp]

Not what you are looking for but I modified the second pick to use getcorner so you can see an outline of the rectangle.

Code: [Select]


(defun c:wd (/ pt1 pt2 pt3 pt4)
  (setq pt1 (getpoint "\nSelect First Corner: ")) ;Gets first point
  (setq pt3 (getcorner pt1 "\nSelect Second Corner: "));Gets third point
  (setq pt2 (list (car pt1) (cadr pt3))) ;Sets second point
  (setq pt4 (list (car pt3) (cadr pt1))) ;Sets fourth point

  (command "pline" pt1 pt2 pt3 pt4 "c") ;Draws a rectangular polyline
  (command "line" pt1 pt3 "") ;Draws first diagonal
  (command "line" pt2 pt4 "") ;Draws second diagonal
  (princ)
) ;end defun

HTH

Ron

[CAB]

How bout this:

Code: [Select]

(defun c:wd (/ pt1 pt2 useros usercmd)
  (setq usercmd (getvar "CMDECHO"))
  (setvar "CMDECHO" 0)
  (cond
    ((and
       (setq pt1 (getpoint "\nSelect First Corner: "))
       (setq pt3 (getcorner pt1 "\nSelect Second Corner: "))
     )
     (setq useros (getvar "osmode"))
     (setvar "osmode" 0)
     (command "._rectangle" pt1 pt3)
     (command "._line" pt1 pt3 "")
     (command "._line"
              (list (car pt1) (cadr pt3))
              (list (car pt3) (cadr pt1))
              ""
     )
     (setvar "osmode" useros)
    )
  )
  (setvar "CMDECHO" usercmd)
  (princ)
) ;end defun

[daron]

To use @, you would need to specify it in the command line of the code, not the getpoint.

[SMadsen]

CAB and Ron used GETCORNER with a point from which to drag, namely the previously input point. Just to complete the fine answers, GETPOINT can also be given a point from which to drag:

(setq pt1 (getpoint "\nSelect first corner: "))
(setq pt2 (getpoint pt1 "\nSelect second corner: "))

Whether you use one function or the other, you just use previously acquired data to continue from. As you seem to have found out, neither of the functions sets LASTPOINT anyway .. so reading it or setting it is useless for this purpose.

[Dann]

Also, For future reference LastPoint is a Autocad variable.
To Change it.....(setvar "LastPoint" Pt1)

[Kate M]

And the learning continues...thanks guys!