Topic: Looking for a script to add file name to specific block and attribute.

[DIW_CADtech]

Ladies and Gentlemen,
I'm looking for a LSP to add the text of the file name to a specific block and a specific attribute of that block.

If anyone has a simple LSP routine to do that.. I'd love to see it.

Any help is appreciated.

[ronjonp]

If it's the name of the drawing you could use a field: %<\AcVar Filename \f "%fn2">%

[DIW_CADtech]

No can do Ronjonp,

Municipality will not accept fields in attributed blocks.  So it has to be text in the attribute.

So the LSP has to read the file name.. and in essance.. type it into the attribute of the block named in the LSP.

Thoughts?

[dgorsman]

Do it as a field (wait - there's more!).  Before returning it, convert the field to simple text either manually or by code.

[DIW_CADtech]

I have three different title blocks I'm trying to populate.. I have LSP routines for 11x17 sheets that break up the file name based on the "-" in the name..
Example... 

Dave-Neu-Dwg.dwg
fills in block attributes
at1 = DAVE
at2 = NEU
at3 = DWG

I have a similar LSP for the 24x36 title blocks

but for drawings we get from the vendor that are TIFF's  we have to use there drawing number block

CLIENT DWG. NO.: <atrribute>

All the previous LSP enter text into the attributes.  I.E. being complient to our CLIENT's CAD standards.. I need the third to

I am recording a macro that will hopefully run all three.. so I can use the same command to update all the title blocks

I.E. Record-->
CLIENT1  (runs LSP for 11x17)
CLIENT2  (runs LSP for 24x36)
CLIENT3  (runs LSP for TIFFS)
end record... name recording CLIENT

I can open all the dwgs  and type.. CLIENT <ENTER> QSAVE <ENTER> CLOSE <ENTER>

(I'd make a SCR and run it in SCRIPTPRO)

[ChrisCarlson]

What happens if the .TIFF filename changes? Is the title block required to update, or only fill in once?

[DIW_CADtech]

I embed the tiff, using Raster tools.  So there is just the file name to contend with.
The title block needs to update just at the time of running the script. 

I've worked on ~2 dozen projects with this client, and once we set the name on existing dwgs (TIFFs) they don't tend to change.  However, we have to generate names in the clients database for the new DWGs.  We don't have a method to delete.. so we have a our own temporary naming system.  Once we get past the Constructability Review.  We enter the DWG names into their database, and finalize the names of the CAD files. 

[DIW_CADtech]

Found one by Lee Mac

(defun c:UPDTNAM (/ ss eLst dNme aEnt aEntLst)
(vl-load-com)
(if (setq ss (ssget "X" (list (cons 0 "INSERT") (cons 2 "TITLEBLOCK") (cons 66 1)
(if (getvar "CTAB")
(cons 410 (getvar "CTAB"))
(cons 67 (- 1 (getvar "TILEMODE")))))))
(progn
(setq eLst (vl-remove-if 'listp (mapcar 'cadr (ssnamex ss)))
dNme (vl-filename-base (getvar "DWGNAME")))
(foreach e eLst
(setq aEnt (entnext e))
(while (not (eq "SEQEND" (cdadr (setq aEntLst (entget aEnt)))))
(if (= "DWGNAM" (cdr (assoc 2 aEntLst)))
(entmod (subst (cons 1 dNme)(assoc 1 aEntLst) aEntLst)))
(setq aEnt (entnext aEnt)))))
(princ "\n<!> No Title Blocks Found <!> "))
(command "_regenall")
(princ))

If you want to modify for your own purposes..

UPDTNAM calls the LSP from the command line
TITLEBLOCK is the name of the block
DWGNAM is the attribute

Thanks Again Lee Mac!!!

[Lee Mac]

Wow - that's some old code!

Here's an updated version which conveniently defines the various parameters at the top of the code, and should also work with dynamic blocks:

Code: [Select]

(defun c:dwgatt ( / blk idx obj sel str tag )
    (setq blk "TITLEBLOCK" ;; Block name (case-insensitive)
          tag "DWGNAM"     ;; Attribute tag (case-insensitive)
          str (vl-filename-base (getvar 'dwgname)) ;; Attribute value
    )
    (if
        (setq sel
            (ssget "_X"
                (list '(0 . "INSERT") '(66 . 1) (cons 2 (strcat "`*U*," blk))
                    (if (= 1 (getvar 'cvport))
                        (cons 410 (getvar 'ctab))
                       '(410 . "Model")
                    )
                )
            )
        )
        (repeat (setq idx (sslength sel))
            (setq obj (vlax-ename->vla-object (ssname sel (setq idx (1- idx)))))
            (if (= (strcase blk) (strcase (vlax-get-property obj (if (vlax-property-available-p obj 'effectivename) 'effectivename 'name))))
                (foreach att (vlax-invoke obj 'getattributes)
                    (if (= (strcase tag) (strcase (vla-get-tagstring att)))
                        (vla-put-textstring att str)
                    )
                )
            )
        )
        (princ (strcat "\nNo \"" blk "\" blocks found in the current layout."))
    )
    (princ)
)
(vl-load-com) (princ)
(the above is untested)

Happy to help DIW!

[DIW_CADtech]

I'm getting a submittal out.. the old code works, but I'm more than happy to "Refresh" it. with the above...  I will test on Monday.

[DIW_CADtech]

The above code works great.. only addition I made was to add a

(command "_regenall")
above the
(princ))

Works great.
Thanks Lee Mac

"Donate to Lee Mac"
google AutoCAD Lee Mac  you'll find the page..   He's a man on a mission.

[Lee Mac]

Many thanks indeed DIW, I'm glad the code works well.