There is no start or end point property.
Perhaps this will help you out. I don't remember the source for this code.
;;;The entity definition data of an arc doesn't reveal much direct information about that arc.
;;;All you get are: center point, start angle, end angle and radius.
;;;However, with a bit of math, you can get much more. Here's how:
;;; Returns a list containing both arc endpoints, arc length and chord length
(defun arc-info (ent / lst cen rad ang1 ang2 p1 p2 len chord)
(setq lst (entget ent)
cen (cdr (assoc 10 lst)) ; center point
rad (cdr (assoc 40 lst)) ; radius
ang1 (cdr (assoc 50 lst)) ; start angle
ang2 (cdr (assoc 51 lst)) ; end angle
inc (- ang1 ang2) ; included angle
inc (if (minusp inc) (- inc) (- (* pi 2.0) inc)) ; included angle correction
p1 (polar cen ang1 rad) ; start point
p2 (polar cen ang2 rad) ; end point
len (* (/ inc (* 2 pi)) ; arc length: (included angle / 360) * circumference
(* 2 (* pi rad))
)
;; another arc length (abs (* (- ang1 ang2) ra))
chord (distance p1 p2) ; chord length
)
(list p1 p2 len chord)
)
;;;Arguments
;;;The entity name of an arc
;;;
;;;Example
;;;(arc-info (car (entsel)))
;;;