Topic: ObjectDBX and attributes: Doesn't work?

[ArgV]

I see there is a post right below this one about the same topic, but I'm still wondering because I'm doing the same thing.... trying to update attributes in several (thousand) drawings with ODBX. It changes the textstring, but if you go in to the drawing after saving it, and double click the block containing the attribute, it's still the same name. However, if you go INTO the block, the textstring for the attribute is correct. ??

I'm gonna google it, but I thought maybe someone had some super special inside info that I'm not aware of. 

[Lee Mac]

What are you trying to change? The attribute in each INSERT or the attribute definition in the block table? For the latter you will need a regen at least. For the former, I created a program here.

[ArgV]

What are you trying to change? The attribute in each INSERT or the attribute definition in the block table? For the latter you will need a regen at least. For the former, I created a program here.

both.

I seen the one you wrote there, but I can't really use it, as I don't know the names of all the attributes, and there are many thousands.

So, what do you have to do to get it to work right? I guess something to do with the block table definition. I'll look into that I suppose.

[MP]

Consider posting a drawing c/w with typical list of search and replace operations you want to execute, or a complete before | after sample.

[Lee Mac]

What are you trying to change? The attribute in each INSERT or the attribute definition in the block table? For the latter you will need a regen at least. For the former, I created a program here.

both.

I seen the one you wrote there, but I can't really use it, as I don't know the names of all the attributes, and there are many thousands.

So, what do you have to do to get it to work right? I guess something to do with the block table definition. I'll look into that I suppose.

As you don't know the names of all the attributes, I assume you want to perform the same change on all of them. If you are just changing the attribute values within the INSERTS, then you would just need to cycle through each object in each layout in the dbx document, and for every attibuted block you come across, cycle through its attributes and make your changes.

For the attribute definitions, you would need to cycle through the objects in the block definition, and make your changes there. And make sure you perform a save on the drawing to save changes.

Lee

[ArgV]

What are you trying to change? The attribute in each INSERT or the attribute definition in the block table? For the latter you will need a regen at least. For the former, I created a program here.

both.

I seen the one you wrote there, but I can't really use it, as I don't know the names of all the attributes, and there are many thousands.

So, what do you have to do to get it to work right? I guess something to do with the block table definition. I'll look into that I suppose.

As you don't know the names of all the attributes, I assume you want to perform the same change on all of them. If you are just changing the attribute values within the INSERTS, then you would just need to cycle through each object in each layout in the dbx document, and for every attibuted block you come across, cycle through its attributes and make your changes.

For the attribute definitions, you would need to cycle through the objects in the block definition, and make your changes there. And make sure you perform a save on the drawing to save changes.

Lee

Yes, there is, depending on the name of the folder the drawings are in, the attribute and block name will change, so I have the nomenclature, but not the knowhow.

Uhm.. I went through the block and changed the "textString" property, is that not enough? There is no paperspace objects to worry about, only the entities that reside in modelspace.

thanks again, Lee.

[Lee Mac]

If you want to change the attributes in the INSERTs in ModelSpace, you will have to iterate through every object in the ModelSpace 'block', and change each INSERT's attributes.

e.g.

Code: [Select]

(defun c:test (/ obj)
  (vl-load-com)

  (vlax-for obj (vla-get-ModelSpace
                  (vla-get-ActiveDocument
                    (vlax-get-acad-object)))
   
    (if (eq "AcDbBlockReference"
            (vla-get-ObjectName obj))
     
      (vla-put-layer obj "0")))

  (princ))


[ArgV]

If you want to change the attributes in the INSERTs in ModelSpace, you will have to iterate through every object in the ModelSpace 'block', and change each INSERT's attributes.

e.g.

Code: [Select]

(defun c:test (/ obj)
  (vl-load-com)

  (vlax-for obj (vla-get-ModelSpace
                  (vla-get-ActiveDocument
                    (vlax-get-acad-object)))
   
    (if (eq "AcDbBlockReference"
            (vla-get-ObjectName obj))
     
      (vla-put-layer obj "0")))

  (princ))


ok, so I use something like this:

Code: [Select]

