Topic: Drawing a polyline (well it's more complicated than that)

[iliekater]

Is it possiple to draw a PLINE with LISP if we have a list with variables (variables that could be either points or list of coordinates - you choose what's easier) ?
I know I can do something like that with VBA (although in that case I had to use an array) but I wonder if I can do that with LISP since it's easy to me to create a list with all points that I want to unite .

[gile]

Hi,

You can see this reply

[It's Alive!]

like this?

Code: [Select]

(defun c:doit (/            activedocument            iacadapplication
               modelspace   paperspace   pt1          pt2
               pt3          pt4          pt5
              )
  (vl-load-com)
  (setq IAcadApplication (vlax-get-acad-object)
        ActiveDocument   (vla-get-ActiveDocument IAcadApplication)
        PaperSpace       (vla-get-PaperSpace ActiveDocument)
        ModelSpace       (vla-get-ModelSpace ActiveDocument)
  )
  (setq pt1 '(0 0 0))
  (setq pt2 '(0 100 0))
  (setq pt3 '(100 100 0))
  (setq pt4 '(100 0 0))
  (setq pt5 '(0 0 0))
  (DrawLwPolyLine ModelSpace (list pt1 pt2 pt3 pt4 pt5) "0")
  (princ)
)
;;;-==-==-==-==-==-==-==-==-==-==-==-==-==-==-==-==-==-==-==-==-==-==-
;;;DrawLwPolyLine DocSpace (list pt1 pt2 pt3) layer
;;;-==-==-==-==-==-==-==-==-==-==-==-==-==-==-==-==-==-==-==-==-==-==-
(defun DrawLwPolyLine (DocSpace PointList layer / e plist ptl)
  (setq ptl   PointList
        plist '()
  )
  (foreach e ptl
    (setq plist (cons (car e) plist)
          plist (cons (cadr e) plist)
    )
  )
  (vla-put-layer
    (vla-addLightweightPolyline
      DocSpace
      (vlax-safearray-fill
        (vlax-make-safearray
          vlax-vbDouble
          (cons 0
                (-
                  (length plist)
                  1
                )
          )
        )
        (reverse plist)
      )
    )
    layer
  )
)


edit: Oops Gile beat me to it

[Joe Burke]

Personally I prefer entmake vs vlisp for a new lwpline because it accepts a 2D or 3D point list (dropping off the Z value in that case) whereas the vlisp method is more picky about what it will accept.

The methods are the same speed-wise.

[iliekater]

Thanks a lot guys . I used it and it did work . The only thing I changed was the

Code: [Select]

"0"in the

Code: [Select]

c:doit function , in order to use the layer I want . I suppose you used "0" in order to make sure that the layer should exist so as not to use useless code to see if it exists. Thanks again !

[It's Alive!]

Thanks a lot guys . I used it and it did work . The only thing I changed was the

Code: [Select]

"0"in the

Code: [Select]

c:doit function , in order to use the layer I want . I suppose you used "0" in order to make sure that the layer should exist so as not to use useless code to see if it exists. Thanks again !

Glad it worked 
You should probably add some sort of layer verification method.

[iliekater]

Thanks , don't worry ; I have ! 

[CAB]

I like gile's example.

Code: [Select]

;;  wraper function created by CAB using entmake code by gile
;;  Expects pts to be a list of 2D or 3D points
;;  Returns the ename of the new pline object
(defun makePline (pts    ; list of points
                  closed ; 1 for closed 0 overwise
                  layer  ; if new layer entmake will create it
                  ;;  must be a valid layer name
                  / elv zdir)
  ;;  add zero Z if 2D point list - CAB added
  (setq pts (mapcar '(lambda(x) (if (=(length x)2)(append x '(0.0))x)) pts))
  ;; catch nil layer name - CAB added
  (or layer (setq layer (getvar "CLAYER")))
 
  ;;  code by gile, modified by CAB
  (setq zdir (trans '(0 0 1) 1 0 t)
        elv  (caddr (trans (car pts) 1 zdir))
  )
  (entmakex ; mod by CAB added x
    (append
      (list '(0 . "LWPOLYLINE")
            '(100 . "AcDbEntity")
            '(100 . "AcDbPolyline")
            (cons 8  layer) ; CAB added
            (cons 90 (length pts))
            (cons 70 closed) ; 1 for closed 0 overwise
            (cons 38 elv)
            (cons 210 zdir)
      )
      (mapcar '(lambda (pt) (cons 10 (trans pt 1 zdir))) pts)
    )
  )
)

Code: [Select]

;;  Test the MakePline
(defun c:DrawPline (/ pt ofs ang ll lr ur ul)
  (if (setq pt (getpoint "\nPick point for center of rectangle"))
    (progn
      (setq ofs 50.0
            ang 0.0 ; base angle
      )
      (setq ll (polar pt (- ang (* pi 0.75)) (sqrt (* (* ofs ofs) 2)))
            lr (polar pt (- ang (/ pi 4)) (sqrt (* (* ofs ofs) 2)))
            ur (polar pt (+ ang (/ pi 4)) (sqrt (* (* ofs ofs) 2)))
            ul (polar pt (+ ang (* pi 0.75)) (sqrt (* (* ofs ofs) 2)))
      )
      (makePline (list ll lr ur ul) 1 "LayerName")
    )
  )
  (princ)
)

[It's Alive!]

Interesting, Why the use of entmakex?

Never Mind, .. its in the docs, Nice coding Gile & Cab

[gile]

I like gile's example

Thanks Alan,

But I don't understand why do you add this:

;;  add zero Z if 2D point list - CAB added
  (setq pts (mapcar '(lambda(x) (if (=(length x)2)(append x '(0.0))x)) pts))

As said Joe, entmake works as well with 2D or 3D points and the Z value is dropped off in the final data list.

[CAB]

Because your code

Code: [Select]

elv  (caddr (trans (car pts) 1 zdir))is looking for the Z. I could have conditionally removed that but it seemed to me to be easier to
understand the final code the way I did it. Perhaps & should have only added the Z to the first point only.
OK, this may be better.

Code: [Select]

;;  Expects pts to be a list of 2D or 3D points
;;  Returns the ename of the new pline object
(defun makePline (pts    ; list of points
                  closed ; 1 for closed 0 overwise
                  layer  ; if new layer entmake will create it
                  ;;  must be a valid layer name
                  / zdir elv)
  ;; catch nil layer name - CAB added
  (or layer (setq layer (getvar "CLAYER")))
 
  ;;  code by gile, modified by CAB
  (if (caddr pts)
    (setq zdir (trans '(0 0 1) 1 0 t)
          elv  (caddr (trans (car pts) 1 zdir))
    )
  )
  (entmakex ; CAB added x
    (append
      (list '(0 . "LWPOLYLINE")
            '(100 . "AcDbEntity")
            '(100 . "AcDbPolyline")
            (cons 8  layer) ; CAB added
            (cons 90 (length pts))
            (cons 70 closed) ; 1 for closed 0 overwise
            (if elv (cons 38 elv) '(38 . 0.))
            (if zdir (cons 210 zdir) '(210 0. 0. 1.))
      )
      (mapcar '(lambda (pt) (cons 10 (trans pt 1 zdir))) pts)
    )
  )
)

[gile]

Don't worry with the Z coordinate the trans function will add it if it doesn't exist yet:
(trans '(2 3) 1 1) returns (2.0 3.0 0.0)
so, (setq elv  (caddr (trans (car pts) 1 zdir))) will return 0.0 if (car pts) is a 2D point, the z coordinates overwise.

Try to run (makepline '((0 0) (1 0) (1 1) (0 1)) 1 nil) with this defun:

Code: [Select]

;;  Expects pts to be a list of 2D or 3D points
;;  Returns the ename of the new pline object
(defun makePline (pts ; list of points
  closed ; 1 for closed 0 overwise
  layer ; if new layer entmake will create it
  ;;  must be a valid layer name
  / zdir elv)
  ;; catch nil layer name - CAB added
  (or layer (setq layer (getvar "CLAYER")))

  (setq zdir (trans '(0 0 1) 1 0 t)
elv  (caddr (trans (car pts) 1 zdir))
  )
  (entmakex ; CAB added x
    (append
      (list '(0 . "LWPOLYLINE")
    '(100 . "AcDbEntity")
    '(100 . "AcDbPolyline")
    (cons 8 layer) ; CAB added
    (cons 90 (length pts))
    (cons 70 closed) ; 1 for closed 0 overwise
    (cons 38 elv)
    (cons 210 zdir)
      )
      (mapcar '(lambda (pt) (cons 10 (trans pt 1 zdir))) pts)
    )
  )
)

[CAB]

Silly me for not testing it. I thought trans would choke on a 2D point.
Thanks gile.

[GDF]

Just wanted to play with the routine a little.

I'm sure others can improve on my coding abilities...

Gary

[CAB]

Nothing wrong with that Gary.
I almost always prefer getdist over getreal and I would use this

Code: [Select]

(or a (setq a 0.0))just a personal preference.

Merry Christmas
Alan