Topic: Get Layer Object from LayerName

[mailmaverick]

How to get Layer Object from layername as string for doing various operations such as (vla-put-LayerOn Layerobj :vlax-false).

I am aware of command line method but i want to use the vla- method.

[Kerry]

Where are Layers stored ?

How do you access an item in a collection ?

[irneb]

Example

Code - Auto/Visual Lisp: [Select]

1. (vla-Item (vla-get-Layers (vla-get-ActiveDocument (vlax-get-acad-object))) "MyLayerName")

Note that throws an error if the layer doesn't exist, so you might have to wrap it inside a vl-catch-all-apply.

[Kerry]

I was teaching fishing irne, not selling filleted snapper.

[Kerry]

acadauto.chm 
for 2013 and later have VLisp examples as well as VBA

Search for LayerOn
-> Example

Visual LISP Example

Code - Auto/Visual Lisp: [Select]

1.  
2. (vl-load-com)
3. (defun c:Example_LayerOn()
4.     ;; This example creates a new layer called "LayerOn".
5.     ;; It then displays the status of the LayerOn property
6.     ;; for the new layer, toggles the status of the
7.     ;; LayerOn property, and again displays its status.
8.     ;; After running this example, you can check the layer
9.     ;; control on the Object Properties tool bar. It will
10.     ;; show the new layer and the latest LayerOn status.
11.     (setq acadObj (vlax-get-acad-object))
12.     (setq doc (vla-get-ActiveDocument acadObj))
13.  
14.     ;; Create the new layer
15.     (setq layerObj (vla-Add (vla-get-Layers doc) "LayerOn"))
16.    
17.     ;; Display the LayerOn status of the new layer
18.     (if (= (vla-get-LayerOn layerObj) :vlax-true)
19.         (alert (strcat "Layer " (vla-get-Name layerObj) " is turned on."))
20.         (alert (strcat "Layer " (vla-get-Name layerObj) " is turned off."))
21.     )
22.  
23.     ;; Toggle the status of the LayerOn property for the layer
24.     (vla-put-LayerOn layerObj (if (= (vla-get-LayerOn layerObj) :vlax-true) :vlax-false :vlax-true))
25.    
26.     ;; Display the LayerOn status of the new layer
27.     (if (= (vla-get-LayerOn layerObj) :vlax-true)
28.         (alert (strcat "Layer " (vla-get-Name layerObj) " is turned on."))
29.         (alert (strcat "Layer " (vla-get-Name layerObj) " is turned off."))
30.     )
31. )
32.  
33.  

[irneb]

I was teaching fishing irne, not selling filleted snapper.

I thought I'd spoon feed a bit ... note I even attached the bib with the catch-all-apply comment 

[Kerry]

And some pre-digested stuff with the bib attached for the Library.
 ... you do keep a Library, don't you ?

Code - Auto/Visual Lisp: [Select]

1.  
2. ;;------------------------------------------------------------------
3. ;;;------------------------------------------------------------------
4. ;; Makes the Layer if reqd and sets active and returns Layer Object
5. ;;; (setq layername "ST-WELDx") (kdub:assertactivelayer layername)
6. ;;
7. (defun kdub:assertactivelayer (layername / iacadlayer)
8.   (if (setq iacadlayer (kdub:assertlayer layername))
9.     (vla-put-activelayer
10.       (vla-get-activedocument (vlax-get-acad-object))
11.       iacadlayer
12.     )
13.   )
14.   iacadlayer
15. )
16. ;;;------------------------------------------------------------------
17. ;;;------------------------------------------------------------------
18. ;;; Makes the Layer if reqd and returns Layer Object
19. ;;; (kdub:assertLayer "ST25x")
20. ;;
21. (defun kdub:assertlayer (layername / iacadlayer)
22.   (if (vl-catch-all-error-p
23.         (setq iacadlayer
24.                (vl-catch-all-apply
25.                  'vla-add
26.                  (list (vla-get-layers
27.                          (vla-get-activedocument (vlax-get-acad-object))
28.                        )
29.                        layername
30.                  )
31.                )
32.         )
33.       )
34.     nil
35.     iacadlayer
36.   )
37. )
38. ;;;------------------------------------------------------------------
39. ;;;------------------------------------------------------------------
40. ;;;
41.  
42.  

[irneb]

... you do keep a Library, don't you ?

Nah! Just throw it on the floor 

Seriously though. Kerry makes a very good point. It's one of the main reasons the convention is to have each function do only one thing. That way you can have all these functions in a library and simply call them instead of copy-pasting (or worse re-writing) code again and again.

For me I'd split this LayerOn function into at least 3:

Code - Auto/Visual Lisp: [Select]