(defun editModelSpaceAttribute (/ doc ms item)
  (vl-load-com)
  (setq doc (vla-get-activedocument (vlax-get-acad-object))
ms (vla-get-modelspace doc))

  (vlax-for item ms
    (if
      (= (vla-get-objectname item) "AcDbBlockReference")
      (progn
      (setq item (apply 'vla-item (list (vla-get-blocks doc) (vla-get-name item))))
      (vlax-for i item
(if
  (= (vla-get-objectname i) "AcDbAttributeDefinition")
  (progn
    (vla-put-textstring i "Test")
    (vla-update i)
    )
  )
  )
)
      )
    )
  )

but this only updates the string when you open the block.. the attribute definition seems to not change at all.

[Lee Mac]

You are editing the attribute definition within the block definition, not the attribute within the insert.

You would need to use something like this:

Code: [Select]

(vlax-for obj (vla-get-ModelSpace
                (vla-get-ActiveDocument (vlax-get-acad-object)))

  (if (and (eq "AcDbBlockReference" (vla-get-ObjectName obj))
           (eq :vlax-true (vla-get-hasAttributes obj)))

    (foreach att (vlax-invoke obj 'GetAttributes)
      (vla-put-TextString att "test"))))

Of course, this is only working on the ActiveDocument, and only in ModelSpace. If you were using ODBX, you would use the ObjectDBX Document, and perhaps iterate through all the layouts.

Lee

[ArgV]

You are editing the attribute definition within the block definition, not the attribute within the insert.

You would need to use something like this:

Code: [Select]

(vlax-for obj (vla-get-ModelSpace
                (vla-get-ActiveDocument (vlax-get-acad-object)))

  (if (and (eq "AcDbBlockReference" (vla-get-ObjectName obj))
           (eq :vlax-true (vla-get-hasAttributes obj)))

    (foreach att (vlax-invoke obj 'GetAttributes)
      (vla-put-TextString att "test"))))

Of course, this is only working on the ActiveDocument, and only in ModelSpace. If you were using ODBX, you would use the ObjectDBX Document, and perhaps iterate through all the layouts.

Lee

well that worked. Thank you! I was about to pull out what little hair I have left on my head.

I'd tried using "vla-getattributes" but it wasn't working??? wel, thanks again.

[Lee Mac]

You're welcome

I'd tried using "vla-getattributes" but it wasn't working??? wel, thanks again.

If you really wanted to use vla-getAttributes:

Code: [Select]

(vlax-for obj (vla-get-ModelSpace
                (vla-get-ActiveDocument (vlax-get-acad-object)))

  (if (and (eq "AcDbBlockReference" (vla-get-ObjectName obj))
           (eq :vlax-true (vla-get-hasAttributes obj)))

    (foreach att (vlax-safearray->list
                   (vlax-variant-value
                     (vla-getAttributes obj)))
     
      (vla-put-TextString att "test"))))


[ArgV]

You're welcome

I'd tried using "vla-getattributes" but it wasn't working??? wel, thanks again.

If you really wanted to use vla-getAttributes:

Code: [Select]

(vlax-for obj (vla-get-ModelSpace
                (vla-get-ActiveDocument (vlax-get-acad-object)))

  (if (and (eq "AcDbBlockReference" (vla-get-ObjectName obj))
           (eq :vlax-true (vla-get-hasAttributes obj)))

    (foreach att (vlax-safearray->list
                   (vlax-variant-value
                     (vla-getAttributes obj)))
     
      (vla-put-TextString att "test"))))


ok, so now I'm a little confused. why is there a difference between the vlax-invoke method and the vla-getattributes method?

I realize it's just a return type, but it seems strange to me that they would be so different.  They must have done attributes on a monday. haha.

[Lee Mac]

Its the same for all the VL methods / properties,

vlax-invoke / vlax-get will return lists.
vlax-invoke-method / vlax-get-property will return variants.

[ArgV]

Its the same for all the VL methods / properties,

vlax-invoke / vlax-get will return lists.
vlax-invoke-method / vlax-get-property will return variants.

So I see. And I guess the attribute definitions are saved within the modelspace block, and the attribute within the insert means almost nothing. Hmm.. I'm sure after a few years of using autocad I'll figure it all out.

thanks for the lesson.

[Lee Mac]

So I see. And I guess the attribute definitions are saved within the modelspace block, and the attribute within the insert means almost nothing. Hmm.. I'm sure after a few years of using autocad I'll figure it all out.

thanks for the lesson.

You're welcome.

The attribute definitions are contained in the Block Definition (within the block table), and each block reference or 'insert' holds the attribute object containing the Tag and Value for that attribute.

Lee