Topic: How to insert block "flat to screen" (regardless of 3D view)

[kruuger]

hello,

is there any way to insert block "'flat to screen" ?
now my code insert block at any ucs. i want to put them like on second picture.

any trick to do that ?

thanks
kruuger

Code - Auto/Visual Lisp: [Select]

1. (defun c:TEST (/ sc)
2.   (setq sc (* (getvar "VIEWSIZE") 0.5))
3.   (vla-InsertBlock
4.     (vla-get-ModelSpace (vla-get-ActiveDocument (vlax-get-acad-object)))
5.     (vlax-3d-point (trans (getpoint "\nSelect insertion point: ") 1 0))
6.     (progn
7.       (entmakex (list (cons 0 "BLOCK") (cons 2 "*U") (cons 8 "0") (cons 10 (list 0 0 0)) (cons 70 1)))
8.       (entmake
9.         (mapcar (quote cons)
10.          '(0 100 67 8 62 100 90 70 38 10 40 41 10 40 41 10 40 41 210)
11.          '("LWPOLYLINE" "AcDbEntity" 0 "0" 4 "AcDbPolyline" 3 0 0.0
12.             (0.0 0.0) 0.02 0.02 (0.0 0.5) 0.33 0.0 (0.5 0.5) 0.0 0.0 (0.0 0.0 1.0)
13.           )
14.         )
15.       )
16.       (entmake
17.         (mapcar (quote cons)
18.          '(0 100 67 8 62 100 90 70 38 43 10 42 10 42 10 42 210)
19.          '("LWPOLYLINE" "AcDbEntity" 0 "0" 4 "AcDbPolyline" 3 0 0.0 0.01
20.             (0.1 0.0) 1 (-0.1 0.0) 1 (0.1 0.0) 0.0 (0.0 0.0 1.0)
21.           )
22.         )
23.       )
24.       (entmake
25.         (mapcar (quote cons)
26.           (list 0 1 10 40 50)
27.           (list "TEXT" "sample" (list 0 0.75 0) 0.02 0)
28.         )
29.       )
30.       (entmake (list (cons 0 "ENDBLK") (cons 8 "0")))
31.     )
32.     sc sc sc
33.     (angle (list 0 0 0) (trans (getvar "UCSXDIR") 0 (trans (list 0 0 1) 1 0 T)))
34.   )
35. )

[Lee Mac]

Try this:

Code - Auto/Visual Lisp: [Select]

1. (defun c:test ( / n p s )
2.     (setq s (/ (getvar 'viewsize) 2.0))
3.     (if
4.         (and
5.             (entmake
6.                '(
7.                     (0 . "BLOCK")
8.                     (2 . "*U")
9.                     (8 . "0")
10.                     (10 0.0 0.0 0.0)
11.                     (70 . 1)
12.                 )
13.             )
14.             (entmake
15.                '(
16.                     (0 . "LWPOLYLINE")
17.                     (100 . "AcDbEntity")
18.                     (100 . "AcDbPolyline")
19.                     (67 . 0)
20.                     (8 . "0")
21.                     (62 . 4)
22.                     (90 . 2)
23.                     (70 . 1)
24.                     (38 . 0.0)
25.                     (43 . 0.01)
26.                     (10 0.1 0.0)
27.                     (42 . 1)
28.                     (10 -0.1 0.0)
29.                     (42 . 1)
30.                     (210 0.0 0.0 1.0)
31.                 )
32.             )
33.             (entmake
34.                '(
35.                     (0 . "TEXT")
36.                     (1 . "Sample")
37.                     (10 0.0 0.0 0.0)
38.                     (11 0.0 0.0 0.0)
39.                     (40 . 0.02)
40.                     (72 . 1)
41.                     (73 . 2)
42.                 )
43.             )
44.             (setq n (entmake '((0 . "ENDBLK") (8 . "0"))))
45.             (setq p (getpoint "\nSpecify Insertion Point: "))
46.             (setq v (trans (getvar 'viewdir) 1 0 t))
47.         )
48.         (entmake
49.             (list
50.                '(0 . "INSERT")
51.                 (cons 002 n)
52.                 (cons 010 (trans p 1 v))
53.                 (cons 041 s)
54.                 (cons 042 s)
55.                 (cons 043 s)
56.                 (cons 050 (- (getvar 'viewtwist)))
57.                 (cons 210 v)
58.             )
59.         )
60.     )
61.     (princ)
62. )

[kruuger]

Hi Lee,

almost perfect. is it possible to insert block at point where we select them ?
at least we can move created block to this position.

I would like to make our company hired a programmer to speed up some work.
you will be the first on the list

shortly i will send you a small "gift" 

thanks
kruuger

[Lee Mac]

almost perfect. is it possible to insert block at point where we select them ?
at least we can move created block to this position.

Sorry kruuger, I'm not sure that I understand - is the block not currently being inserted at the selected point?

EDIT: After some more testing, you are right - I shall look to fix this for you.

I would like to make our company hired a programmer to speed up some work.
you will be the first on the list

shortly i will send you a small "gift" 

Many thanks Kruuger, that's very kind of you, I appreciate it 

[Lee Mac]

Updated above code.

[kruuger]

Updated above code.

pure magic. PERFECTO !!!

Thanks 
kruuger

[Lee Mac]

pure magic. PERFECTO !!!

Thanks 
kruuger

Excellent

You're very welcome Kruuger, enjoy