Topic: Unfrozen a list of layers

[Tharwat]

Hello .

Here is my code that would unfrozen a list of layers , but the issue is that the code does the trick and the entities being hidden for a while until
I jump to any layout and go back to model to allow objects to be appeared , and the command *regen* or *regenall* did not solve the issue .

Is there anything goes wrong within my code ?

Code: [Select]

  (defun Unfrozen-Layers (Layerlist / tbl)
    ;;; Tharwat 20. march. 2012 ;;;
    (foreach x Layerlist
      (if (tblsearch "LAYER" x)
        (entmod
          (subst (cons 70 0)
                 (assoc 70 (setq tbl (entget (tblobjname "LAYER" x))))
                 tbl
          )
        )
      )
    )
    (princ)
  )

Thank you

[CAB]

Take a look here:
http://www.theswamp.org/index.php?topic=8934.0

[Tharwat]

Thank you CAB .

I know how to make it in VLisp , but I am looking for Vanilla codes , although I can not see any error of my previous code and I need someone to test the code and tell me if they may have the same result that I had .

Appreciated a lot.

[danallen]

do you need to entupd the modified table? my vanilla version just uses command calls

[CAB]

Tested your code in plain 2006 and same problem.

[alanjt]

Make a selection set of the items and (redraw <entity> 1) each.

[Tharwat]

Make a selection set of the items and (redraw <entity> 1) each.

The same thing , although that the selection set is not nil which means that it selects the unfrozen entities during the routine but it doesn't show them .

Any other idea ? 

Thanks

Code: [Select]

(defun Unfrozen-Layers (Layerlist / tbl ents i)
;;; Tharwat 20. march. 2012 ;;;
  (foreach x Layerlist
    (if (tblsearch "LAYER" x)
      (progn
        (entmod
          (subst (cons 70 0)
                 (assoc 70 (setq tbl (entget (tblobjname "LAYER" x))))
                 tbl
          )
        )
        (if (setq ents (ssget "_x" (list (cons 8 x))))
          (repeat (setq i (sslength ents))
            (redraw (ssname ents (setq i (1- i))) 1)
          )
        )
      )
    )
  )
  (princ)
)



[Stefan]

Try

Code: [Select]

