Topic: LISP to Change linetype scale for enity in blocks & nested blocks

[vernonlee]

This LISP was written by LEE MAC to help me change all linetype scale for enity in blocks & nested blocks.

This LISP will affect the whole drawing.

Can someone help me to incorporate a selection options (window & picking) for this LISP?

Code: [Select]

(defun c:lts ( / doc scl )
    (initget 6)
    (if (setq scl (getreal "\nSpecify new linetype scale: "))
        (vlax-for blk (vla-get-blocks (setq doc (vla-get-activedocument (vlax-get-acad-object))))
            (if (= :vlax-false (vla-get-isxref blk))
                (vlax-for obj blk
                    (if (and (vlax-write-enabled-p obj) (vlax-property-available-p obj 'linetypescale t))
                        (vla-put-linetypescale obj scl)
                    )
                )
            )
        )
    )
    (vla-regen doc acallviewports)
    (princ)
)

[Lee Mac]

Try the following:

Code - Auto/Visual Lisp: [Select]

1. (defun c:lts ( / lts:processed idx scl sel )
2.     (initget 6)
3.     (if (setq scl (getreal "\nSpecify new linetype scale: "))
4.         (if (setq sel (ssget "_:L"))
5.             (repeat (setq idx (sslength sel))
6.                 (lts:obj (vlax-ename->vla-object (ssname sel (setq idx (1- idx)))) scl)
7.             )
8.         )
9.     )
10.     (vla-regen lts:acdoc acallviewports)
11.     (princ)
12. )
13. (defun lts:blk ( obj scl / bln )
14.     (if (not (member (setq bln (vla-get-name obj)) lts:processed))
15.         (progn
16.             (vlax-map-collection (vla-item lts:acblk bln) '(lambda ( obj ) (lts:obj obj scl)))
17.             (setq lts:processed (cons bln lts:processed))
18.         )
19.     )
20. )
21. (defun lts:obj ( obj scl )
22.     (if (and (vlax-write-enabled-p obj) (vlax-property-available-p obj 'linetypescale t))
23.         (vla-put-linetypescale obj scl)
24.     )
25.     (if (= "AcDbBlockReference" (vla-get-objectname obj))
26.         (lts:blk obj scl)
27.     )
28. )
29. (setq lts:acdoc (vla-get-activedocument (vlax-get-acad-object))
30.       lts:acblk (vla-get-blocks lts:acdoc)
31. )
32. (vl-load-com) (princ)

[vernonlee]

Thanks Lee. It works flawlessly as usual. 

Try the following:

Code - Auto/Visual Lisp: [Select]

1. (defun c:lts ( / lts:processed idx scl sel )
2.     (initget 6)
3.     (if (setq scl (getreal "\nSpecify new linetype scale: "))
4.         (if (setq sel (ssget "_:L"))
5.             (repeat (setq idx (sslength sel))
6.                 (lts:obj (vlax-ename->vla-object (ssname sel (setq idx (1- idx)))) scl)
7.             )
8.         )
9.     )
10.     (vla-regen lts:acdoc acallviewports)
11.     (princ)
12. )
13. (defun lts:blk ( obj scl / bln )
14.     (if (not (member (setq bln (vla-get-name obj)) lts:processed))
15.         (progn
16.             (vlax-map-collection (vla-item lts:acblk bln) '(lambda ( obj ) (lts:obj obj scl)))
17.             (setq lts:processed (cons bln lts:processed))
18.         )
19.     )
20. )
21. (defun lts:obj ( obj scl )
22.     (if (and (vlax-write-enabled-p obj) (vlax-property-available-p obj 'linetypescale t))
23.         (vla-put-linetypescale obj scl)
24.     )
25.     (if (= "AcDbBlockReference" (vla-get-objectname obj))
26.         (lts:blk obj scl)
27.     )
28. )
29. (setq lts:acdoc (vla-get-activedocument (vlax-get-acad-object))
30.       lts:acblk (vla-get-blocks lts:acdoc)
31. )
32. (vl-load-com) (princ)

[Lee Mac]

You're welcome.