Topic: GetRam | GetFreeRam

[MP]

A colleague needed these today -- in case anyone else has need down the road --

Code: [Select]

(defun _GetRam ( / wmiLocater wmiService queryResult result )

[color=green]    ;;========================================================================
    ;;
    ;;  2010/04/22 | Quick & Dirty | Michael Puckett
    ;;
    ;;========================================================================[/color]

    (vl-catch-all-apply
       '(lambda ( )
            (vlax-for item
                (setq queryResult
                    (vlax-invoke
                        (setq
                            wmiLocater (vlax-create-object "WbemScripting.SWbemLocator")
                            wmiService (vlax-invoke wmiLocater 'ConnectServer "." "root\\cimv2")
                        )
                       'ExecQuery
                        (strcat
                            "Select * "
                            "from   Win32_ComputerSystem "
                        )
                    )
                )
                (setq result (vlax-get item 'TotalPhysicalMemory))
            )
        )
    )

    (if queryResult (vlax-release-object queryResult))
    (if wmiService (vlax-release-object wmiService))
    (if wmiLocater (vlax-release-object wmiLocater))

    (if result (/ (distof result) 1024 1024)) [color=green];; return MB[/color]

)

Code: [Select]

(defun _GetFreeRam ( / wmiLocater wmiService queryResult result )

[color=green]    ;;========================================================================
    ;;
    ;;  2010/04/22 | Quick & Dirty | Michael Puckett
    ;;
    ;;========================================================================[/color]

    (vl-catch-all-apply
       '(lambda ( )
            (vlax-for item
                (setq queryResult
                    (vlax-invoke
                        (setq
                            wmiLocater (vlax-create-object "WbemScripting.SWbemLocator")
                            wmiService (vlax-invoke wmiLocater 'ConnectServer "." "root\\cimv2")
                        )
                       'ExecQuery
                        (strcat
                            "Select * "
                            "from   Win32_OperatingSystem "
                        )
                    )
                )
                (setq result (vlax-get item 'FreePhysicalMemory))
            )
        )
    )

    (if queryResult (vlax-release-object queryResult))
    (if wmiService (vlax-release-object wmiService))
    (if wmiLocater (vlax-release-object wmiLocater))

    (if result (/ (distof result) 1024)) [color=green];; return MB[/color]

)
cheers

[Lee Mac]

Thanks Michael - they work well.

If you have the time, I have a few questions about the code:

• Why do you use "." for the Server and "root\\cimv2" for the namespace? Are these the defaults?
• I don't quite understand the structure of SWbemObjectSet that is returned by the ExecQuery, but could you use "Select TotalPhysicalMemory" as opposed to "Select *" ?

Sorry to be a bother.

Lee

[MP]

I didn't put much thought  into it to be honest -- I just converted this vbscript code to lisp.

[MP]

I did lift this part:

Code: [Select]

                        (setq
                            wmiLocater (vlax-create-object "WbemScripting.SWbemLocator")
                            wmiService (vlax-invoke wmiLocater 'ConnectServer "." "root\\cimv2")
                        )
From some previous work I had done and if memory serves Daniel had helped me with it.

[Lee Mac]

Gotcha - thanks mate 

[alanjt]

Cool stuff Michael. Always teaching us something new.

[VovKa]

i wonder why MS guys decided to count "TotalPhysicalMemory" in bytes and "FreePhysicalMemory" in kilobytes?

[MP]

i wonder why MS guys decided to count "TotalPhysicalMemory" in bytes and "FreePhysicalMemory" in kilobytes?

I wondered who would be first to catch that. When I first wrote them I was like "What  the hell? -- Left hand doesn't know what the right hand is doing".

[Andrea]

is something like...

Code: [Select]

(command "_shell" "mem > c:\\mem.txt")
(startapp "notepad" "c:\\mem.txt")

working ?

[HasanCAD]

I tried to show the resule in an alert box bot not working

Code: [Select]

(DEFUN C:GetRamF ()

  (setq GetRam_T (_GetRam))
  (setq GetRam_F (_GetFreeRam))
  (alert GetRam_T"\n" GetRam_F)
  )

[alanjt]

I tried to show the resule in an alert box bot not working

Code: [Select]

(DEFUN C:GetRamF ()

  (setq GetRam_T (_GetRam))
  (setq GetRam_F (_GetFreeRam))
  (alert GetRam_T"\n" GetRam_F)
  )

Look at strcat to join strings.

eg.
(strcat "H" "E" "L" "P") => "HELP"

[HasanCAD]

alanjt
Thanx for your reply
As expected your replies are very fast more than I imagine

[alanjt]

Oops, didn't realize the return was a real. You'll have to convert to string first.
Look at RToS or vl-princ-to-string.

[HasanCAD]

the 2 previous routines and gives alert message

Code: [Select]

; o_|_||
;   Subroutine

;;  2010/04/22 | Quick & Dirty | Michael Puckett

(defun _GetRam ( / wmiLocater wmiService queryResult result )


    (vl-catch-all-apply
       '(lambda ( )
            (vlax-for item
                (setq queryResult
                    (vlax-invoke
                        (setq
                            wmiLocater (vlax-create-object "WbemScripting.SWbemLocator")
                            wmiService (vlax-invoke wmiLocater 'ConnectServer "." "root\\cimv2")
                        )
                       'ExecQuery
                        (strcat
                            "Select * "
                            "from   Win32_ComputerSystem "
                        )
                    )
                )
                (setq result (vlax-get item 'TotalPhysicalMemory))
            )
        )
    )

    (if queryResult (vlax-release-object queryResult))
    (if wmiService (vlax-release-object wmiService))
    (if wmiLocater (vlax-release-object wmiLocater))

    (if result (/ (distof result) 1024 1024)) ;; return MB

)


(defun _GetFreeRam ( / wmiLocater wmiService queryResult result )

  (vl-catch-all-apply
       '(lambda ( )
            (vlax-for item
                (setq queryResult
                    (vlax-invoke
                        (setq
                            wmiLocater (vlax-create-object "WbemScripting.SWbemLocator")
                            wmiService (vlax-invoke wmiLocater 'ConnectServer "." "root\\cimv2")
                        )
                       'ExecQuery
                        (strcat
                            "Select * "
                            "from   Win32_OperatingSystem "
                        )
                    )
                )
                (setq result (vlax-get item 'FreePhysicalMemory))
            )
        )
    )

    (if queryResult (vlax-release-object queryResult))
    (if wmiService (vlax-release-object wmiService))
    (if wmiLocater (vlax-release-object wmiLocater))

    (if result (/ (distof result) 1024)) ;; return MB

)
; o_|_||
;                          Subroutine


; o_|_||
;  mainroutine
(DEFUN C:GetRamF ()

  (setq GetRam_T (_GetRam))
  (setq GetRam_F (_GetFreeRam))
  (alert (strcat "total Ram = " (rtos GetRam_T) "\nFree ram = " (rtos GetRam_F)))
  )

; o_|_||
;                         mainroutine
Thanx for alanjt

[HasanCAD]

Oops, didn't realize the return was a real. You'll have to convert to string first.
Look at RToS or vl-princ-to-string.

I got it after try and error
I tried to use itoa then rtos

This pulling me to ask
Is there a way to know is the result string, intiger or real?

[alanjt]

(type "test")
(type (car (entsel)))
(type '(1 2 3))
(type 1.25)
(type 1)

[MP]

Use the type function:

(type 42) => 'int
(type 42.0) => 'real
(type "42") => 'str

etc.

edit: gat damn I type too slow

[HasanCAD]

MP
You have to get more practises in typing 

[alanjt]

edit: gat damn I type too slow

Post ninja strikes again!

[MP]

 

[JohnK]

> post ninja

*rofl*

[alanjt]