Topic: Apply Plot style table to all layout

[miquan]

Dear all,

I use this lisp for set plot style table of layout to specific one.

Code - Auto/Visual Lisp: [Select]

1. ; (defun c:PLOTHORY ()
2.  (vla-put-StyleSheet
3.     (vla-get-ActiveLayout
4.         (vla-get-ActiveDocument (vlax-get-acad-object))
5.     )
6.     "monochrome.ctb"
7.   )
8. )

But it still works only in current layout.
Could you possily help me to modify for all layout setting?

Thanks in advanced,
Miquan

[Ketxu]

You could try :

Code - Auto/Visual Lisp: [Select]

1. (vlax-map-collection
2.         (vla-get-Layouts
3.                 (vla-get-ActiveDocument (vlax-get-acad-object))
4.     )
5.         '(lambda(x)(vla-put-StyleSheet x "monochrome.ctb"))
6. )

[Krushert]

 
Funny I was just trying to do the same thing.   
I love this place!
Thanks!.

[miquan]

Dear ketxu,

Thanks for your support.
I works fine.

PS: you're from vietnam?

Miquan

[Ketxu]

Yeah. Im living in Ha Noi

[BlackBox]

FWIW -

It's actually faster to iterate the Layouts Collection, and manipulate each Layout Object directly, than it is to Map an anonymous function to same... To demonstrate, here's a quick speed test:

Code - Auto/Visual Lisp: [Select]

1. (vl-load-com)
2.  
3. (defun _foo1 (ctb)
4.   (vlax-map-collection
5.     (vla-get-Layouts
6.       (vla-get-ActiveDocument (vlax-get-acad-object))
7.     )
8.     '(lambda (x) (vla-put-StyleSheet x ctb))
9.   )
10. )
11.  
12. (defun _foo2 (ctb)
13.   (vlax-for x (vla-get-layouts
14.                 (vla-get-activedocument (vlax-get-acad-object))
15.               )
16.     (vla-put-stylesheet x ctb)
17.   )
18. )
19.  

... And the results from console:

Code - Auto/Visual Lisp: [Select]

1. _$ (bench '(_foo1 _foo2) '("FOO.ctb") 10000)
2.  
3. _FOO1
4. Elapsed: 4774
5. Average: 0.4774
6.  
7. _FOO2
8. Elapsed: 3791
9. Average: 0.3791
10.  

[BlackBox]

Also, as it is loosely related, for those who might be interested: vla-SetActivePageSetup

[3dwannab]

Added checking if the plot style exists.

Code: [Select]

;;----------------------------------------------------------------------;;
;; setPlotStyle FUNCTION
;; https://www.theswamp.org/index.php?topic=45000.msg502065#msg502065
;; Added checking if the plot style exists by 3dwananb on 2024.05.15

(defun setPlotStyle (ctb / CurDoc installedPs)
  (setq CurDoc (vla-get-ActiveDocument (vlax-get-acad-object)))
  (setq installedPs (vlax-safearray->list (vlax-variant-value (vla-GetPlotStyleTableNames (vla-get-ActiveLayout CurDoc))))) ;;get the plotstyles
  (if (/= nil (vl-position ctb installedPs))
    (progn
      (princ (strcat "\nPlot Style successfully set to: '" ctb "'\n"))
      (vlax-map-collection
        (vla-get-Layouts
          (vla-get-ActiveDocument (vlax-get-acad-object))
        )
        '(lambda (x) (vla-put-StyleSheet x ctb))
      )
    )
    (princ (strcat "\nPlot Style '" ctb "' not found!\n"))
  ) ;; if verify if the plotstyle exist, if not, print to the commandline.
)

(setPlotStyle "monochrome.ctb")


[Lonnie]

Added checking if the plot style exists.

I was messing with changing page setup when I saw this. Since this was played with today I thought why not?

Removed case sensitivity

Code: [Select]

(setq ctbLower (strcase ctb nil))
(setq installedPsLower (mapcar '(lambda (ps) (strcase ps nil)) installedPs))


Code: [Select]

(if (/= nil (vl-position ctbLower installedPsLower))


Code: [Select]

;;----------------------------------------------------------------------;;
;; setPlotStyle FUNCTION
;; https://www.theswamp.org/index.php?topic=45000.msg502065#msg502065
;; Added checking if the plot style exists by 3dwananb on 2024.05.15

(defun setPlotStyle (ctb / CurDoc installedPs ctbLower installedPsLower)
  ;; Get the active document
  (setq CurDoc (vla-get-ActiveDocument (vlax-get-acad-object)))
  ;; Get the list of installed plot styles
  (setq installedPs (vlax-safearray->list (vlax-variant-value (vla-GetPlotStyleTableNames (vla-get-ActiveLayout CurDoc)))))

  ;; Convert the input plot style name and the list of installed plot styles to lowercase for case-insensitive comparison
  (setq ctbLower (strcase ctb nil))
  (setq installedPsLower (mapcar '(lambda (ps) (strcase ps nil)) installedPs))

  ;; Check if the specified plot style exists in a case-insensitive manner and set it
  (if (vl-position ctbLower installedPsLower)
    (progn
      (princ (strcat "\nPlot Style successfully set to: '" ctb "'\n"))
      (vlax-map-collection
        (vla-get-Layouts CurDoc)
        '(lambda (x) (vla-put-StyleSheet x ctb))
      )
    )
    (progn
      (princ (strcat "\nPlot Style '" ctb "' not found!\n"))
      ;; Print the available plot style tables if the specified plot style is not found
      (princ "\nAvailable plot style tables:\n")
      (mapcar '(lambda (ps) (princ (strcat ps ""))) installedPs)
    )
  ) ;; If plotstyle exists, set it; otherwise, print available plot styles.
)

;; Example invocation
(setPlotStyle "monochrome.ctb")



Before I did that I added the list of files to look at trying to figure out why it failed.

Code: [Select]

(setq CurDoc (vla-get-ActiveDocument (vlax-get-acad-object)))


Code: [Select]

(setq installedPs (vlax-safearray->list (vlax-variant-value (vla-GetPlotStyleTableNames (vla-get-ActiveLayout CurDoc)))))