Topic: Delete all layouts?

[KewlToyZ]

I'm just looking for the short and sweet bit of code for deleting all layouts from a drawing.
I see AutoCAD will still make a layout which is fine but I want to remove extra information from files to be used as XREF's

[T.Willey]

Code: [Select]

(vlax-for lo (vla-get-Layouts (vla-get-ActiveDocument (vlax-get-Acad-Object)))
  (if (/= (vla-get-Name lo) "Model")
    (vla-Delete lo)
  )
)


[KewlToyZ]

Thanks Tim =)
I'll post my mess when I'm finished

[T.Willey]

Thanks Tim =)
I'll post my mess when I'm finished

Cool.  You're welcome.

[KewlToyZ]

Hi Tim,

I'm missing something from a batch processing lisp routine you posted before.
I seem to keep breaking the thing :ugly:

Code: [Select]

;; To Batch Drawings As ZBase XREF's ......
;;
;; Note: replace the Path/filename below to call up your Lisp
;;       to process the drawings the way you want.
;;
;; Make sure your lisp program is in a 'support' folder ..
;; Setup to batch specific project drawing files and prevent any non illiterate from destroying a project


(autoload "mkxref" '("mkxref"))

(setq my_lisp_file "mkxref.lsp"); Place your specific lisp here !

;; Load Supporting Functions
;; Old Version of 'BrowseForFolder' by: Tony Tanzillo
(defun BrowseForFolder ( Message / sh folder parentfolder folderobject result)
 (vl-load-com)
  (setq sh
   (vla-getInterfaceObject
     (vlax-get-acad-object)
       "Shell.Application"
     )
   )


   (setq folder
      (vlax-invoke-method
          sh
          'BrowseForFolder
          0
          Message
          0
       )
   )
   (vlax-release-object sh)


    (if folder
      (progn
         (setq parentfolder
           (vlax-get-property folder 'ParentFolder)
         )
        (setq FolderObject
           (vlax-invoke-method
              ParentFolder
               'ParseName
              (vlax-get-property Folder 'Title)
           )
        )
       (setq result
          (vlax-get-property FolderObject 'Path)
       )
       (mapcar 'vlax-release-object
         (list folder parentfolder folderobject)
       )
     (if (/= (substr result (strlen result)) "\\")
       (setq result (strcat result "\\"))
       result
     )
   )
 )
); defun

(defun C:MAKEXREF ()
;; portions by Tim Willey
  (if (setq DirPath (BrowseForFolder "Select directory to batch drawings."))
   (progn
    (setq DwgList (vl-directory-files DirPath "*.dwg" 1))
    (setq ScrFile (strcat DirPath "batchme.scr"))
    ;(setq Ofil (open ScrFile "W"))
    (setq Ofil (open ScrFile "R"))
     (write-line "SDI 0" Ofil); Force Multi-Document mode
     (write-line (strcat "(setvar " (chr 34) "FILEDIA" (chr 34) " 0)") Ofil)


;; Check for specific project drawing names starting with "Z0001"..
;; Edit this line for your specific batch

     (foreach Dwg DwgList
      ;;(if (= (substr Dwg 1 5) "P0604")
       (progn
        (setq FullPath (strcat DirPath Dwg))
        (write-line (strcat "_.open " (chr 34) FullPath (chr 34)) Ofil)
        (write-line (strcat "(load " (chr 34) my_lisp_file (chr 34) ")") Ofil)
        (write-line (strcat "(setvar " (chr 34) "FILEDIA" (chr 34) " 1)") Ofil)
        (write-line "_.qsave" Ofil)
        (write-line "_.close" Ofil)
       ); progn
      ;;); if
     ); foreach
     (write-line (strcat "(setvar " (chr 34) "FILEDIA" (chr 34) " 1)") Ofil)
     (close Ofil)
     (command "_.script" ScrFile)
   ); progn
  ); if
 (princ)
); function
 (prompt "\nType MAKEXREF to begin the batch process:")
 (princ)


[Kerry]

Mr Z

How about a hint ?

[T.Willey]

Here is one problem.

Code: [Select]

    ;(setq Ofil (open ScrFile "W"))
    (setq Ofil (open ScrFile "R"))
You can't write to a file when you open it for read.  The 'w' stands for 'write' and the 'r' stands for 'read', so switch the comment.

[Kerry]

 

I was going to let him cut his own bait.

[T.Willey]

I was going to let him cut his own bait.

Ah.  I'm sorry for messing up the teaching session.  Next time I will read into your message a little more. 

[KewlToyZ]

Just curious,
I didn't want to write to the file.
I am using an -exporttoautocad to create a new file with a pre-fix and removing AEC Objects?
This R prevents the lisp routine from doing the export?

[T.Willey]

Just curious,
I didn't want to write to the file.
I am using an -exporttoautocad to create a new file with a pre-fix and removing AEC Objects?
This R prevents the lisp routine from doing the export?

What do you think my portion of the code is doing?

[KewlToyZ]

From what I can tell it is batching through the files and saving them on close.
It is loading the routine without actually calling the command from the loaded routine.

I assumed I could run commands aginst the file in memory without saving in read only?

I just needed to change the qsave line and check against the prompt for saving changes on close instead.

[T.Willey]

From what I can tell it is batching through the files and saving them on close.
It is loading the routine without actually calling the command from the loaded routine.

I assumed I could run commands aginst the file in memory without saving in read only?

I just needed to change the qsave line and check against the prompt for saving changes on close instead.

All it is doing is writing the script file.  Then it calls the script command.  That is why you need to open the text file to write.  If you don't want it to save, then remove that line.  If you want to see if the drawing needs to be saved, and then answer the prompts correctly, look at the system variable 'dbmod'.  This will tell you if the drawing has been changed.

[KewlToyZ]

Thanks for the smelling salts...
I was brain dead 

[T.Willey]

Thanks for the smelling salts...
I was brain dead 

That is what we are here for.  Sometimes even if you know how to fish..... one forgets the bait.