Topic: Help with reactor

[Coder]

Hello guys .

I am trying to write a reactor to not allow any changes on a text I insert and re write it if modified .

Code: [Select]

(defun c:write (/ pnt txtobj)
  (vl-load-com)
     (setq pnt (getpoint "\n text location :"))
      (setq txtobj (entmakex (list '(0 . "TEXT")
                              (cons 10 pnt)
                              (cons 11 pnt)
                              (cons 40 1.0)
                              (cons 1 "Text example")
                        )
              )
      )
      (setq *obj* (vlr-object-reactor
                    (list (vlax-ename->vla-object txtobj))
                    "example-1"
                    '((:vlr-modified . modifytext))
                  )
      )
  (princ)
)

(defun modifytext (noifier reactor paparms /)
  (vla-put-textstring (vlr-data reactor) "Text example")
)

thanks in advance .

[dgorsman]

As noted in the developers documentation for reactors, trying to modify the entity you are reacting to is a Bad Thing To Do.   

[roy_043]

Note that (vlr-data reactor) does not point to the text object.

[roy_043]

A way around the limitation referred to by dgorsman is to use an acdb reactor instead of an object reactor.

It is important to realise that an acdb reactor will react to every change to the database so you need some condition inside the callback function to limit actions to certain cases.

But there are other, easier, ways to 'protect' a text entity that do not rely on Lisp code and reactors. I am thinking of a locked layer or putting the entity in a non-explodable block.

Note: The code was only tested BricsCAD.

Code: [Select]

(defun c:write (/ pnt enameTxt)
  (vl-load-com)
  (setq pnt (getpoint "\nText location: "))
  (setq enameTxt
    (entmakex
      (list
        '(0 . "TEXT")
        (cons 10 pnt)
        (cons 11 pnt)
        (cons 40 1.0)
        (cons 1 "Text example")
      )
    )
  )
  (setq *acdbReactor*
    (vlr-acdb-reactor
      enameTxt ; Reactor data.
      '((:vlr-objectmodified . CallBackObjectModified))
    )
  )
  (princ)
)

(defun CallBackObjectModified (rea lst)
  (print "> CallBackObjectModified")
  (if
    (and
      (equal (cadr lst) (vlr-data rea))
      (vlax-write-enabled-p (cadr lst))
    )
    (progn
      (print "> CallBackObjectModified > Action")
      (vla-put-textstring (vlax-ename->vla-object (cadr lst)) "Text example")
    )
  )
)

[Coder]

Thank you roy so much .

The routine does not reset the text if it is modified 

[roy_043]

Thank you roy so much .

The routine does not reset the text if it is modified 

The code then only works on BricsCAD and not on AutoCAD.

[roy_043]

Maybe using (vla-sendcommand) and a 'PostProcess' will work on AutoCAD? The code below works fine on BricsCAD.

Code: [Select]

(defun c:write (/ pnt enameTxt)
  (vl-load-com)
  (setq pnt (getpoint "\nText location: "))
  (setq enameTxt
    (entmakex
      (list
        '(0 . "TEXT")
        (cons 10 pnt)
        (cons 11 pnt)
        (cons 40 1.0)
        (cons 1 "Text example")
      )
    )
  )
  (setq *acdbReactor*
    (vlr-acdb-reactor
      enameTxt ; Reactor data.
      '((:vlr-objectmodified . CallBackObjectModified))
    )
  )
  (princ)
)

(defun CallBackObjectModified (rea lst /)
  (print "> CallBackObjectModified")
  (if (equal (cadr lst) (vlr-data rea))
    (progn
      (print "> CallBackObjectModified > Action: Send command")
      (vla-sendcommand (vla-get-activedocument (vlax-get-acad-object)) "(PostProcess) ")
    )
  )
)

(defun PostProcess ( / enameTxt)
  (print "> PostProcess")
  (if (not (vlax-erased-p (setq enameText (vlr-data *acdbReactor*))))
    (progn
      (print "> PostProcess > Action")
      (vla-put-textstring (vlax-ename->vla-object enameText) "Text example")
    )
  )
  (princ)
)

[tombu]

Plot the text to PDF and attach it to the drawing. 

[Coder]

Maybe using (vla-sendcommand) and a 'PostProcess' will work on AutoCAD? The code below works fine on BricsCAD.

Thank you roy for your help , that is too kind work from you . 

Your codes work but it keeps printing in the command line too much until I press esc button to stop .

Select an annotation object or [Undo]: (PostProcess)
"> PostProcess"
"> PostProcess > Action"
"> CallBackObjectModified"
"> CallBackObjectModified > Action: Send command"

[roy_043]

OK, so obviously a global variable is required to avoid a chain reaction on AutoCAD.

Code: [Select]

(defun c:write (/ pnt enameTxt)
  (vl-load-com)
  (setq pnt (getpoint "\nText location: "))
  (setq enameTxt
    (entmakex
      (list
        '(0 . "TEXT")
        (cons 10 pnt)
        (cons 11 pnt)
        (cons 40 1.0)
        (cons 1 "Text example")
      )
    )
  )
  (setq *acdbReactor*
    (vlr-acdb-reactor
      enameTxt ; Reactor data.
      '((:vlr-objectmodified . CallBackObjectModified))
    )
  )
  (princ)
)

