Topic: Insert New Block above existing Block in Layout tabs

[Fett2oo5]

I'm just a beginner but have big wishes and goals.  I'm looking for a way to add revision blocks to multiple layout tabs (single .dwg file) at one time.

Per project, we design our product in 2D, in one .dwg file.  AutoCAD 2013.
We use the layout tabs for multiple views of the objects that are in modelspace, (each layout tab has the project titleblock on it, but each layout tab has its own set of revision blocks.)
We "stack" the revision blocks in the Y direction, please see first screenshot)

There are times in the project when ALL layout tabs need the same revision description. For example, Issue for Construction, P.E. comments, As Built... etc.  This was previously done by inserting the revision block, editing attributes, Copy-Basepoint, switching to each layout tab, and pasting above the existing RevBlk.

So we would like to be able to insert a revision block into each layout tab using a dialog box or excel.

Explained simply (hopefully): The routine would find the revision block (RevBlk) with the largest Y value (because we "stack" the revision blocks in the Y direction, please see example) and insert a new revision block (RevBlk) above it.  The height (in Y direction) of the block is .1271, so the new RevBlk would need it's insertion point @0,.1271,0 in relation to the existing RevBlk with the highest Y value.  Please see first screenshot:




Our Layout Tab labels follow this sequence:


Following that numbering sequence these are possible but not so frequent:




It would be nice if we could control the insertion of new revisions from a dialog box:
(the routine would need to detect what tabs were available?)
I'm sorry for the way it looks, the only way I know how to make one is in Excel's VBA



This routine would be a sub-part of other sequences, but I need to start here before it gets bigger.
So I'm hoping this smaller task will help me along with the larger endeavor.

***
I've reached out for help in a few places but to no avail.

Is this too ambitious?
Perhaps I could piece this together?

1. Find the insertion points of a particular block across all layout tabs. (block name will never change: RevBlk)

2. Prompt user for new attribute values, preferably in a dialog box as shown above.

3.Insert the same block (RevBlk, it will already be loaded into drawing) at the largest Y value of another RevBlk +.1271, across all layout tabs.

The part that is tripping me up is the "across all layout tabs"

If no code solution is available; links to examples, tutorials, similar situations, anything will help.

[ronjonp]

Welcome to TheSwamp! .. Here's a quick example without user input how to copy & increment the revision block value on each layout tab. I've added comments so you can learn from it .

Code - Auto/Visual Lisp: [Select]

1. (defun c:revs ;; Localized variables & functions
2.               (/ _dxf _copy _getattval _setattval blks co o rev ss)
3.   (vl-load-com)
4.   ;; < / Helper functions
5.   (defun _dxf (code ename)
6.     (if (and ename (= (type ename) 'ename))
7.       (cdr (assoc code (entget ename '("*"))))
8.     )
9.   )
10.   (defun _getattval (block tag / att out)
11.     (foreach att (vlax-invoke block 'getattributes)
12.       (if (eq (strcase tag) (strcase (vla-get-tagstring att)))
13.         (setq out (vla-get-textstring att))
14.       )
15.     )
16.     out
17.   )
18.   (defun _setattval (block tag value / att out)
19.     (foreach att (vlax-invoke block 'getattributes)
20.       (if (eq (strcase tag) (strcase (vla-get-tagstring att)))
21.         (setq out (vla-put-textstring att value))
22.       )
23.     )
24.     out
25.   )
26.   (defun _copy (obj from to / out)
27.     (cond ((setq out (vlax-invoke obj 'copy)) (vlax-invoke out 'move from to) (vla-update out) out))
28.   )
29.   ;; Helper functions \ >
30.   ;;
31.   ;; Foreach paperspace tab
32.   (foreach tab (layoutlist)
33.     ;; If we find 'revblk'(s) on that tab
34.     (if (and (setq ss (ssget "_X" (list '(0 . "insert") (cons 410 tab) '(2 . "RevBlk"))))
35.              ;; Convert the selection set to a list
36.              (setq ss (mapcar 'cadr (ssnamex ss)))
37.              ;; Sort the blocks by greatest Y value & grab the first item
38.              (setq ss (car (vl-sort ss '(lambda (a b) (> (caddr (_dxf 10 a)) (caddr (_dxf 10 a)))))))
39.              ;; Add the first item ( greatest Y ) to a 'blks' list
40.              (setq blks (cons ss blks))
41.         )
42.       ;; Iterate the 'blks' list
43.       (foreach blk blks
44.         (if (and ;; Convert block from 'ename' to vla-object
45.                  (setq o (vlax-ename->vla-object blk))
46.                  ;; Make a copy + 0.127148 in the Y
47.                  (setq co (_copy o '(0.0 0.0 0.0) '(0.0 0.127148 0.0)))
48.             )
49.           (progn ;; Check that the att value is a number
50.                  (or (and (setq rev (_getattval o "R#"))
51.                           (numberp (read rev))
52.                           ;; Increment the value by 1
53.                           (setq rev (itoa (1+ (atoi rev))))
54.                      )
55.                      ;; Or set it to 0
56.                      (setq rev "0")
57.                  )
58.                  ;; Set new attribute values in the copied block
59.                  (_setattval co "R#" rev)
60.                  (_setattval co "REVl1" (strcat "DESCRIPTION FOR REV - " rev))
61.                  (_setattval co "REVB" "YODA")
62.                  (_setattval co "REVD" (menucmd "M=$(edtime,$(getvar,date),M\"/\"YY)"))
63.           )
64.         )
65.       )
66.     )
67.   )
68.   (princ)
69. )

[Fett2oo5]

Wow, Ron that is very nice!  And works wonderfully!

That is a big head-start to get this thing rolling.

Thank you very much!

Ron, when I run it:  It will place a new block (RevBlk) above the existing one, but it will also place #.  # being the amount of layout tabs there are.
So if there are 6 Layout tabs, a quantity of 6 blocks will be inserted.  I'm learning/sifting through it to find where this is happening.


And thank you for the welcome, I've been a lurker here for a while now, and it was time I became more involved.  I'm excited about learning as much as I can.

[BlackBox]

Forgive what might be a silly question, but have you considered simply using Sheet Set Manager (SSM) custom Properties, to populate your attributed title block(s), etc with FIELDs?

Cheers

[Fett2oo5]

Well my new friends, I've got some bad news.

I was told I am going to be laid off.  I'm to finish my current design/engineering projects and after about 2 weeks I'll need to find a new employer.

So I won't be able to put much attention (if any) on this project for a little bit. If you are interested in this project please subscribe to it.

As for this project thread, I'm going to make the DCL that I was referencing in the OP, and then we could go from there?

Thank you for the help so far.  I'm not going to give up on this project thread, but I can not devote the time to it in the next few weeks as I hoped I could.
Know that I will be coming back to this project I feel it is to versatile and useful to let it die.

I hope to be back posting soon.

[ronjonp]

Well my new friends, I've got some bad news.

I was told I am going to be laid off.  I'm to finish my current design/engineering projects and after about 2 weeks I'll need to find a new employer.

So I won't be able to put much attention (if any) on this project for a little bit. If you are interested in this project please subscribe to it.

As for this project thread, I'm going to make the DCL that I was referencing in the OP, and then we could go from there?

Thank you for the help so far.  I'm not going to give up on this project thread, but I can not devote the time to it in the next few weeks as I hoped I could.
Know that I will be coming back to this project I feel it is to versatile and useful to let it die.

I hope to be back posting soon.

Sorry to hear that 

[BlackBox]

That is most unfortunate; good luck on your job search.