Topic: Does List Contain Text

[cmwade77]

Ok, so I have a list and a string. The list contains wild cards and I need to determine if the string is in the list, allowing for the use of wild cards.

Here is where I set my list:

Code: [Select]

(setq TstList (List "*demo notes*" "*general notes*" "*installation notes*" "*reference notes*"))
So, I will give an example string that should return true when checked with the list:

Code: [Select]

(setq TstString "These are some general notes, this text should be found in the list.")
I am at a loss as to where to even begin on this one. I know that I could just do wcmatches manually, but the list may change over time, so I want to make it where I will need to make as few modifications as possible to the routine when that happens.


Edit: Modified test list, I had left in an extra wild card.....oops.

[JohnK]

I'm worthless with AutoLisp these days but i can complicate the concept as well as anyone i suppose. BTW, this should be super slow.

Code: [Select]

(defun instr? (sstr str c-sen / a)
  (cond ((eq c-sen nil) (setq sstr (strcase sstr))
               (setq str (strcase str))))
  (defun instr-nest (sstr str)
    (cond ((> (strlen str) 0)
           (if (eq sstr (substr str 1 (strlen sstr)))
             str
             (instr-nest sstr (substr str 2))))))
  (setq a (instr-nest sstr str))
  (if a (1+ (- (strlen str) (strlen a))) nil) )

(defun strParse (aStr delim / strList pos)
  (while
    (setq pos (vl-string-search delim aStr 0))
    (setq strList (cons (substr aStr 1 POS) strList)
          aStr (substr aStr (+ pos 2)))
    )
  (reverse (cons aStr strList))
 )

(setq TstList (List "*demo notes*" "*general notes*" "*installation notes*" "*reference notes*" "*"))
(setq TstString "These are some general notes, this text should be found in the list.")


(apply
  'append
  (mapcar
    (function
      (lambda (y)
(mapcar
  (function
    (lambda (x)
      (instr? x y nil)
    )
  )
  (strParse TstString " ")
)
      )
    )
    TstList
  )
)

[cmwade77]

Thinking about it some more, here is my attempt, although I think if the list gets long, it will be slow:

Code: [Select]

(defun nt_ListCheck (TstList TstString / Result Item)
    (foreach Item TstList
           (cond
                  ((wcmatch TstString Item)
                        (setq Result T)
                  )
           )
    )
Result
)

[alanjt]

first one is case sensitive...

Code: [Select]

(defun match? (lst string) (vl-some '(lambda (match) (wcmatch string match)) lst))

Code: [Select]

(defun match? (lst string)
  (vl-some '(lambda (match) (wcmatch (strcase string) (strcase match))) lst)
)

[kpblc]

Another one?

Code: [Select]

(defun test (/ tstlist tststring)

  (setq tstlist (list "*demo notes*" "*general notes*" "*installation notes*" "*reference notes*" "*"))
  (setq tststring "These are some general notes, this text should be found in the list.")
  (wcmatch tststring
   (strcat (car tstlist) (apply 'strcat (mapcar '(lambda (x) (strcat "," x)) (cdr tstlist))))
   ) ;_ end of wcmatch
  ) ;_ end of defun

[Stefan]

first one is case sensitive...

Code: [Select]

(defun match? (lst string) (vl-some '(lambda (match) (wcmatch string match)) lst))

Code: [Select]

(defun match? (lst string)
  (vl-some '(lambda (match) (wcmatch (strcase string) (strcase match))) lst)
)

This will always return T because of the last item in lst...
So, cmwade, what is the result you are looking for?

[CAB]

Are you sure about that? 

[cmwade77]

There was an error in my list example, I have fixed it in the first post.

Alan's code seems to be doing exactly what I need it to, now if I can just get the rest of my code to work right, I'll be doing good.....LOL.

Thank you all.

[Stefan]

Are you sure about that? 

alanjt's function is OK but in OP, last item in TstList is was "*"
(wcmatch "some text" "*") is True for any string:

Code: [Select]

_$ (wcmatch "text" "*")
T
_$ (wcmatch "123" "*")
T
_$ (wcmatch "" "*")
T

[Lee Mac]

Another, Vanilla LISP version, perhaps for those users unfortunate enough to be using a Mac 

Code: [Select]

(defun _MatchInList ( str lst )
  (and lst (or (wcmatch str (car lst)) (_MatchInList str (cdr lst))))
)

[Jeff H]

for those users unfortunate enough to be using a Mac 

[JohnK]

I got a few minutes this morn so I cobbled together a VL method (man, I am rusty at lisp *phew*).

Code: [Select]

(setq TstList (List "*demo notes*" "*general notes*" "*installation notes*" "*reference notes*"))
(setq TstString "These are some general notes, this text should be found in the list.")

(mapcar
  (function
    (lambda ( x )
      (vl-string-search x TstString)))
  (mapcar
    (function
      (lambda ( x )
  (vl-string-trim "*" x)))
    TstList) )Returns the string and the position. This one should "compete"; if I remember right, WCMATCH is the fastest method so I put the word `compete' in quotes.

BTW, was this supposed to be just a Boolean return?

[CAB]

Sorry Stefan I thought you were referring to Alan's code and not the original list.
I removed "*" in my test because it looked like an obvious error.

[alanjt]

Why would you have a "*" by itself to begin with?
You could always add (vl-remove "*" lst) before processing the list with vl-some.

[cmwade77]

Why would you have a "*" by itself to begin with?
You could always add (vl-remove "*" lst) before processing the list with vl-some.

The * by it's self was a residual of an older version of what I am working on, so it broke some things here, but I will need to put it back in, so I will keep in mind your vl-remove idea, thank you.