Topic: Search a plotstyle ...

[Hangman]

Afternoon everyone,

I am importing a plotstyle into a drawing and want to search for the plotstyle.  If it exists in the drawing, don't import.
But you can't (at least I can't find how to) use "tblsearch" to look for it.

How would you search for a plot style?

Thanks.

[Matt__W]

Are you referring to the CTB file in the page setup?

[Hangman]

Are you referring to the CTB file in the page setup?

No, actually the Page Setup itself.
For example, we have 5 plotters in the office, but the drawing template only has 3 of the 5.
I'm new here and can't modify the template (they don't let newbies modify anything).  So, When I start a new drawing, I have to manually create a page setup for the 4th and 5th plotter.
So I created my own template and simply import the page setup into the new drawing.  But sometimes I forget I already did this and when I run my import lisp again, it gives me the notice that the page setup already exists, do I want to overwrite it?  So I want to search for the page setup and verify it's in the drawing before the import kicks in.

[CAB]

Code: [Select]

; (getPlotConfigNames (vla-get-activedocument (vlax-get-acad-object)))
(defun getPlotConfigNames (document / names)
 (reverse
  (vlax-for x (vla-get-plotconfigurations document)
   (setq names (cons (vla-get-name x) names))
   )
  )
 )

[danallen]

here is what I use

-Dan

Code: [Select]


(setq ACME_PAGESETUPS  "u:\\Drawings\\_Support\\Cad Standards\\SDG-Settings.dwg")

;;;============================================================================
;;; Delete Page Setups
;;; From: "Ken Alexander" <kalex@fremontmillwork.com
;;;============================================================================
(defun-q ACME_DeletePlotConfig (pcname / plcfg)
  (setq plcfg (vl-catch-all-apply
                'vla-item
                (list (vla-get-plotconfigurations (vla-get-activedocument (vlax-get-acad-object)))
                      pcname
                ) ;_ list
              ) ;_ vl-catch-all-apply
  ) ;_ setq
  (if (not (vl-catch-all-error-p plcfg))
    (vla-delete plcfg)
  ) ;_ if
) ;_ defun


;;;============================================================================
;;; CONFIGURE PAGE SETUPS
;;;============================================================================
  (defun-q ACME_pageSetupMsg ( size / )
    (if dos_msgbox
      (dos_msgbox
        (strcat "Reloaded " size " pagesetups from ACME Settings.dwg"
           "\n\nTo refresh display go to PageSetups and Double-click desired setup"
        )
        "Pagesetups"
        1 ; OK button
        3 ; info icon
        3 ; 3 sec duration
      )
      (alert (strcat "Reloaded " size " pagesetups from ACME Settings.dwg"
        "\n\nTo refresh display go to PageSetups and Double-click desired setup"))
    )
  )

(defun-q c:PG24x36 ( / psn)
    (setq psn "Olive_24x36_Half")
    (ACME_DeletePlotConfig psn) ;delete page setup if it exists
    (command "-psetupin" ACME_PAGESETUPS psn)
    (setq psn "Olive_24x36_Full")
    (ACME_DeletePlotConfig psn) ;delete page setup if it exists
    (command "-psetupin" ACME_PAGESETUPS psn)
    (ACME_pageSetupMsg "24x36")
    (princ)
  )


[Hangman]

Hello Charles, it's been a while.  Good to hear from you.  And thank you for the help.

And thank you Dan for the help as well.

I will make the best of these and get back when I can.

Thank you again guys.

[ronjonp]

I just delete all the page setups then re-import all of them. This way you don't get any prompts.

Something like this:

Code: [Select]

(defun c:page (/ psetups)
  (vl-load-com)
  (vlax-map-collection
    (vla-get-plotconfigurations (vla-get-activedocument (vlax-get-acad-object)))
    'vla-delete
  )
  ;; Modify this line
  (setq psetups "S:/Your/Filepath/GoesHere/sht_manager_overrides.dwt")
  (if (findfile psetups)
    (progn (setvar 'filedia 0)
   (vl-cmdf ".-psetupin" psetups "*")
   (setvar 'filedia 1)
   (princ "\n <<<Pagesetups Imported>>>")
    )
    (princ "\n <<<Pagesetups NOT FOUND!>>>")
  )
  (princ)
)

[Cathy]

Are you referring to the CTB file in the page setup?

No, actually the Page Setup itself.
For example, we have 5 plotters in the office, but the drawing template only has 3 of the 5.
I'm new here and can't modify the template (they don't let newbies modify anything).  So, When I start a new drawing, I have to manually create a page setup for the 4th and 5th plotter.
So I created my own template and simply import the page setup into the new drawing.  But sometimes I forget I already did this and when I run my import lisp again, it gives me the notice that the page setup already exists, do I want to overwrite it?  So I want to search for the page setup and verify it's in the drawing before the import kicks in.

I can understand not wanting everyone to be able to change the template, but surely someone has write access to the template and can add the new plotters to it!  Seems infinitely easier than copying and recopying page setups a zillion times. 

[Hangman]

I just delete all the page setups then re-import all of them. This way you don't get any prompts.
  < ... >

Ron,
If you are just deleting them all, why not use the 'expert' set to 5 and then your code is only a fraction of the size and you accomplish the same goal?

Jus' wonder'n

I can understand not wanting everyone to be able to change the template, but surely someone has write access to the template and can add the new plotters to it!  Seems infinitely easier than copying and recopying page setups a zillion times. 

Cathy,
Yes I agree also.  I've been around enough to see newbies screw things up to the point the company is on the brink of disaster.  But it's also a difficult to ask a somebody who has access and have been with the company for years to update this simple thing when they say something to the effect of:

That is a low priority on the list at the moment and I don't have time nor the will to do it.  When you can get an executive order from the president and I don't have anything else worthwhile to do, then I'll think about it.

  Sounds alot like the IT guy.   
Of course, as I'm walking away I hear them cursing under their breath,

Stupid newbies don't know anything.

   

Anyway, for the moment and probably the next 5 years, I have to work around it all.  But who knows, perhaps by then I'll be laid-off again and back where I was when I found this job.   

[Lee Mac]

But you can't (at least I can't find how to) use "tblsearch" to look for it.

dictsearch 

Code - Auto/Visual Lisp: [Select]

1. (defun _configsearch ( config )
2.     (dictsearch (cdr (assoc -1 (dictsearch (namedobjdict) "ACAD_PLOTSETTINGS"))) config)
3. )

[ronjonp]

I just delete all the page setups then re-import all of them. This way you don't get any prompts.
  < ... >

Ron,
If you are just deleting them all, why not use the 'expert' set to 5 and then your code is only a fraction of the size and you accomplish the same goal?

Jus' wonder'n

...

True .. that will suppress the prompts but it won't remove old setups. 

[irneb]

Just curious. If you're going to delete setups before importing them, what happens to layouts which have been assigned to a setup? Wouldn't the expert=5 or even a while-CmdActive idea work "better" in this scenario? Or do you want to dis-assign all plot setups from tabs?

[ronjonp]

If the resources (CTB pc3 etc.) for the page setup are still available, the setup that was saved to a layout will remain intact minus the name (will show "<None>").

[irneb]

What I'm concerned with though: Generally if I load setups (and especially if I'm overwriting existing ones), I'd like the layouts to update accordingly. If I first delete the config from the drawing, then the layout is disassociated from it and reloading does not re-associate the layout. Which means I'll have to re-run my code from here: http://forums.augi.com/showthread.php?80461-Page-Setup-Manager

[CAB]

More tools. 
http://www.theswamp.org/index.php?topic=8855.0