Author Topic: Help - Create new viewport lisp (Read 2647 times)

PM · « **on:** February 11, 2022, 11:27:31 AM »

Hi i find this lisp code in this post

https://www.theswamp.org/index.php?topic=47145.0;all

The problem is that this lisp code not working well my template units and viewport scale units. I try to change it but i failed. Can any one help me ?? i upload the original lisp code with original lisp template and i upload my template with a drawing (look at viewport scales and template unit settings)

thanks

PM · « **Reply #1 on:** February 12, 2022, 03:08:16 AM »

Any ideas ?

Thanks

PM · « **Reply #2 on:** February 12, 2022, 10:07:16 AM »

i update the code but something is missing. The new viewport is big in correct dimension but the misc is off (in properties ), the annotation scale is 1:1 and is lock and not center to the previous selection (is empty. )

Can any one help ?

Thanks

Code - Auto/Visual Lisp: [Select]

; Source:                            http://www.theswamp.org/index.php?topic=42149.msg473439#msg473439
; Improvements suggested by Lee Mac: http://www.theswamp.org/index.php?topic=42149.msg473793#msg473793
; Modified version for:              http://www.theswamp.org/index.php?topic=47145
(defun c:NV (/ *error* _RestoreView p1 p2 doc ct vs vc tmp mp sc ll sl res vpdoc vpp vp ans)
  (defun *error* (Msg)
    (princ "Error: ")
    (princ Msg)
    (if ct (_RestoreView))
    (princ)
  )
  (defun _RestoreView ()
    (setvar "ctab" ct)
    (vla-ZoomCenter (vlax-Get-Acad-Object) (vlax-3d-Point (trans vc 1 0)) vs)
  )
  (vl-load-com)
  (if (/= (getvar "cvport") 1)
    (if
      (and
        (setq p1 (getpoint "\nSelect first point of view: "))
        (setq p2 (getcorner p1 "\nSelect second point of view: "))
      )
      (progn
        (setq doc (vla-get-ActiveDocument (vlax-get-acad-object))
              ct (getvar "ctab")
              vs (getvar "viewsize")
              vc (getvar "viewctr")
              sc (cond
                   ( (getint
                       (strcat
                         "\nWhat is Viewport Scale 1: <"
                         (itoa (setq sc (cond (sc) (50))))
                         ">: "
                       )
                     )
                   )
                   ( sc )
                 )
        )
        (setq ll
          (vlax-for % (vla-get-layouts doc)
            (setq res
              (cons
                (list
                  (vla-get-name %)
                  %
                  (vla-get-TabOrder %)
                )
                res
              )
            )
          )
        )
        (setq ll
          (cdr
            (vl-sort ll
             '(lambda (a b)
                (< (last a) (last b))
              )
            )
          )
        )
;;; ============================================================ Start of mod.
        (if (setq sl (cd:DCL_StdListDialog (mapcar ' car ll) 0 "NewViewport" "Select layout:" 40 15 2 nil T T))
          (progn
            ;; 'Trans stuff' has to be done before changing the active layout:
            (setq mp (trans (mapcar '* (mapcar '+ p1 p2) '(0.5 0.5 0.5)) 1 0)) ; WCS.
            (setq vpDir (trans '(0.0 0.0 1) 2 0 T))
            (setq vpDims (mapcar '* (mapcar 'abs (mapcar '- (trans p1 1 2) (trans p2 1 2))) (list (/ 1000.0 sc) (/ 1000.0 sc) 0.0)))
            (setq vpTwist (getvar 'viewtwist))
            (setvar "ctab" (car (nth sl ll)))
            (vla-put-mspace doc :vlax-false)
            (if (setq vpp (getpoint "\nSelect bottom left point for viewport: "))
              (progn
                (setq vp
                  (vla-addpviewport
                    (vla-get-paperspace doc)
                    (vlax-3d-point (mapcar '+ vpp (mapcar '* vpDims '(0.5 0.5 0.5))))
                    (car vpDims)
                    (cadr vpDims)
                  )
                )
                (vla-put-customscale vp (/ 1000.0 sc))
                (vla-put-direction vp (vlax-3d-point vpDir))
                (vla-put-target vp (vlax-3d-point mp))
                (vla-put-twistangle vp vpTwist)
                (vla-put-displaylocked vp :vlax-true)
;;; ============================================================ End of mod.
                (vla-put-MSpace doc :vlax-true)
                (vla-put-ActivePViewport doc vp)
                (vla-ZoomCenter
                  (vlax-get-acad-object)
                  (vlax-3d-point mp)
                  1.0
                )
                (vla-put-CustomScale vp (/ 1. sc))
                (vla-put-MSpace doc :vlax-false)
                (vla-put-DisplayLocked vp :vlax-true)
                (initget "Yes No")
                (setq ans
                  (cond
                    ( (getkword "\nBack to model space [Yes/No] <No>: ") )
                    ( "No" )
                  )
                )
                (if (= ans "Yes") (_RestoreView))
              )
              (progn
                (princ "\n** Invalid Point ** ")
                (if ct (_RestoreView))
              )
            )
          )
          (princ "\n** Layout not selected ** ")
        )
      )
      (princ "\n** Invalid Point ** ")
    )
    (princ "\nStart Program in Model Space ")
  )
  (princ)
)
; =========================================================================================== ;
; Okno dialogowe z lista (list_box) / Dialog control with list (list_box)                     ;
;  Data      [LIST]    - lista do wyswietlenia / list to display                              ;
;  Pos       [INT]     - pozycja poczatkowa na liscie / select list position                  ;
;  Title     [STR/nil] - tytul okna / window title                                            ;
;  ListTitle [STR/nil] - tytul list_box / list_box title                                      ;
;  Width     [INT]     - szerokosc / width                                                    ;
;  Height    [INT]     - wysokosc / height                                                    ;
;  Btns      [0/1/2]   - [cancel/ok/ok_cancel] przyciski / buttons                            ;
;  MSelect   [T/nil]   - dopuszczenie multiple_select / allow multiple select                 ;
;  DPos      [T/nil]   - zapamietanie pozycji okna / save window position                     ;
;  DblClick  [T/nil]   - podwojny klik (wykluczone Cancel) / double click (not for Cancel)    ;
; ------------------------------------------------------------------------------------------- ;
; Zwraca / Return:                                                                            ;
;  nil  = nic nie wybrano (anulowano) / nothing was selected (canceled)                       ;
;  INT  = wybrano jedna pozycje / one position selected  | MSelect = nil                      ;
;  LIST = wybrano kilka pozycji / few positions selected | MSelect = T                        ;
; ------------------------------------------------------------------------------------------- ;
; (cd:DCL_StdListDialog '("A" "B" "C") 0 "Title" "ListTitle:" 40 15 2 nil T nil)              ;
; =========================================================================================== ;
(defun cd:DCL_StdListDialog (Data Pos Title ListTitle Width Height Btns MSelect DPos DblClk
                             / f tmp dc res)
  (if (not DPos) (setq *cd-TempDlgPosition* (list -1 -1)))
  (cond
    ( (not
        (and
          (setq f
            (open
              (setq tmp (vl-FileName-MkTemp nil nil ".dcl"))
              "w"
            )
          )
          (foreach %
            (list
              "StdListDialog:dialog{"
              (strcat "label=\""
                (if Title (strcat Title "\";") "\"\";")
              )
              ":list_box{key=\"list\";"
              (if ListTitle
                (strcat "label=\"" ListTitle "\";")""
              )
              "fixed_width=true;fixed_height=true;"
              (strcat "width="
                (if (not Width) "20" (itoa Width))";"
              )
              (strcat "height="
                (if (not Height) "20" (itoa Height))";"
              )
              (if (not DblClck)
                (strcat "multiple_select="
                  (if MSelect "true;" "false;")
                )
                "multiple_select=false;"
              )
              "}"
              (cond
                ( (zerop Btns) "cancel_button;")
                ( (= 1 Btns) "ok_only;")
                (T "ok_cancel;")
              )
              "}"
            )
            (write-line % f)
          )
          (not (close f))
          (< 0 (setq dc (load_dialog tmp)))
          (new_dialog "StdListDialog" dc ""
            (cond
              ( *cd-TempDlgPosition* )
              ( (quote (-1 -1)) )
            )
          )
        )
      )
    )
    ( T
      (start_list "list")
      (mapcar (quote add_list) Data)
      (end_list)
      (if (not Pos)
        (setq Pos 0)
        (if (> Pos (length Data)) (setq Pos 0))
      )
      (setq res (set_tile "list" (itoa Pos)))
      (action_tile "list"
        (strcat
          "(setq res $value)(if DblClk (if(or(not MSelect)"
          "(not (zerop Btns)))"
          "(if (= $reason 4)(setq "
          "*cd-TempDlgPosition* (done_dialog 1)))))"
        )
      )
      (action_tile "accept" "(setq *cd-TempDlgPosition* (done_dialog 1))")
      (action_tile "cancel" "(setq res nil) (done_dialog 0)")
      (setq res
        (if (= 1 (start_dialog))
          (read (strcat "(" res ")"))
          nil
        )
      )
    )
  )
  (if (< 0 dc) (unload_dialog dc))
  (if (setq tmp (findfile tmp)) (vl-File-Delete tmp))
  (if (not DPos) (setq *cd-TempDlgPosition* (list -1 -1)))
  (if res (if (= 1 (length res)) (car res) res))
)
(princ "\n Type NV to Invoke ")
(princ)
 
 

smemo · « **Reply #3 on:** February 13, 2022, 09:06:15 AM »

maybe you can use the lisp to Create viewport "as-CreaFinLay.zip"
http://www.theswamp.org/index.php?topic=42149.msg474945#msg474945

PM · « **Reply #4 on:** February 13, 2022, 12:15:36 PM »

hi smemo . The lisp i use is from the same post. Your code is too coplicated for me . You have 6 lisp code in a zip file . I want something simple . The original code i use in my first post work fone with NewViewport_Approach_2.lsp.dwg .The problem is when i use it in MY TEMPLATE.dwg the viewports are too small because my scale are (for example 1:50 --> 1000 : 50 in meters). I use meters . I try to change the code in my thirs post and the viewports are big in corect size but the drawing is not in the correct scale, the annotation scale is 1:1 and is lock and not center to the previous selection (is empty. ).

Than you help me with this problem ?

Thanks

smemo · « **Reply #5 on:** February 15, 2022, 01:10:33 AM »

this is a single file including DCL, type CFL to start after loading

PM · « **Reply #6 on:** February 15, 2022, 01:39:01 AM »

Hi smemo. I try your code but gives me this error

smemo · « **Reply #7 on:** February 15, 2022, 07:31:19 AM »

"ai_utils.lsp" is a function present in Express Tools.
Requires the installation of the express tools in autocad
https://knowledge.autodesk.com/support/autocad/learn-explore/caas/sfdcarticles/sfdcarticles/How-to-install-Express-Tools-into-AutoCAD.html

PM · « **Reply #8 on:** February 15, 2022, 09:23:24 AM »

I am using Autocad 2020 and the express tools works fine.

smemo · « **Reply #9 on:** February 15, 2022, 02:02:14 PM »

try to search..
(findfile "ai_utils.lsp")
and eventually load it

PM · « **Reply #10 on:** February 15, 2022, 04:58:36 PM »

Sorry smemo this code is not working for me. If you can help me to fix the code i post is ok

Thanks

PM · « **Reply #11 on:** February 18, 2022, 02:18:04 PM »

Hi smemo i find the ai_utils.lsp was in

Code - Auto/Visual Lisp: [Select]

"C:\\Program Files\\Autodesk\\AutoCAD 2020\\Support\\en-us;"
 

Is it posible to create the DCL file in C:\Users\Admin\AppData\Local\Temp and not

C:\Users\Admin\AppData\Roaming\Autodesk\AutoCAD 2020\R23.1\enu ?

Thanks

mhupp · « **Reply #12 on:** February 18, 2022, 08:08:38 PM »

this will make a temp file in the TEMPPREFIX folder location

Code - Auto/Visual Lisp: [Select]

(setq fo (open (setq fn (vl-filename-mktemp "" "" ".dcl")) "w"))
when done with the dcl
(vl-file-delete fn)
 

PM · « **Reply #13 on:** February 19, 2022, 03:03:53 AM »

Hi mhupp .I try to do this change but something in going wrong. Can you tell me exactly what lines of the code to change? Thanks

PM · « **Reply #14 on:** February 23, 2022, 11:57:22 AM »

I try to do the change here

Code - Auto/Visual Lisp: [Select]

(defun create_dcl (fn / acadfn)
  (if (null(wcmatch (strcase fn) "*`.DCL"))
    (setq fn (strcat fn ".DCL"))
  )
  (if (not (findfile (strcat (getvar "roamablerootprefix") fn)))
    ;; create dcl file 
    (progn
      (setq fn (strcat (getvar "roamablerootprefix") fn)
            fn (open fn "w")
      )
 
 

but is not working. Can any one help me to create the dcl file in C:\Users\Admin\AppData\Local\Temp

Thanks

ronjonp · « **Reply #15 on:** February 23, 2022, 01:19:18 PM »

Quote from: PM on February 23, 2022, 11:57:22 AM

I try to do the change here

Code - Auto/Visual Lisp: [Select]
(defun create_dcl (fn / acadfn)
(if (null(wcmatch (strcase fn) "*`.DCL"))
(setq fn (strcat fn ".DCL"))
)
(if (not (findfile (strcat (getvar "roamablerootprefix") fn)))
;; create dcl file
(progn
(setq fn (strcat (getvar "roamablerootprefix") fn)
fn (open fn "w")
)

but is not working. Can any one help me to create the dcl file in C:\Users\Admin\AppData\Local\Temp

Thanks

Why don't you use your profile? You probably don't have access to the admin profile if you're a limited user ....

PM · « **Reply #16 on:** February 23, 2022, 01:35:14 PM »

Hi ronjonp. I can not understand your answer!!! I want to use C:\Users\Admin\AppData\Local\Temp because the dcl file is a temp file it is easyer for me to delete it.

ronjonp · « **Reply #17 on:** February 23, 2022, 01:50:32 PM »

Quote from: PM on February 23, 2022, 01:35:14 PM

Hi ronjonp. I can not understand your answer!!! ...

Chill out...

I'm not sure why you're having problems with this.

Code - Auto/Visual Lisp: [Select]

(defun create_dcl (fn / acadfn)
  (if (null(wcmatch (strcase fn) "*`.DCL"))
    (setq fn (strcat fn ".DCL"))
  )
  (setq path "C:\\Users\\Admin\\AppData\\Local\\Temp\\")
  (if (not (findfile (strcat path fn)))
    ;; create dcl file 
    (progn
      (setq fn (strcat path fn)
            fn (open fn "w")
      )

Was your previous username Topographer ?

PM · « **Reply #18 on:** February 23, 2022, 07:02:41 PM »

Hi ronjonp . I replace the part in the code , run the code without errors but when i write CFL to start the lisp nothing happened . Any idea?

Thanks

ronjonp · « **Reply #19 on:** February 23, 2022, 07:22:10 PM »

Quote from: PM on February 23, 2022, 07:02:41 PM

Hi ronjonp . I replace the part in the code , run the code without errors but when i write CFL to start the lisp nothing happened . Any idea?

Thanks

Sorry I don't know what your problem is. Maybe try using (getenv "temp") as your directory assuming that you login as "ADMIN"

Again, was your previous username Topographer ?

News:

Author Topic: Help - Create new viewport lisp (Read 2647 times)

PM

PM

PM

PM

PM

PM

PM

PM

PM

PM

PM

PM