Topic: attmode toggle

[Pad]

Hi

Could you please have a quick look at this short lisp and tell me what's wrong?

Code: [Select]

(defun c:ATTMODETOG (attmodetog)

(setq attmodesetting (getvar "attmode"))
(cond ((= attmodesetting 1)) (setvar "attmode" 2))
(princ "\nAttributes On."))

((= attmodesetting 2) (setvar "attmode" 0))
(princ "\nAttributes Off."))

((= attmodesetting 0) (setvar "attmode" 1))
(princ "\nAttributes Normal."))
)

(command "regenall")

    (princ)
);defun
Thanks
Patrick

[ronjonp]

You're parens don't match...take a look at this (did not test):

Code: [Select]

(defun c:attmodetog (/ attmodesetting);;
  (setq attmodesetting (getvar "attmode"))
  (cond ((= attmodesetting 1) (setvar "attmode" 2) (princ "\nAttributes On."))
        ((= attmodesetting 2) (setvar "attmode" 0) (princ "\nAttributes off."))
        ((= attmodesetting 0) (setvar "attmode" 1) (princ "\nAttributes Normal."))
  )
  (command "regenall")
  (princ)
)

[Pad]

ah i see, my parenthesis were all over he place. Thank you, that's fixed it.

I have been playing with invisible attributes today.
Is it not possible for invisible attributes to be gripped, when they are made visible using attmode or attdisp?

I'd like to be able to move 'visible invisible attributes' whilst drafting so I can read them in cluttered areas.

Thanks

[Pad]

Hello

I am having a terrible time with toggling invisible/visible attributes.
The attributes sometimes come out of sync with each other and I often loose the ability to use the grips (acad2004).

Anyway CAB (I think) kindly wrote this lisp which seems quite bullet proof:

(defun c:testOFF (/ ss idx ename att)
  (and
    (setq ss (ssget '((0 . "INSERT") (66 . 1))))
    (setq idx -1)
    (while (setq ename (ssname ss (setq idx (1+ idx))))
      (foreach att (vlax-invoke (vlax-ename->vla-object ename) 'getattributes)
        (if (member (vla-get-tagstring att) '("NO" "CODE"))
          (vla-put-Invisible att :vlax-true)
        )
      )
    )
  )
  (princ)
)

And I have modified it to now turn the attributes visible again (vla-put-Invisible att :vlax-false)

How can i modify this, so that instead of asking me to select objects it automatically selects all objects within model space?
I'd also like to modify it so that it toggles between the two, what variable can i use to enable this?  The attmode variable in this case doesn't change.

Thanks
Patrick

[ronjonp]

Give this a try..to select all objects without user input you need to use "_x" in the ssget.  To toggle...all you have to is check the visibility of the att then do the opposite.

Code: [Select]

(defun c:testoff (/ ss idx ename att)
  (and (setq ss (ssget "_x" '((0 . "INSERT") (410 . "Model") (66 . 1))))
       (setq idx -1)
       (while (setq ename (ssname ss (setq idx (1+ idx))))
         (foreach att (vlax-invoke (vlax-ename->vla-object ename) 'getattributes)
           (if (member (vla-get-tagstring att) '("NO" "CODE"))
             (if (= (vla-get-invisible att) :vlax-true)
               (vla-put-invisible att :vlax-false)
               (vla-put-invisible att :vlax-true)
             )
           )
         )
       )
  )
  (princ)
)

[Pad]

That is absolutely perfect, exactly what I was after.
Thank you so much.

_x is very handy to know

Regarding invisibility I had no idea what to do, as according to BATTMAN the invisible attribs aren't invisible.

Great stuff
Cheers!

[JohnK]

<snip>
Regarding invisibility I had no idea what to do, as according to BATTMAN the invisible attribs aren't invisible.
<snip>

That's because that invisible is not the same as the invisible in an attribute.
DXF group code 70 is what your thinking of.

70
 Attribute flags:
1 = Attribute is invisible (does not appear)
2 = This is a constant attribute
4 = Verification is required on input of this attribute
8 = Attribute is preset (no prompt during insertion)

[Pad]

Thanks Se7en, I thought it would be something along those lines.

This invisible seems to be a much better method than the DXF 70 code.
I'll have to look into these codes some time, but so far I only have slim grasp of lisp.

This method doesn't suffer from the same loss of grips as the attmode method, so everything is good.

Cheers
P

[JohnK]

No problem.

"vla-put-invisible" is easier code wise (well, shorter sorta) but slower (but you wouldnt be able to tell the difference).

If you want to learn, you found the right place.