Topic: Check if drawing is Open of in Use?

[mgreven]

Hello,

Does anyone have a sample which shows whats the best way to check if a drawing is already open or in use by another user?

Regards,

Marco

[Brick_top]

Finally I think I can help someone!

here

Code: [Select]

(defun IsRO (fileN / fileH)
;;;by RobertB http://forums.augi.com/showpost.php?p=35803&postcount=3
 (cond ((setq fileH (open fileN "a"))
        (close fileH)))
 (not fileH))


[mgreven]

Thanks for the quick respons...

I came up with the following code to check if the drawing is open in de autocad:

(defun testopen   (file / n doc-collection item Dwgname opened)
  ; Routine checks if file is already open in Acad
  (setq n 0)
  (setq doc-collection (vla-get-Documents (vlax-get-acad-object)))
  (vlax-for item doc-collection
    (Setq Dwgname (vla-get-FullName item))
    (If (= Dwgname file) (Setq opened T) )
  )
  (princ opened)
)

[Lee Mac]

Note that your code will only check whether the drawing is open in that instance of the application on your computer - the drawing could be open on another person's computer or in another instance of the application.

[mgreven]

Yeah i know i am only checking on the local autocad.

How can i best check this for other users?

[Lee Mac]

Two ways:

Code - Auto/Visual Lisp: [Select]

1. ;; filename = filename of file to test
2. ;; Returns T if specified file is open
3.  
4. (defun _FileOpen-p ( filename )
5.     (not (vl-file-rename filename filename))
6. )

Similar to above post:

Code - Auto/Visual Lisp: [Select]

1. ;; filename = filename of file to test
2. ;; Returns T if specified file is open
3.  
4. (defun _FileOpen-p ( filename / f )
5.     (if (setq f (open filename "a"))
6.         (close f)
7.         t
8.     )
9. )

[irneb]

I know the attempt to open in append mode is a bit scary, but it shouldn't do anything "wrong".

Anyhow, here's another method. It either returns nil if no-one has the drawing open, or it returns a list containing ("Username" "PC Name" "Date/Time") if someone has it open:

Code: [Select]

(defun DWGOpenedBy (filename / dwl f lst s)
  (if (and (setq dwl (findfile (strcat (vl-filename-directory filename) "\\" (vl-filename-base filename) ".DWL")))
           (not (vl-file-delete dwl)))
    (if (setq f (open dwl "r"))
      (progn
        (while (setq s (read-line f)) (setq lst (cons s lst)))
        (close f)
        (reverse lst)
      )
      T
    )
  )
)Note though it only checks if someone's got it opened in AutoCAD. It would theoretically be possible to open a DWG in NotePad, though I can't imagine why you'd want to  :ugly:

[mgreven]

Thanks for the respons... It is very Helpfull.

[Ketxu]

And another way, check the same dwl file exist :

Code - Auto/Visual Lisp: [Select]

1. (defun _FileOpen-p (f /)
2. (or
3.         (findfile (strcat (vl-filename-directory f) (vl-filename-base f) ".dwl"))
4. ))

[irneb]

Ketxu, that's what mine does as well. Though I try to delete the DWL file - since ACad sometimes leaves these here if it crashes.

[alanjt]

Ketxu, that's what mine does as well. Though I try to delete the DWL file - since ACad sometimes leaves these here if it crashes.

Precisely why I keep this in our startup...

Code: [Select]

; cleanup drawing directory
((lambda (path)
   (if (eq (getvar 'DWGTITLED) 1)
     (foreach file (vl-directory-files path nil 1)
       (if (wcmatch (strcase file) "*.TMP,*.LOG,*.ERR,*.DWL,*.DWL2")
         (vl-file-delete (strcat path file))
       )
     )
   )
 )
  (getvar 'dwgprefix)
)

[Ketxu]

Ketxu, that's what mine does as well. Though I try to delete the DWL file - since ACad sometimes leaves these here if it crashes.

Hi, I was writing it in editor when you post your code (and i saw the alert). Tks you ^^