Topic: How to find if a line is behind a polyline segement

[Coder]

Hello guys .

I would like to know how to find if a line is completely laying behind a Polyline segment ! any idea ?

Thank you.

[ymg]

Use a cross product to test if each point of the line
are on the segment.

You could use the following test twice, however it means
that you need to do it  for every segment of your poly.

Smarter way would be to locate the segment on which the point
lies and test only that segment with the second point of the line.

Code: [Select]

;;                                                                            ;
;; online_p      by ymg                                                        ;
;;                                                                            ;
;; Returns t if point is strictly on line v1-> v2                          ;
;;                                                                            ;
;; Arguments:  p, Point on line to be tested                                                      ;
;;            v1, First point of Polyline Segment                             ;
;;            v2, Second point of Polyline Segment v1->v2                               ;
;;                                                                            ;


(defun online_p (p v1 v2 / xp yp)
   (setq  xp (car  p) yp (cadr  p))

   (zerop
     (- (* (- (cadr v1) yp) (- (car v2) xp)) (* (- (car v1) xp) (- (cadr v2) yp)))
   )
)


[Coder]

Thank you for your reply .

I am sorry I don't know how to test that function , can you give an example please ?

[Lee Mac]

To test whether a line lies beneath a polyline segment (and entirely within the bounds of the segment), I would use the following method:

Code - Auto/Visual Lisp: [Select]

1. (defun line-on-line ( p1 p2 l1 l2 / d1 )
2.     (setq d1 (distance l1 l2))
3.     (and (equal (+ (distance l1 p1) (distance l2 p1)) d1 1e-8)
4.          (equal (+ (distance l1 p2) (distance l2 p2)) d1 1e-8)
5.     )
6. )

Example program:

Code - Auto/Visual Lisp: [Select]

1. (defun c:test ( / a b e p )
2.     (if
3.         (and
4.             (setq a (getpoint   "\nPick 1st line endpoint: "))
5.             (setq b (getpoint a "\nPick 2nd line endpoint: "))
6.             (setq p (entsel    "\nSelect polyline segment: "))
7.             (setq e (car p)
8.                   p (vlax-curve-getparamatpoint e (vlax-curve-getclosestpointto e (trans (cadr p) 1 0)))
9.             )
10.         )
11.         (line-on-line
12.             (trans a 1 0)
13.             (trans b 1 0)
14.             (vlax-curve-getpointatparam e (fix p))
15.             (vlax-curve-getpointatparam e (1+ (fix p)))
16.         )
17.     )
18. )

[Coder]

Thank you Lee for your reply and example.

You are testing the two lines by distance that is logically should be the same if they are beneath each other , correct ?

[David Bethel]

Similarly :

Code - Auto/Visual Lisp: [Select]

1. ;;;ARG -> TestPt LinePt1 LinePt2 Fuzz
2. ;;;RET T nil
3. (defun is_pt_online (pt l1 l2 fz)
4.   (and (numberp fz)
5.        (equal (distance l1 l2)
6.               (+ (distance l1 pt)
7.                  (distance l2 pt)) fz)))
8.  
9. ;;;ARG -> LinePt1 LinePt2 SegPt1 SegPt2 Fuzz
10. ;;;RET T nil
11. (defun is_line_on_seg (l1 l2 s1 s2 fz)
12.    (and (is_pt_online l1 s1 s2 fz)
13.         (is_pt_online l2 s1 s2 fz)))
14.  
15.  

[Lee Mac]

You are testing the two lines by distance that is logically should be the same if they are beneath each other , correct ?

Yes, the function is essentially using the Triangle Inequality with each line endpoint tested against the two polyline segment endpoints.

[Coder]

Similarly :

Code - Auto/Visual Lisp: [Select]

