Topic: (if (and

[AWW]

Analyzing conditionals. This is what I know, pulled from older posts:

Code: [Select]

(if (this is true)
  (then do this)
)

Code: [Select]

(if (this is true)
  (then do this)
  (else do this when false)
)

Code: [Select]

(and (a. is true) ; keep going
      (b. do this & if true keep going)
      (c. do this if b was true)
)
My question is:

Code: [Select]

(if (and (XX YY ZZ)
How does it work with 2 conditionals like so? Considering if returns a value & and returns T/NIL...

[Matt__W]

I would opt for the COND function instead of IF.

http://www.afralisp.net/autolisp/tutorials/cond-vs-if.php

[MP]

My question is:

Code: [Select]

(if (and (XX YY ZZ)
How does it work with 2 conditionals like so? Considering if returns a value & and returns T/NIL...

*blink* What is the question? Sorry, my coffee blend is weak today.

[AWW]

This is the original code I'm looking at:

Code: [Select]

  (if (and Ltext DXLeaderHandle DXItemHandle)
    (DLEADERPUTXDATA
      Ltext
      "DLEADER_TEXT"
      (vl-prin1-to-string (list DXLeaderHandle DXItemHandle))
    )
  )
The question resulted from not quite understanding whats happening with (2) conditional functions: if & and. So is the test expression evaluated twice? Once to return a T/NIL and once to return a value? Why are there 2 conditionals? Just looking for an elaboration of the code, if possible.

[alanjt]

and is just checking to make sure each item is not nil. Thus returning T (all not nil) or nil (some or all are nil).

eg.

Code: [Select]

(if (and (setq a (getint "Gimmie first integer: ")) ; if not nil, continue
         (setq b (getint "Gimmie second integer: ")) ; if not nil, continue
         (setq c (getint "Gimmie third integer: ")) ; if not nil, continue
    ) ; everything not nil, do something
  (alert (strcat "First:  "
                 (itoa a)
                 "\nSecond: "
                 (itoa b)
                 "\nThird:  "
                 (itoa c)
         )
  )
  (alert "You suck!")
)

[CAB]

More on Cond And others. 
http://www.theswamp.org/index.php?topic=13046.msg158557#msg158557

[Lee Mac]

The question resulted from not quite understanding whats happening with (2) conditional functions: if & and.

AND is not a conditional. AND is a boolean function returning the logical AND operation of one or more expressions.

AND will return T if (and only if) all of the supplied expressions evaluate to a non-nil* value.

In your example you have the structure:

Code: [Select]

(if
    (and
        <expression1>
        <expression2>
        ...
        <expressionN>
    )
    (do_this)
    (else_do_this)
)
Here, the 'test expression' is:

Code: [Select]

(and <expression1> <expression2> ... <expressionN>)
Hence, each of <expression1> ... <expressionN> must return a non-nil value for the AND function to return T, and hence for the test expression to be validated and the THEN expression to be subsequently evaluated.

This reads:

Code: [Select]

If (this AND this AND this AND ... AND this)
    do_this
    else_do_this
A possible (and far less readable) re-write could be:

Code: [Select]

(if <expression1>
    (if <expression2>
        (if <expression3>
            ...
            (if <expressionN>
                (do_this)
                (else_do_this)
            )
            ...
        )
    )
)
However, apart from being extremely difficult to manage and maintain, the intent is far harder to ascertain.

[ *Note that expressions needn't evaluate explicitely to T, but anything non-nil, this could be a string, number, list (non-empty), etc, or even T. ]

[AWW]

I see how they're tied together now. Makes sense. Will have to look into boolean functions more. Wikipedia seems to have a wealth of information on this stuff!

[Lee Mac]

I see how they're tied together now. Makes sense. Will have to look into boolean functions more. Wikipedia seems to have a wealth of information on this stuff!

Good stuff 

Yeah, don't be 'swamped' by Wikipedia... it goes pretty deep.

[Matt__W]

...it goes pretty deep.

TWSS   

[Lee Mac]

 

[ribarm]

Still, even now I think I couldn't wrote this code differently without (if ... (if ... (if ... )))... So please examine and make your own conclusion...
Posted on AUGI

M.R.

[Lee Mac]

Still, even now I think I couldn't wrote this code differently without (if ... (if ... (if ... )))... So please examine and make your own conclusion...
Posted on AUGI

M.R.

COND

[ribarm]

Still, even now I think I couldn't wrote this code differently without (if ... (if ... (if ... )))... So please examine and make your own conclusion...
Posted on AUGI

M.R.

COND

That was I thinking at first glance, but try to realize it with cond... (you may reply on AUGI if you wish)
M.R.

[CAB]

I took a shot at recoding the (If's but did no testing.

Code: [Select]

(defun c:dc_block (/ _name ss ent att attpt pt0 pt1 pt2 pt3 pt4 pt5 pt6 data)
  (vl-load-com)
  (defun _name (obj)
    (if (vlax-property-available-p obj 'effectivename)
      (vla-get-effectivename obj)
      (vla-get-name obj)
    )
  )

 (defun attchk (att)
   (setq attpt (cdr (assoc 10 (entget att))))
   (setq pt0 (mapcar '+ attpt (list (/ (cdr (assoc 40 (entget att))) 6.0) (/ (cdr (assoc 40 (entget att))) 2.5) 0.0)))
   (setq pt1 (mapcar '+ attpt (list (/ (cdr (assoc 40 (entget att))) 6.0) (/ (cdr (assoc 40 (entget att))) 6.0) 0.0)))
   (setq pt2 (mapcar '+ attpt (list (/ (cdr (assoc 40 (entget att))) 6.0) (* (/ (cdr (assoc 40 (entget att))) 6.0) 5.0) 0.0)))
   (setq pt3 (mapcar '+ attpt (list (/ (cdr (assoc 40 (entget att))) 6.0) (- (/ (cdr (assoc 40 (entget att))) 10.0)) 0.0)))
   (setq pt4 (mapcar '+ attpt (list (/ (cdr (assoc 40 (entget att))) 6.0) (cdr (assoc 40 (entget att))) 0.0)))
   (setq pt5 (mapcar '+ attpt (list (/ (cdr (assoc 40 (entget att))) 6.0) (/ (cdr (assoc 40 (entget att))) 2.0) 0.0)))
   (setq pt6 (mapcar '+ attpt (list (/ (cdr (assoc 40 (entget att))) 6.0) (- (/ (cdr (assoc 40 (entget att))) 3.0)) 0.0)))
  )
 
  (if (and (or (and (setq ss (ssget "_I" '((0 . "INSERT") (66 . 1))))
                    (setq ent (ssname ss 0))
                    (setq att (entnext ent))
               )
               (and (setq ent (car (entsel "\nSelect block: ")))
                    (setq att (entnext ent))
                    (eq (cdr (assoc 0 (setq data (entget ent)))) "INSERT")
                    (eq (cdr (assoc 66 data)) 1)
               )
           )
           (eq (_name (vlax-ename->vla-object ent)) "24x36 Old")
      )
    (progn
      (command "_.eattedit" ent)
      (while (eq (cdr (assoc 0 (entget att))) "ATTRIB")
        (attchk att)
        (vl-some (function (lambda (p) (if (ssget p) (command "_.attipedit" p))) )
                 (list attpt pt0 pt1 pt2 pt3 pt4 pt5 pt6)
        )
        (setq att (entnext att))
      )
    )
  )
  (print (_name (vlax-ename->vla-object ent)))
  (princ)
)