1. (defun ib:ActiveDocument () (vl-load-com) (vla-get-ActiveDocument (vlax-get-acad-object)))
2.  
3. (defun ib:GetLayerObject  (Doc Name / result)
4.   (if (not (vl-catch-all-error-p
5.              (setq result (vl-catch-all-apply 'vla-Item (list (vla-get-Layers Doc) Name)))))
6.     result))
7.  
8. (defun ib:LayerOn (Doc Name On / layObj)
9.   (if (setq layObj (ib:GetLayerObject Doc Name))
10.     (vla-put-LayerOn layObj On)))
11.  
12. ;; Example:
13. ;; (ib:LayerOn (ib:ActiveDocument) "MyLayer" :vlax-on)

That way the same code would even be usable if the document is an ObjectDBX document.

[Kerry]

< .. > It's one of the main reasons the convention is to have each function do only one thing. That way you can have all these functions in a library and simply call them instead of copy-pasting (or worse re-writing) code again and again.
< ..>

Yes Irne, that's what I do with my production code.
The functions I posted actually have been modified to make them more palatable here.

Personally I attempt to design modular functions (where practical) to follow the Single Responsibility Principle
This makes testing a breeze.

[ronjonp]

And a mishmash: 

Code: [Select]

(defun _layob (name / l)
  (if (setq l (tblobjname "layer" name))
    (vlax-ename->vla-object l)
  )
)
;; (_layob "0")

[mailmaverick]

RON's method is the best and fastest too.

Code: [Select]

(defun c:test ()
;;; 1.) RON's method
  (setq Start (getvar "Millisecs"))
  (repeat 25000 (setq cv (_layob "0")))
  (setq End (getvar "Millisecs"))
  (setq yu (- End Start))
  (setq yu (/ yu 1000.00))
  (princ "\nTime Taken to Run in Ron's Method : ")
  (princ yu)
  (princ " seconds \n")
;;; 2.) IRNEB's 1st method
  (setq Start (getvar "Millisecs"))
  (repeat 25000
    (setq
      cv (vla-Item (vla-get-Layers
     (vla-get-ActiveDocument (vlax-get-acad-object))
   )
   "0"
)
    )
  )
  (setq End (getvar "Millisecs"))
  (setq yu (- End Start))
  (setq yu (/ yu 1000.00))
  (princ "\nTime Taken to Run in IRNEB's 1st Method : ")
  (princ yu)
  (princ " seconds \n")
;;; 3.) IRNEB's 2nd method
  (setq Start (getvar "Millisecs"))
  (repeat 25000
    (setq cv (ib:GetLayerObject
       (vla-get-ActiveDocument (vlax-get-acad-object))
       "0"
     )
    )
  )
  (setq End (getvar "Millisecs"))
  (setq yu (- End Start))
  (setq yu (/ yu 1000.00))
  (princ "\nTime Taken to Run in IRNEB's 2nd Method : ")
  (princ yu)
  (princ " seconds \n")
  (princ)
)

(defun _layob (name / l)
  (if (setq l (tblobjname "layer" name))
    (vlax-ename->vla-object l)
  )
)

(defun ib:GetLayerObject (Doc Name / result)
  (if (not (vl-catch-all-error-p
     (setq result (vl-catch-all-apply
    'vla-Item
    (list (vla-get-Layers Doc) Name)
  )
     )
   )
      )
    result
  )
)

Results :
Time Taken to Run in Ron's Method : 1.279 seconds

Time Taken to Run in IRNEB's 1st Method : 2.496 seconds

Time Taken to Run in IRNEB's 2nd Method : 2.636 seconds

[dgorsman]

< .. > It's one of the main reasons the convention is to have each function do only one thing. That way you can have all these functions in a library and simply call them instead of copy-pasting (or worse re-writing) code again and again.
< ..>

Yes Irne, that's what I do with my production code.
The functions I posted actually have been modified to make them more palatable here.

Personally I attempt to design modular functions (where practical) to follow the Single Responsibility Principle
This makes testing a breeze.

And upgrades as well.  Treat it as a black box (small "b"    ), and as long as the inputs and outputs are the same what's inside doesn't matter.

[Kerry]

 

I think ronjonp's method is the best.

Yes, I like ron's offering.

I'm not arguing with you, but I wonder how/why you came to that determination ?
and what do you mean by "best" ?

[Kerry]

< .. > It's one of the main reasons the convention is to have each function do only one thing. That way you can have all these functions in a library and simply call them instead of copy-pasting (or worse re-writing) code again and again.
< ..>

Yes Irne, that's what I do with my production code.
The functions I posted actually have been modified to make them more palatable here.

Personally I attempt to design modular functions (where practical) to follow the Single Responsibility Principle
This makes testing a breeze.

And upgrades as well.  Treat it as a black box (small "b"    ), and as long as the inputs and outputs are the same what's inside doesn't matter.

Yes David, I agree.

Had a cackle about the (small "b"    )   

[alanjt]

I love the way you make people work for their knowledge, Kerry. I know it's benefited me over the years.

[Kerry]

I love the way you make people work for their knowledge, Kerry. I know it's benefited me over the years.

Nah, I'm just a nasty bastard who enjoys inflicting pain.

[BlackBox]

Example

Code - Auto/Visual Lisp: [Select]

1. (vla-Item (vla-get-Layers (vla-get-ActiveDocument (vlax-get-acad-object))) "MyLayerName")

Note that throws an error if the layer doesn't exist, so you might have to wrap it inside a vl-catch-all-apply.

FWIW -

The Add() Method will yield an existing, or create a new LayerTableRecord for the LayerName (string) passed, which is great for reactors that set a specific layer current prior to a given command execution, etc.

For the OP's situation though, the Item() Method is perfectly fine, given that the string passed is from a selected entity.

Cheers

[Kerry]

< .. >  but i want to use the vla- method.

mailmaverick,
When did you change your mind about what you wanted ?

1.2 seconds time difference for 25,000 iterations is miniscule.

I probably spend longer than that every 5 minutes finding a key on the keyboard.

Just to be fair , what happens is you run each of those routines on a drawing which doesn't contain the layer you want ?

[alanjt]

I love the way you make people work for their knowledge, Kerry. I know it's benefited me over the years.

Nah, I'm just a nasty bastard who enjoys inflicting pain.

lol. Well, then I enjoy watching you annoying the hell out of everyone. 

[Kerry]

[< .. >
For the OP's situation though, the Item() Method is perfectly fine, given that the string passed is from a selected entity.

Cheers

I didn't know that (must have missed the memo) . If so, all the rules change.

[BlackBox]

[< .. >
For the OP's situation though, the Item() Method is perfectly fine, given that the string passed is from a selected entity.

Cheers

I didn't know that (must have missed the memo) . If so, all the rules change.

I must have confused two different threads, regarding the selected entity part.