1. ;;;ARG -> TestPt LinePt1 LinePt2 Fuzz
2. ;;;RET T nil
3. (defun is_pt_online (pt l1 l2 fz)
4.   (and (numberp fz)
5.        (equal (distance l1 l2)
6.               (+ (distance l1 pt)
7.                  (distance l2 pt)) fz)))
8.  
9. ;;;ARG -> LinePt1 LinePt2 SegPt1 SegPt2 Fuzz
10. ;;;RET T nil
11. (defun is_line_on_seg (l1 l2 s1 s2 fz)
12.    (and (is_pt_online l1 s1 s2 fz)
13.         (is_pt_online l2 s1 s2 fz)))
14.  
15.  

Thank you David , that works perfectly. 

You are testing the two lines by distance that is logically should be the same if they are beneath each other , correct ?

Yes, the function is essentially using the Triangle Inequality with each line endpoint tested against the two polyline segment endpoints.

Thank you for the codes and for replying to my question.

Many thanks guys.

[irneb]

I was just wondering ... since it's just a line and a straight segment, and you're looking to see if the line is "completely" underneath the PL ... all you really need to do is test if the line's endpoints lie on the polyline.

Code - Auto/Visual Lisp: [Select]

1. (vl-load-com)
2. (defun c:LinePolyTest  (/ line poly lStart lEnd pStart pEnd dist)
3.   (setq poly   (entsel "\nPick polyline: ")
4.         line   (entsel "\nPick line: ")
5.         dist   (getdist "\nEnter maximum error distance: ")
6.         lStart (vlax-curve-getStartPoint (car line))
7.         lEnd   (vlax-curve-getEndPoint (car line))
8.         pStart (vlax-curve-getClosestPointTo (car poly) lStart)
9.         pEnd   (vlax-curve-getClosestPointTo (car poly) lEnd))
10.   (princ
11.     (strcat
12.       "The line is"
13.       (if (and (equal lStart pStart dist)
14.                (equal lEnd pEnd dist))
15.         " "
16.         " not")
17.       " underneath the polyline."))
18.   (princ))

I'm using a user specified distance as a fuzz factor, since the chance that floating point numbers in points are exactly the same is close to nil even if they're as close as damit. Change to whatever other fuzz you'd prefer.

Of course, this won't work if the line extends beyond the polyline - in that case the others' codes should suffice.

[Lee Mac]

I was just wondering ... since it's just a line and a straight segment, and you're looking to see if the line is "completely" underneath the PL ... all you really need to do is test if the line's endpoints lie on the polyline.

But what if the line endpoints lie on different polyline segments?

[irneb]

But what if the line endpoints lie on different polyline segments?

OK, yes, I can then agree on that. Something like a triangle with 2 sides being the polyline and another the line - that would break my code and give a false positive. So I'd thus need to check if both of the line's endpoints fall within the "same" segment - i.e. the parameter needs to be in the same integer range.

But then also in the same breath it's possible to have two segments be co-linear and the line spanning through them. I think this may be a bit more complicated than it seemed. Will have to think about it more.

[David Bethel]

And we assumed the OP had all points / lines on the same Z axis

[irneb]

And we assumed the OP had all points / lines on the same Z axis

And that the polyline has no bulges.

[Lee Mac]

And we assumed the OP had all points / lines on the same Z axis

No, the functions which test the straight-line distance between a given line endpoint and the two polyline segment endpoints will also perform correctly with 3D points (providing all three points are expressed relative to the same coordinate system, which they are in my example).

[David Bethel]

No, the functions which test the straight-line distance between a given line endpoint and the two polyline segment endpoints will also perform correctly with 3D points (providing all three points are expressed relative to the same coordinate system, which they are in my example).

Yes, that is true.  My thought was more of , if in a plan view, were the line were directly under the segment, but not on the same z axis.  A 2D only kind of test.

-David

[Lee Mac]

No, the functions which test the straight-line distance between a given line endpoint and the two polyline segment endpoints will also perform correctly with 3D points (providing all three points are expressed relative to the same coordinate system, which they are in my example).

Yes, that is true.  My thought was more of , if in a plan view, were the line were directly under the segment, but not on the same z axis.  A 2D only kind of test.

-David

Oh I see - a sort of 'apparent collinearity', view-dependent.