(setvar 'LAYLOCKFADECTL 0)before unlocking layers, then set it back to original value.

[edit] Forget it.... I was thinking to Unlock Layers..

[Edit 2]:
replace

Code: [Select]

(redraw (ssname ents (setq i (1- i))) 1)with

Code: [Select]

(entupd (ssname ents (setq i (1- i))))

[Tharwat]

Try

Code: [Select]

(setvar 'LAYLOCKFADECTL 0)before unlocking layers, then set it back to original value.

[edit] Forget it.... I was thinking to Unlock Layers..

[Edit 2]:
replace

Code: [Select]

(redraw (ssname ents (setq i (1- i))) 1)with

Code: [Select]

(entupd (ssname ents (setq i (1- i))))

Great work Stefan . 

Thank you so much .

[ronjonp]

Not sure if you need it, but I added a line to turn the layer on as well:

Code - Auto/Visual Lisp: [Select]

1. (defun unfrozen-layers (layerlist / ents i l)
2. ;;; Tharwat 20. march. 2012 ;;;
3.   (foreach x layerlist
4.     (if (setq l (tblobjname "LAYER" x))
5.       (progn
6.         (entmod (subst '(70 . 0) (assoc 70 (entget l)) (entget l)))
7.         ;; This line turns the layer on
8.         (entmod (subst (cons 62 (abs (cdr (assoc 62 (entget l))))) (assoc 62 (entget l)) (entget l))
9.         )
10.         (if (setq ents (ssget "_x" (list (cons 8 x))))
11.           (repeat (setq i (sslength ents)) (entupd (ssname ents (setq i (1- i)))))
12.         )
13.       )
14.     )
15.   )
16.   (princ)
17. )

[alanjt]

BTW, if the layer is locked, it will be unlocked by just putting 0 to the 70 dxf code.

[lamarn]

I use a routine that sums a list of frozen layers.
I would like to use the same code to list vp frozen layer.
What is wright code i shoul use for 'lyr'. Could use some help. thanks

Code: [Select]


(defun C:THL (/ oldEcho lyr lyrList dh rtnList)
     (setq
       oldEcho (getvar "cmdecho")
       lyr (tblnext "layer" 'T)
     )
     (while lyr
       (if (not (zerop (logand (cdr (assoc 70 lyr)) 4)))  ;<- ASSOC 70 LYR
          (setq lyrList (cons (cdr (assoc 2 lyr)) lyrList))
       )
       (setq lyr (tblnext "layer"))
     )
     (if lyrList
       (progn
         (if (< (length lyrList) (getvar "maxsort"))
           (setq lyrList (acad_strlsort lyrList))
         )
         (setq dh (load_dialog "ddthaw.dcl"))
         (if (not (new_dialog "ddlocked" dh))(exit))
         (start_list "lyrlist")
         (mapcar 'add_list lyrList)
         (end_list)
         (action_tile "lyrlist" "(setq rtnList $value)")
         (action_tile "cancel" "(done_dialog 0)")
         (action_tile "accept" "(done_dialog 1)")
         (if (= (start_dialog) 1)
           (progn
             (setq rtnList (read (strcat "(" rtnList ")")))
             (command "_.layer")
             (foreach i rtnList
               (command "unlock" (nth i lyrList))
             )
             (command "")
           )
         )
         (unload_dialog dh)
       )
       (alert "Drawing does not contain\n   any locked layers!\n")
     )
     (princ)
   )




[CAB]

Take a look at this:

Code: [Select]

(defun LayerFrozenList(doc / result)
  (vlax-for layer (vla-get-Layers doc)
    (if (= (vla-get-freeze layer) :vlax-true)
      (setq result (cons (vla-get-name layer) result)))
    )
  result
)

(setq lst (LayerFrozenList (vla-get-ActiveDocument (vlax-get-acad-object))))

[lamarn]

So, this might work you think..(?)
====

(defun C:THL (/ oldEcho lyr lyrList dh rtnList)
     (setq
       oldEcho (getvar "cmdecho")
;;;
  (vlax-for layer (vla-get-Layers doc)
    (if (= (vla-get-freeze layer) :vlax-true)
      (setq result (cons (vla-get-name layer) result)))
    )
  result
)

(setq lst (LayerFrozenList (vla-get-ActiveDocument (vlax-get-acad-object))))
;;;;
     (if LayerFrozenList
       (progn
         (if (< (length LayerFrozenList) (getvar "maxsort"))
           (setq lyrList (acad_strlsort lyrList))
         )

....;; etc.

[CAB]

Looks promising. 

[lamarn]

Thank you mr. CAB!

[lamarn]

Can you help with a few lines to get it to work..

Code: [Select]

(defun C:THV (/ doc result oldEcho lyr LayerFrozenList dh rtnList)
  (setq oldEcho (getvar "cmdecho")
  (vlax-for layer (vla-get-Layers doc)
    (if (= (vla-get-freeze layer) :vlax-true)
      (setq result (cons (vla-get-name layer) result)))
    )
  result
)

(setq lst (LayerFrozenList (vla-get-ActiveDocument (vlax-get-acad-object))))
     (if LayerFrozenList
       (progn
         (if (< (length LayerFrozenList) (getvar "maxsort"))
           (setq lyrList (acad_strlsort lyrList))
         )

         (setq dh (load_dialog "ddthaw.dcl"))
         (if (not (new_dialog "ddthaw" dh))(exit))
         (start_list "lyrlist")
         (mapcar 'add_list LayerFrozenList)
         (end_list)
         (action_tile "lyrlist" "(setq rtnList $value)")
         (action_tile "cancel" "(done_dialog 0)")
         (action_tile "accept" "(done_dialog 1)")
         (if (= (start_dialog) 1)
           (progn
             (setq rtnList (read (strcat "(" rtnList ")")))
             (command "_.layer")
             (foreach i rtnList
               (command "thaw" (nth i LayerFrozenList))
             )
             (command "")
           )
         )
         (unload_dialog dh)
       )
       (alert "Viewport does not contain\n   any vp frozen layers!\n")
     )
     (princ)
)


[hanhphuc]

Just had a quick fixed. not perfect yet
1. add in, (vl-load-com) & doc
2. setq lst instead of setq LayerFrozenList
3. (setq oldEcho (getvar "cmdecho") ..; parenthesis not close
4. (if lst; instead of  (if LayerFrozenList..
5.  (and (= (start_dialog) 1) rtnList)
reset oldEcho
etc..

Code: [Select]

(defun C:THV (/ doc result oldEcho lyr LayerFrozenList dh rtnList)
 
  (defun unfrozen-layers (layerlist / ents i l)
;;; Tharwat 20. march. 2012 ;;;
  (foreach x layerlist
    (if (setq l (tblobjname "LAYER" x))
      (progn
(entmod (subst '(70 . 0) (assoc 70 (entget l)) (entget l)))
;; This line turns the layer on
(entmod (subst (cons 62 (abs (cdr (assoc 62 (entget l))))) (assoc 62 (entget l)) (entget l))
)
(if (setq ents (ssget "_x" (list (cons 8 x))))
  (repeat (setq i (sslength ents)) (entupd (ssname ents (setq i (1- i)))))
)
      )
    )
  )
  (princ)
)

(defun LayerFrozenList(doc / result)
  (vlax-for layer (vla-get-Layers doc)
    (if (= (vla-get-freeze layer) :vlax-true)
      (setq result (cons (vla-get-name layer) result)))
    )
  result
)


(setq doc     (vla-get-activedocument (vlax-get-acad-object))
      oldEcho (getvar "cmdecho")
      lst     (LayerFrozenList doc)
      ) ;_ end of setq
 (setvar "cmdecho" 0)
     (if lst; LayerFrozenList
       (progn
         (if (< (length lst) (getvar "maxsort"))
           (setq lyrList (acad_strlsort lyrList))
         )

         (setq dh (load_dialog "ddthaw.dcl"))
         (if (not (new_dialog "ddthaw" dh))(exit))
         (start_list "lyrlist")
         (mapcar 'add_list lst)
         (end_list)
         (action_tile "lyrlist" "(setq rtnList $value)")
         (action_tile "cancel" "(done_dialog 0)")
         (action_tile "accept" "(done_dialog 1)")
         (if (and (= (start_dialog) 1) rtnList)
           (progn
             (setq rtnList (read (strcat "(" rtnList ")")))
             (command "_.layer")
             (foreach i rtnList
               (command "thaw" (nth i lst))
             )
             (command "")
           )
         )
         (unload_dialog dh)
       )
       (alert "Viewport does not contain\n   any vp frozen layers!\n")
     )

    (setvar "cmdecho" oldEcho)
     (princ)
)
(vl-load-com)


[lamarn]

Thanks for your reply!

instead of using (vla-get-freeze ... i need the vp equevalent... something lik (vla-get-vpfreeze..
I dont know. vpfreeze does not exist. i has tp be something else.