Topic: lisp to count number of attributes in block

[serge_c]

is it possible to count the number of attributes in block and prompt it ? This is the easiest question .
and hardest one : is it possible to compare the numbers of attributes between 2 blocks , and prompt if the results is negative ?

[Marc'Antonio Alessi]

This can be a start:

Code: [Select]

; Function: ALE_Block_GetAttributesFilter
;
; Version 1.00 - 30/11/2005
;
; Description:
;   returns a list of all attributes matching Tag names and Tag values
;
; Arguments:
;   VlaObj: [VLA-OBJECT]
;   TagNms: Tag names  - Wcmatch string > "Date,Scale" or "*" for all
;   TagVls: Tag values - Wcmatch string > "*2005,1:10" or "*" for all
;
; Return Values: LIST
;     tag   value   ObjectID                 vla-object
;  (("Tag1" "Val1" 2130160792 #<VLA-OBJECT IAcadAttributeReference 0abb21e4>) ...)
;
(defun ALE_Block_GetAttributesFilter (VlaObj TagNms TagVls / AttObj TagNam TagVal OutLst)
  (if
    (and
      (= 'VLA-OBJECT (type VlaObj))
      (= (vla-get-hasattributes VlaObj) :vlax-true)
    )
    (foreach ObjFor (vlax-invoke VlaObj 'GetAttributes)
      (if   
        (and
          (wcmatch (setq TagNam (vla-get-TagString  ObjFor))           (strcase TagNms))
          (wcmatch (strcase (setq TagVal (vla-get-TextString ObjFor))) (strcase TagVls))
        )
        (setq OutLst (cons (list TagNam TagVal (vla-get-ObjectID ObjFor) ObjFor) OutLst))
      )
    )
  )
  OutLst
)

[Tharwat]

Something like this ?

Code - Auto/Visual Lisp: [Select]

1. (defun c:Test (/ s ss)
2. ;;; Tharwat 23.01.2015  ;;;
3.   (if (and (princ "\n Select FIRST Attributed Block :")
4.            (setq s (ssget "_+.:S:E" '((0 . "INSERT") (66 . 1))))
5.            (princ "\n Select the SECOND Attributed Block :")
6.            (setq ss (ssget "_+.:S:E" '((0 . "INSERT") (66 . 1))))
7.       )
8.     (mapcar
9.       'length
10.       (mapcar
11.         '(lambda (a)
12.            (mapcar
13.              '(lambda (x) (vla-get-textstring x))
14.              (vlax-invoke (vlax-ename->vla-object a) 'getattributes)
15.            )
16.          )
17.         (list (ssname s 0) (ssname ss 0))
18.       )
19.     )
20.   )
21. )

[Lee Mac]

Another:

Code - Auto/Visual Lisp: [Select]

1. (defun c:attcompare ( / a b )
2.     (if (and (setq a (selectattblock "\nSelect 1st block: "))
3.              (setq b (selectattblock "\nSelect 2nd block: "))
4.         )
5.         (if (apply '/= (mapcar '(lambda ( x ) (length (vlax-invoke (vlax-ename->vla-object x) 'getattributes))) (list a b)))
6.             (princ "\nNumber of attributes is different.")
7.             (princ "\nNumber of attributes is identical.")
8.         )
9.     )
10.     (princ)
11. )
12. (defun selectattblock ( msg / ent enx )
13.     (while
14.         (progn (setvar 'errno 0) (setq ent (car (entsel msg)))
15.             (cond
16.                 (   (= 7 (getvar 'errno))
17.                     (princ "\nMissed, try again.")
18.                 )
19.                 (   (null ent) nil)
20.                 (   (/= "INSERT" (cdr (assoc 0 (setq enx (entget ent)))))
21.                     (princ "\nSelected object is not a block.")
22.                 )
23.                 (   (/= 1 (cdr (assoc 66 enx)))
24.                     (princ "\nSelected block is not attributed.")
25.                 )
26.             )
27.         )
28.     )
29.     ent
30. )
31. (vl-load-com) (princ)

[serge_c]

Sorry Tharwat and LeeMac , but both lisp dose not work , I try both of them.
I attach a dwg file you can try lisps on it .

[Marc'Antonio Alessi]

Sorry Tharwat and LeeMac , but both lisp dose not work , I try both of them.
I attach a dwg file you can try lisps on it .

Sorry but all 3 solutions works here:

Code: [Select]

Comando: TEST
 Select FIRST Attributed Block :
 Select the SECOND Attributed Block :
(151 151)

Comando: TEST
 Select FIRST Attributed Block :
Selezionare oggetti:
 Select the SECOND Attributed Block :
Selezionare oggetti:
(297 295)

Code: [Select]

Comando: ATTCOMPARE
Select 1st block:
Select 2nd block:
Number of attributes is different.

Comando:  ATTCOMPARE
Select 1st block:
Select 2nd block:
Number of attributes is identical.

Code: [Select]

(length (ALE_Block_GetAttributesFilter (vlax-ename->vla-object (car (entsel))) "*" "*"))
=> 151
 
(length (ALE_Block_GetAttributesFilter (vlax-ename->vla-object (car (entsel))) "*" "*"))
=> 297
 
(length (ALE_Block_GetAttributesFilter (vlax-ename->vla-object (car (entsel))) "*" "*"))
=> 295


[ronjonp]

Just tested Lee's here and it worked fine 

[CAB]

Me thinks the OP wants a prompt for each att & perhaps update the block.
Just a guess. 

[serge_c]

Sorry my bad , I try it in 2012 version work fine , I am working in 2013 version and few day I try a lot of lisps and problably some of them overlapped ...
Phanks a lot sensei Lee and sensei Tharwat  !!!!
It would be very helpful to my work ..

[Tharwat]

Sorry my bad , I try it in 2012 version work fine , I am working in 2013 version and few day I try a lot of lisps and problably some of them overlapped ...
Phanks a lot sensei Lee and sensei Tharwat  !!!!
It would be very helpful to my work ..

Good to hear , you are welcome .