Topic: How to gather between these two methods ?

[Coder]

Hello .

Is it possible to gather between these two methods with the *ssget* function ?

This one .

Code: [Select]

"_:L"
And this .

Code: [Select]

"_X"
Many thanks .

[Lee Mac]

I'm afraid not - you would have to construct a list of locked layer names and exclude these from the Selection.

[Lee Mac]

Something like this would suffice:

Code: [Select]

(
  (lambda ( / x l )
    (while (setq x (tblnext "LAYER" (null x)))
      (if (= 4 (logand 4 (cdr (assoc 70 x))))
        (setq l (cons "," (cons (cdr (assoc 2 x)) l)))
      )
    )
    (if l
      (ssget "_X" (list '(-4 . "<NOT") (cons 8 (apply 'strcat (cdr l))) '(-4 . "NOT>")))
      (ssget "_X")
    )
  )
)


[Coder]

Clever idea Lee . 

I did not understand the use of constructing Layer names to become with comma. Example ("," "0") .

Code: [Select]

(setq l (cons "," (cons (cdr (assoc 2 x)) l)))
And this .

Code: [Select]

(apply 'strcat .....
Many Thanks .

[Lee Mac]

I did not understand the use of constructing Layer names to become with comma. Example ("," "0")

I would recommend you first read the help on the wcmatch function.

Following that, type this at the command line:

Code: [Select]

(setq lst '("," "A" "," "B" "," "C"))
Then this:

Code: [Select]

(apply 'strcat (cdr lst))
And see if you can work out what is happening 

[Lee Mac]

If you didn't want to use wildcards, here is another method:

Code: [Select]

(
  (lambda ( / x l )
    (while (setq x (tblnext "LAYER" (null x)))
      (if (= 4 (logand 4 (cdr (assoc 70 x))))
        (setq l (cons (cdr (assoc 2 x)) l))
      )
    )
    (if l
      (ssget "_X"
        (append
         '((-4 . "<NOT") (-4 . "<OR"))
          (mapcar '(lambda ( x ) (cons 8 x)) l)
         '((-4 . "OR>") (-4 . "NOT>"))
        )
      )
      (ssget "_X")
    )
  )
)

[gile]

Lee,

No need to trim starting or ending comma, neither to check if the filter is empty:

Code: [Select]

((lambda (/ f l)
   (setq f "")
   (while (setq l (tblnext "layer" (not l)))
     (if (= 4 (logand 4 (cdr (assoc 70 l))))
       (setq f (strcat f (cdr (assoc 2 l)) ","))
     )
   )
   (ssget "_X" (list '(-4 . "<not") (cons 8 f) '(-4 . "not>")))
 )
)

[Lee Mac]

Thanks gile 

[CAB]

Similar here:

Code: [Select]

 (setq filter "")
  (while (setq elst (tblnext "layer" (null elst)))
    (if (/= 4 (logand 4 (cdr (assoc 70 elst))))
      (setq filter (strcat filter (cdr (assoc 2 elst)) ","))
    )
  )
  (and (= filter "")(setq filter "*"))
  (setq SS (ssget "_X" (list (cons 8 filter))))