Topic: Save (only) the path of a specific Xref

[Clujna]

Hi all.

I'm trying to find a simple method to extract only the saved path of an specific Xref. The only thing I've achieved has been this paleozoic code:

Code - Auto/Visual Lisp: [Select]

1. (setq XPATHNAME (cdr (assoc 1 (tblsearch "BLOCK" "XREF-A0-BOX"))))
2. (setq XPATH (substr XPATHNAME 1 (- (strlen XPATHNAME)(+ (strlen "XREF-A0-BOX") 4))))

I have tried several combinations with vla-get-path, but it is evident that something I do wrong. Here are a few:

Code - Auto/Visual Lisp: [Select]

1. (setq XPATH (vla-get-path (vlax-ename->vla-object (cdr (assoc 1 (tblsearch "BLOCK" "XREF-A0-BOX"))))))

or

Code - Auto/Visual Lisp: [Select]

1. (setq XPATH (vla-get-path (vlax-ename->vla-object (tblobjname "BLOCK" "XREF-A0-BOX"))))

Thanks in advance.

[mhupp]

Code - Auto/Visual Lisp: [Select]

1. (setq XPATHNAME (vl-filename-directory (cdr (assoc 1 (tblsearch "BLOCK" "XREF-A0-BOX")))))

Sorry never noticed that before.   

[JohnK]

...
https://documentation.help/AutoLISP-Functions/WS1a9193826455f5ff1a32d8d10ebc6b7ccc-68bc.htm

Hey, mhupp. Click on the "vl-filename-directory" function in your code block.   Most times you don't have to link to another website because we worked really hard and developed our own code block with built in help. Cool huh?

[ribarm]

Well, I've asked the same thing back in 2020 I think...
And I did get very comprehensive answer...
Thank you MP again (though he is not among us anymore, but his spirit lives with us...)

So, I've pulled essence from here :
http://www.theswamp.org/index.php?topic=55658.msg597784#msg597784

Code - Auto/Visual Lisp: [Select]

