Topic: Maybe I'm just thick - Cond question...

[CHulse]

OK, maybe I'm just thick. Is one of these 2 snippets correct? Are they the same? 

Code - Auto/Visual Lisp: [Select]

1.                                 (cond
2.                                         ((not(or(equal "UPD Not Found" TXT1) (equal "" TXT1)))
3.                                                 (setq TXT TXT1)
4.                                         )
5.                                        
6.                                         ((not(or(equal "UPD Not Found" TXT2) (equal "" TXT2)))
7.                                                 (setq TXT TXT2)
8.                                         )
9.                                                
10.                                         ((not(equal "" FULL))
11.                                                 (setq TXT FULL)
12.                                         )
13.                                                
14.                                         ( T
15.                                                 (setq TXT "NO TAG#")
16.                                         )
17.                                 );;_end cond
18.  

Code - Auto/Visual Lisp: [Select]

1.                         (setq TXT
2.                                 (cond
3.                                         ((not(or(equal "UPD Not Found" TXT1) (equal "" TXT1)))
4.                                                 (TXT1)
5.                                         )
6.                                        
7.                                         ((not(or(equal "UPD Not Found" TXT2) (equal "" TXT2)))
8.                                                 (TXT2)
9.                                         )
10.                                                
11.                                         ((not(equal "" FULL))
12.                                                 (FULL)
13.                                         )
14.                                                
15.                                         ( T
16.                                                 ("NO TAG#")
17.                                         )
18.                                 );;_end cond   
19.                         );;_end setq
20.  

[JohnK]

#2 is better. #1 reads like a second-grader's writing practice.

In essence, #2 reads like this: "Define the `TXT` variable and fill it with the results of the following conditional." #2 is a very common construct.

[d2010]

If you have C++ experinced, then
--you replace
   (equal "UPD Not Found" TXT2)
--with
   (equal TXT2 "UPD Not Found").

[CHulse]

Thanks guys
I've got a gremlin I can't ferret out and I thought it was this. I thought #2 was correct, but keep getting a nil return. I shall look elsewhere...

Why does the order of the elements matter after the "equal"?

Much appreciated.

[JohnK]

The order of the elements matters in the higher order languages because of the "=" and "==" functions. One "tests" and the other "sets" equality.

It looks like your variable `TXT` will/should have at worse case contain "NO TAG#". Tracking down Booleans is difficult (first reason why #1 above is "incorrect" and #2 is "correct"). ...people love to toss around '(or (this) (that) (dosomething (somethingelse (setq...))))' around their code with very little thought about the returns of those statements.

[CHulse]

Helpful, thank you. I'm struggling to get better at this and be able to do more than just stealing and tweaking other's programs.

I am still stumped by this though. The logic here seems sound to me, and I think the construct is correct, but it isn't assigning a value to TXT (always nil).

The watch shows me this:
TXT = nil
TAG2 = "598"
TAG1 = "UPD Not Found"
FULL = "t598"

So the second cond should return T correct?
Either way, TXT should get "NO TAG#" if nothing else, and it isn't.
I'm clearly missing something...

Code - Auto/Visual Lisp: [Select]

1.                         (setq TXT
2.                                 (cond
3.                                         ((not(or(equal "UPD Not Found" TXT1) (equal "" TXT1)))
4.                                                 TXT1
5.                                         )
6.                                        
7.                                         ((not(or(equal "UPD Not Found" TXT2) (equal "" TXT2)))
8.                                                 TXT2
9.                                         )
10.                                                
11.                                         ((not (null FULL))
12.                                                 FULL
13.                                         )
14.                                                
15.                                         ( T
16.                                                 "NO TAG#"
17.                                         )
18.                                 );;_end cond   
19.                         );;_end setq
20.  

[JohnK]

What--exactly--your statement is doing at a specific point in operation is a bit vague (we don't have enough information really to comment on which statement will be true) but this COND construct will not return TRUE/NIL it will return the value of the expression.

For example see if you can determine what var2 will be set to.

Code - Auto/Visual Lisp: [Select]

1. (setq var1 1)
2. (setq var2
3.       (cond
4.         ((eq var1 7) var1)
5.         ((eq var1 6) "twenty one")
6.         ((eq var1 1) 42)))

It looks to me as your variable `txt` should be set to `no tag#` (the last condition). What is the `txt` variable supposed to do?

[kdub_nz]

>> . .
--you replace
   (equal "UPD Not Found" TXT2)
--with
   (equal TXT2 "UPD Not Found").

It's not often I see the point of d2010 posts but in this case I agree.

'is the value of X "yes" '

[Jeff_M]

Is it TAG1 & TAG2 or TXT1 & TXT2 ?  What your Watch says vs the code.

[CHulse]

OMG. I have the variables named wrong. 
Any wonder it doesn’t work.
Thanks.

[ronjonp]

FWIW this:

Code - Auto/Visual Lisp: [Select]

1. (or (equal "UPD Not Found" txt1) (equal "" txt1))

Could be this:

Code - Auto/Visual Lisp: [Select]

1. (wcmatch txt1 "UPD Not Found,")

[CHulse]

FWIW this:

Code - Auto/Visual Lisp: [Select]

1. (or (equal "UPD Not Found" txt1) (equal "" txt1))

Could be this:

Code - Auto/Visual Lisp: [Select]

1. (wcmatch txt1 "UPD Not Found,")

Interesting
Thanks Ron

[ronjonp]

FWIW this:

Code - Auto/Visual Lisp: [Select]

1. (or (equal "UPD Not Found" txt1) (equal "" txt1))

Could be this:

Code - Auto/Visual Lisp: [Select]

1. (wcmatch txt1 "UPD Not Found,")

Interesting
Thanks Ron

Anytime

[BIGAL]

For me a simpler way to read the cond

Code: [Select]

     (cond
             ((wcmatch txt1 "UPD Not Found")(setq txt TXT1))
             ((wcmatch txt2 "UPD Not Found")(setq txt TXT2))
             ((null FULL)(setq txt full))
             ((setq txt "NO TAG#"))
     );;_end cond

[bruno_vdh]

Hello,
FWIW this:

Code - Auto/Visual Lisp: [Select]

1. (not(or(equal "UPD Not Found" TXT1) (equal "" TXT1)))

Could be this:

Code - Auto/Visual Lisp: [Select]

1. (/= "UPD Not Found" txt1 "")

[bruno_vdh]

OK, maybe I'm just thick. Is one of these 2 snippets correct? Are they the same? 

#1 can be written with or, while #2 can only be constructed with cond, if that helps your thinking...

[ronjonp]

For me a simpler way to read the cond

Code: [Select]

     (cond
             ((wcmatch txt1 "UPD Not Found"))(setq txt TXT1))
             ((wcmatch txt2 "UPD Not Found"))(setq txt TXT2))
             ((null FULL))(setq txt full)
             ((setq txt "NO TAG#"))
     );;_end cond

