Topic: Get all Xrefs

[Shade]

Is there a quick way to get all the xrefs in a drawing?

I have this so far

Code: [Select]

(setq  XREFS (vla-get-filedependencies
                         (vla-get-activedocument
                                  (vlax-get-acad-object)
)                 )     );
But I am a little lost on where to go from there?
I have the number of xrefs in a drawing, but how do i get their names?

Any help would be appreciated

[CAB]

TRY THIS
http://www.theswamp.org/index.php?topic=2600.msg32858#msg32858

[daron]

This ought to get you what you're looking for. It creates a list of vla-objects  based on your collection.
vla-collection = XREFS <your variable
string = "ACAD:XRef"
BTW, that's seems like a nice way to get the xrefs. I would've thought to go the the blocks collection.

Code: [Select]

(defun getobject (vla-collection string / item xlist cnt)
   (setq cnt 1)
   (repeat (vla-get-count xrefs)
      (and (= (vla-get-feature (setq item (vla-item xrefs cnt))) string)
   (setq xlist (append xlist (list item)))
      )
      (setq cnt (1+ cnt))
   )
   xlist
)

[daron]

From there you're looking for vla-get-filename or vla-get-fullfilename.

[CAB]

From my stash.

Code: [Select]

;;A simpler version of getxrefs:
;;D. C. Broad, Jr. - 2002
(defun getxrefs( /  b bl)
  (while (setq b (tblnext "block" (not b)))
    (and
      (assoc 1 b) ;xr path
      (setq bl (cons (cdr (assoc 2 b)) bl))))
   bl)


;;A version that gets only resolved xrefs
;;(Only resolved xrefs appear in drawing)
;;D. C. Broad, Jr. - 2002
(defun GetResXrefs( /  b bl)
  (while (setq b (tblnext "block" (not b)))
    (and
      (= 32 (logand 32(cdr(assoc 70 b)))) ;xr path resolved
      (setq bl (cons (cdr (assoc 2 b)) bl))))
   bl)


;;A version that gets only unresolved xrefs
;;Won't report problems as long as the xref
;;is visible on the screen
;;D. C. Broad, Jr. - 2002
(defun BitSetDXF (bit key alist)
   (= bit (logand bit (cdr(assoc key alist)))))
(defun GetLostXrefs ( / b bl)
 (while (setq b (tblnext "block" (not b)))
    (and
      (BitSetDXF 4 70 b) ;xref
      (not (BitSetDXF 32 70 b));path not resolved
      (setq bl (cons (cdr (assoc 2 b)) bl))));add to list
   bl)

PS
Took me awhile but here is the link

[Shade]

Thanks for all the help.
I was able to complete my lisp based on the info provided.
 

[daron]

No problem. It gave me something to think about.