1. (defun xrefpath ( name / mpx-split-folders mpx-join-folders mpx-absolute-path xref doc data2 data1 path-parent path path-type found path-absolute name! correct-name )
2.  
3.   (vl-load-com)
4.  
5.   (defun mpx-split-folders ( path )
6.     ( (lambda ( lst / apart parts )
7.         (foreach x (reverse lst)
8.           (if (eq 92 x)
9.             (setq parts (cons apart parts) apart nil)
10.             (setq apart (cons x apart))
11.           )
12.         )
13.         (mapcar 'vl-list->string (cons apart parts))
14.       )
15.       (vl-string->list (vl-string-trim "\\" (vl-string-translate "/" "\\" path)))
16.     )
17.   )
18.  
19.   (defun mpx-join-folders ( parts )
20.     (if parts
21.       (apply 'strcat
22.         (cons
23.           (car parts)
24.           (mapcar (function (lambda ( p ) (strcat "\\" p))) (cdr parts))
25.         )
26.       )
27.       ""
28.     )
29.   )
30.  
31.   (defun mpx-absolute-path ( parent-path relative-path / parent relative )
32.    (cond
33.       ( (wcmatch relative-path "~*\\*")
34.         (strcat
35.           (vl-string-right-trim "/\\" parent-path)
36.           "\\"
37.           relative-path
38.         )
39.       )
40.       ( (wcmatch relative-path "`.\\*")
41.         (strcat
42.           (vl-string-right-trim "/\\" parent-path)
43.           (substr relative-path 2)
44.         )
45.       )
46.       ( (wcmatch relative-path "`.`.\\*")
47.         (setq
48.             parent   (cdr (reverse (mpx-split-folders (vl-string-right-trim "/\\" parent-path))))
49.             relative (cdr (mpx-split-folders relative-path))
50.         )
51.         (while (eq ".." (car relative))
52.           (setq parent   (cdr parent)
53.                 relative (cdr relative)
54.           )
55.         )
56.         (strcat
57.           (mpx-join-folders (reverse parent))
58.           "\\"
59.           (mpx-join-folders relative)
60.         )
61.       )
62.       ("")
63.     )
64.   )
65.  
66.   (if
67.     (and
68.       (not (vl-catch-all-error-p (setq xref (vl-catch-all-apply 'vla-item (list (vla-get-blocks (vla-get-activedocument (vlax-get-acad-object))) name)))))
69.       (= (vla-get-isxref xref) :vlax-true)
70.       (setq doc (vla-get-document xref))
71.     )
72.     (progn
73.       (vl-catch-all-apply 'eval
74.       '((setq data2
75.           (entget
76.             (cdr
77.               (assoc 360
78.                 (setq data1
79.                   (entget
80.                     (vlax-vla-object->ename xref)
81.                   )
82.                 )
83.               )
84.             )
85.           )
86.         ))
87.       )
88.       (setq path-parent
89.         (cond
90.           ((/= 'vla-object (type doc)) "")
91.           ((vlax-property-available-p doc 'path) (vla-get-path doc))
92.           ((vlax-property-available-p doc 'name) (vl-filename-directory (vla-get-name doc)))
93.           ("")
94.         )
95.       )
96.       (setq path (cdr (assoc 1 data2)))
97.       (setq path-type
98.         (if (wcmatch path "*`.\\*,~*\\*")
99.           "RELATIVE"
100.           "ABSOLUTE"
101.         )
102.       )
103.       (setq found
104.         (cond
105.           ((eq "ABSOLUTE" path-type) (if (findfile (setq path-absolute path)) "TRUE" "FALSE"))
106.           ((findfile (setq path-absolute (mpx-absolute-path path-parent path))) "TRUE")
107.           ("FALSE")
108.         )
109.       )
110.       (setq
111.         name!        (strcase name)
112.         correct-name (if (eq name! (strcase (vl-filename-base path))) "TRUE" "FALSE")
113.       )
114.       (prompt "\nName : ") (princ name)
115.       (prompt "\nCorrectName : ") (princ correct-name)
116.       (prompt "\nSavedPath : ") (princ path)
117.       (prompt "\nAbsolutePath : ") (princ path-absolute)
118.       (prompt "\nPathType : ") (princ path-type)
119.       path
120.     )
121.   )
122. )
123.  

You call it with just :

Code: [Select]

(xrefpath "XREF-A0-BOX")

You should get all important info + output (correct path string as a return of evaluation of function (xrefpath name)...

HTH., M.R.

[Clujna]

Thanks mhupp and Marko (sorry for the delay...) vl-filename-directory it works perfectly.
My intention was to get a quick way to rename Xrefs keeping the original paths, and integrate them into an Acaddoc to apply the changes to large sets of drawings as a script.
I attach the result.

Greetings

[ribarm]

Thanks mhupp and Marko (sorry for the delay...) vl-filename-directory it works perfectly.
My intention was to get a quick way to rename Xrefs keeping the original paths, and integrate them into an Acaddoc to apply the changes to large sets of drawings as a script.
I attach the result.

Greetings

Are you aware that when you rename xrefs-DWG files (childs), you'll also have to alter all DWG files (parents) that use them to have valid data (new xref names after renaming) stored inside DWG files in order to have them operate properly/ordinary like they supposed to?
If you don't alter them - you'll get buch of - missed - not founded signs instead of actual DWG blocks/xrefs inside their parent drawings...

[Clujna]

Yes, I am aware. After applying the script/acaddoc on the most obvious files, I do a general sweep with the Reference Manager to confirm that there are no DWGs left that still have the old Xref.

[Lee Mac]

FWIW, you can also use the fnsplitl function to obtain either the path, filename, or extension for a supplied filepath, e.g.:

Code - Auto/Visual Lisp: [Select]

1. (car (fnsplitl (cdr (assoc 1 (tblsearch "block" "xref-a0-box")))))

[Clujna]

Thank you very much Lee. I confess my absolute ignorance of that function. I'll have to add it to my list of "rare" AutoLISP commands...