"Unbalanced closing brackets."

Also .. you can pull the (setq txt outside of the COND and only return the values.

[BIGAL]

Thanks ronjonp just typed did not check

Code: [Select]

(cond
             ((wcmatch txt1 "UPD Not Found")(setq txt TXT1))
             ((wcmatch txt2 "UPD Not Found")(setq txt TXT2))
             ((null FULL)(setq txt full))
             ((setq txt "NO TAG#"))
     );;_end cond

[steve.carson]

I know when I first started using cond, I always got tripped up by the parenthesis so I would type something like this first, just to keep things straight in my head:

Code - Auto/Visual Lisp: [Select]

1. (cond
2.     ((         ) ;<-- First test
3.         (          ) ;<-- Do this
4.         (          ) ;<-- And this
5.     )
6.     ((         ) ;<-- Second test
7.         (          ) ;<-- Do this
8.         (          ) ;<-- And this
9.     )
10.     ((         ) ;<-- Third test
11.         (          ) ;<-- Do this
12.         (          ) ;<-- And this
13.     )
14. ); cond
15.  

And then go back and start filling it in with what I want it to do.

[CHulse]

This is what I eventually ended up with (and is working nicely).
Thanks to everyone for the help with this.

Code - Auto/Visual Lisp: [Select]

1.                         (setq TXT
2.                                 (cond
3.                                         ((not(or (wcmatch TAG1 "UPD Not Found,0,")(null TAG1))) ;;check if UDP not found, empty string, 0, or null
4.                                                 TAG1
5.                                         )
6.                                         ((not(or(wcmatch TAG2 "UPD Not Found,0,")(null TAG2)))
7.                                                 TAG2
8.                                         )
9.                                         ((not(or(wcmatch FULL "0,")(null FULL) ))  
10.                                                 FULL
11.                                         )      
12.                                         ( T
13.                                                 "NO TAG#"
14.                                         )
15.                                 );;_end cond   
16.                         );;_end setq
17.  

[bruno_vdh]

Hi,

This is what I eventually ended up with (and is working nicely).

Just a small note, it is better to check if the variable is null first:

Code: [Select]

_$ (setq TAG1 nil)
nil
_$ (not (or (wcmatch TAG1 "UPD Not Found,0,") (null TAG1)))
; erreur: type d'argument incorrect: stringp nil
_$ (not (or (null TAG1) (wcmatch TAG1 "UPD Not Found,0,")))
nil

[bruno_vdh]

Just a small note, it is better to check if the variable is null first:

Code: [Select]

_$ (setq TAG1 nil)
nil
_$ (not (or (wcmatch TAG1 "UPD Not Found,0,") (null TAG1)))
; erreur: type d'argument incorrect: stringp nil
_$ (not (or (null TAG1) (wcmatch TAG1 "UPD Not Found,0,")))
nil

To avoid type errors, you can also use the member function as a predicate

Code - Auto/Visual Lisp: [Select]

1. (not (member TAG1 '("UPD Not Found" "0" "" nil)))