(defun CallBackObjectModified (rea lst /)
  (print "> CallBackObjectModified")
  (if
    (and
      (not *waitingForPostProcessP*)
      (equal (cadr lst) (vlr-data rea))
    )
    (progn
      (print "> CallBackObjectModified > Action: Send command")
      (setq *waitingForPostProcessP* T)
      (vla-sendcommand (vla-get-activedocument (vlax-get-acad-object)) "(PostProcess) ")
    )
  )
)

(defun PostProcess ( / enameTxt)
  (print "> PostProcess")
  (if
    (and
      (not (vlax-erased-p (setq enameText (vlr-data *acdbReactor*))))
      (/= (vla-get-textstring (vlax-ename->vla-object enameText)) "Text example")
    )
    (progn
      (print "> PostProcess > Action")
      (vla-put-textstring (vlax-ename->vla-object enameText) "Text example")
    )
  )
  (setq *waitingForPostProcessP* nil)
  (princ)
)

[Coder]

Hi Roy 

Nothing happen after modifying the text  it does not go back to original text example .

Many thanks

[Lee Mac]

Here's another way to approach it:

Code - Auto/Visual Lisp: [Select]

1. (setq write:id "text-reactor")
2.  
3. (defun c:write ( / ins )
4.     (write:removereactors write:id)
5.     (if (setq ins (getpoint "\nText location: "))
6.         (vlr-object-reactor
7.             (list
8.                 (vla-addtext
9.                     (vlax-get-property (vla-get-activedocument (vlax-get-acad-object))
10.                         (if (= 1 (getvar 'cvport))
11.                             'paperspace
12.                             'modelspace
13.                         )
14.                     )
15.                     "Text Example"
16.                     (vlax-3D-point (trans ins 1 0))
17.                     (getvar 'textsize)
18.                 )
19.             )
20.             write:id
21.            '((:vlr-modified . write:callback))
22.         )
23.     )
24.     (princ)
25. )
26.  
27. (defun c:unwrite nil
28.     (write:removereactors write:id)
29.     (princ)
30. )
31.  
32. (defun write:removereactors ( str )
33.     (foreach typ (vlr-reactors :vlr-object-reactor :vlr-command-reactor)
34.         (foreach rea (cdr typ)
35.             (if (= str (vlr-data rea))
36.                 (vlr-remove rea)
37.             )
38.         )
39.     )
40. )
41.  
42. (defun write:callback ( own rea arg )
43.     (setq write:data (list own rea))
44.     (vlr-command-reactor write:id
45.        '(
46.             (:vlr-commandended     . write:modify)
47.             (:vlr-commandcancelled . write:modify)
48.             (:vlr-commandfailed    . write:modify)
49.         )
50.     )
51.     (princ)
52. )
53.  
54. (defun write:modify ( rea arg )
55.     (vlr-remove rea)
56.     (if (and write:data
57.              (not (wcmatch (strcase (car arg)) "U,UNDO"))
58.              (vlax-read-enabled-p  (car write:data))
59.              (/= "Text Example" (vla-get-textstring (car write:data)))
60.              (vlax-write-enabled-p (car write:data))
61.         )
62.         (progn
63.             (vlr-remove (cadr write:data))
64.             (vla-put-textstring (car write:data) "Text Example")
65.             (vlr-add (cadr write:data))
66.         )
67.     )
68.     (setq write:data nil)
69.     (princ)
70. )
71.  
72. (vl-load-com) (princ)

[Coder]

Thank you so much LEE for your help , it worked like a charm 

Thanks also to ROY for his hard work and lovely willing to help me   

Great people and forum .

[roy_043]

FWIW: Here is another attempt using an acdb reactor and a 'PostProcess':

Code: [Select]

(defun c:write (/ pnt enameTxt)
  (vl-load-com)
  (setq pnt (getpoint "\nText location: "))
  (setq enameTxt
    (entmakex
      (list
        '(0 . "TEXT")
        (cons 10 pnt)
        (cons 11 pnt)
        (cons 40 1.0)
        (cons 1 "Text example")
      )
    )
  )
  (setq *acdbReactor*
    (vlr-acdb-reactor
      enameTxt ; Reactor data.
      '((:vlr-objectmodified . CallBackObjectModified))
    )
  )
  (princ)
)

(defun CallBackObjectModified (rea lst)
  (print "> CallBackObjectModified")
  (if
    (and
      (not *postProcessActiveP*)
      (equal (cadr lst) (vlr-data rea))
    )
    (progn
      (print "> CallBackObjectModified > Action: Send command")
      (vla-sendcommand (vla-get-activedocument (vlax-get-acad-object)) "(PostProcess) ")
    )
  )
)

(defun PostProcess ( / objectTxt)
  (print "> PostProcess")
  (if
    (and
      (vlax-write-enabled-p (setq objectTxt (vlax-ename->vla-object (vlr-data *acdbReactor*))))
      (vlax-read-enabled-p objectTxt)
    )
    (progn
      (print "> PostProcess > Action")
      (if (/= (vla-get-textstring  objectTxt) "Text example")
        (progn
          (print "> PostProcess > Action > Change text")
          (setq *postProcessActiveP* T)
          (vla-put-textstring objectTxt "Text example")
          (setq *postProcessActiveP* nil)
        )
      )
    )
  )
  (princ)
)

[Coder]

Roy , it does not work and it behaves like the routine in post No - 6