Topic: entity help

[crowellsr]

I am having a problem with entities.

I have the user select a point on an entity. It stores the selected point coordinates and the entity name in a variable. I want to get the entity typ and that is where I am havinbg problems. If the entity is a line I am going to run one section of the program and if it is an arc or circle I want it to run another section. If it is neither I want it to display a message such as "please select a line, arc or circle" (don't know how to do this part yet). What do I need to add to my code to get it to determine the entity type and store it in "typ"

(setq ent (entsel "Select point:"))
(setq typ (cdr (assoc 0 ent)))

Steve

[Kerry]

What is the value of ent ?

[crowellsr]

The value of ent is the name of the entity selected and the coordinates of the point selected on the entity.

Steve

[Kerry]

ok, have a look at the ENTSEL help

At the bottom of the page
"See Also"

See anything that may help ?

[MP]

Sorry to jump ahead, but have a look at this --

Code: [Select]

(defun c:MyProggy ( / ent ename data typex )

    (cond
   
        (   (setq ename (car (setq ent (entsel))))
       
            (setq
                data  (entget ename)
                typex (cdr (assoc 0 data))
            )
   
            (cond
   
                (   (member typex '( "ARC" "CIRCLE" ))
                   
                    (princ (strcat "Processing <" typex "> ...\n"))
                   
                    ;;  do ARC / CIRCLE stuff ...
                   
                )               
               
                (   (eq "LINE" typex)
   
                    (princ (strcat "Processing <" typex "> ...\n"))
   
                    ;;  do LINE stuff ...
                )
               
                (   t
   
                    (princ (strcat "DOH! No provision for <" typex "S>.\n"))
   
                )
               
            )
        )
       
        (   t   
       
            (princ "You didn't pick anything so I'm going for coffee.\n")
           
        )           
       
    )

    (princ)
   
)
Couple things to note:

•	The (ssget ":S" '((0 . "arc,circle,line"))) statement as coded limits selection to one entity, and the entity
	must be an arc, circle or line. This statement was misleading at best.
•	I had the impression you'd be processing arcs and circles with the same code, thus they are both captured
	by the statement (member typex '( "ARC" "CIRCLE" )). If this isn't appropriate code up separate
	processing branches like detailed in the line processing (eq "LINE" typex).
•	Time to do some reading, it's all there in the tutorials / references.

Edit1: Sorry Kerry, sometimes I'm too impatient { shrug }.
Edit2: Revised sample code / comments per ensuing discussion.

[Kerry]

Thanks Michael.

I was going to lead him on a treasure hunt to a similar answer.

[Kerry]

Couple things to note:

•	The (ssget ":S" '((0 . "arc,circle,line"))) statement as coded limits selection to one entity, and the entity
	must be an arc, circle or line.

This is not actually correct.
The selection is limited to a single try, not one entity.

[MP]

Thanks Michael.

I was going to lead him on a treasure hunt to a similar answer.

See footnote on last post. I hard started the example before anyone had responded and
by the time I'd finished yoiks, a couple posts:

Warning - while you were typing a new reply has been posted. You may wish to review your post.

But I was already committed (or should be) so I posted it anyway.

[crowellsr]

I looked at entsel in th VisualLISP help but it did not have a See Also at the bottom. I am still unsure of what I am doing wrong. All of the programs I have written up to now have created entities and not had to retreive info from them, so I am really new at this part of it. My program successfully stores the selected coordinates and the entity name but I can't get it to retrieve the entity type. Is it in the VisualLISP help that I should have been looking?

Steve

[MP]

This is not actually correct.
The selection is limited to a single try, not one entity.

Actually it will kind of work if pickauto is 0, which I failed to note. I said kind of because it
doesn't prevent the user from enter "p" at the selection prompt which, as you know, would
retrieve the last selection. So yeah, half baked at best for sure.

If you don't code up a decent alternative for filtered selection of a single entity I'll do one
later, but I've got to get back to work right now.

Thanks for the heads up Kerry and your continued quest for shared knowledge / excellence.

[Kerry]

Steve,
Which ACAD version are you using ?

I was leading you to ENTGET.

[Kerry]

This is not actually correct.
The selection is limited to a single try, not one entity.

Actually it will kind of work if pickauto is 0, .........

Yes, otherwise the user can select [say] crossing and select multiple ents ..

..............
If you don't code up a decent alternative for filtered selection of a single entity I'll do one
later, but I've got to get back to work right now. .......

I think there may be a couple of samples posted here at theSwamp already.
added:
Here's one
http://www.theswamp.org/index.php?topic=6992.0

and another [included]
http://www.theswamp.org/index.php?topic=17720.msg214383#msg214383

[crowellsr]

I am using Landdesktop 2007. Does entget store the coordinates of the point picked also?

Steve

[MP]

Thanks Kerry, I revised my original post accordingly but kept comments
intact so it so it doesn't wreak havoc with the discussion continuity, like
folks who delete their posts on a regular basis.

Edit: Man I can't spell tonight. The benefits of working all weekend I suppose.

[Kerry]

I am using Landdesktop 2007. Does entget store the coordinates of the point picked also?

Steve

no.
examine each of these variables.

Code: [Select]

(SETQ ent (ENTSEL))

(SETQ ename     (CAR ent)
      pickpoint (CADR ent)
      data      (ENTGET ename)
      enttype   (CDR (ASSOC 0 data))
)

[Kerry]

Then have a look at the results of this ..

Code: [Select]

(IF (SETQ ss (SSGET ":S:E" '((0 . "LINE,ARC,CIRCLE"))))
  (SETQ ename   (SSNAME ss 0)
        data    (ENTGET ename)
        enttype (CDR (ASSOC 0 data))
  )
)

[crowellsr]

Thanks Kerry, it now gets the picked point and the type of entity. I can now start woking on the different sections of the program that it is directed to depending on the entity type.

Steve

[CAB]

And to get the pick point with ssget.

Code: [Select]

  (if (setq ss (ssget ":S:E" '((0 . "LINE,ARC,CIRCLE"))))
    (setq ssdata  (ssnamex ss 0)
          ename   (cadar ssdata)
          elist   (entget ename)
          enttype (cdr (assoc 0 data))
          PickPt  (cadr (car (cdddar ssdata)))
    )
  )