Topic: Can a file be moved using LISP...

[A_LOTA_NOTA]

When a drawing has been revised we create a PDF and move the old PDF to a "VOID" folder. So for example when 301s1r1.pdf is created 301s1r0.pdf would need to be moved. Could lisp be used to accomplish the moving of the old file?

[Lee Mac]

Maybe something like this?

Code: [Select]

(defun LM:MoveFile ( file dest / fso result ) (vl-load-com)
  (if
    (and
      (setq file (findfile file))
      (setq dest (strcat (vl-string-right-trim "\\" (vl-string-translate "/" "\\" dest)) "\\"))
      (or (vl-file-directory-p dest) (vl-mkdir dest))
      (setq fso  (vlax-create-object "Scripting.FileSystemObject"))
    )
    (setq result (not (vl-catch-all-error-p (vl-catch-all-apply 'vlax-invoke (list fso 'MoveFile file dest)))))
  )
  (if fso (vlax-release-object  fso))
  result
)
e.g.

Code: [Select]

(LM:MoveFile "C:\\MyFile.txt" "C:\\MyFolder\\")
MyFolder is created if non-existent.

[alanjt]

MoveFile

Bah! I tried Move, it didn't work and I went on with my business.

[LE3]

or the old fashion way (of DOS) via command SHELL

Command: SH
OS Command: MOVE E:\\TEST.TXT E:\\TEMP

[Lee Mac]

MoveFile

Bah! I tried Move, it didn't work and I went on with my business.

The 'Move' method may also be used, but it requires different parameters:

Code: [Select]

(defun LM:MoveFile2 ( file dest / fso fob result ) (vl-load-com)
  (if
    (and
      (setq file (findfile file))
      (setq dest (strcat (vl-string-right-trim "\\" (vl-string-translate "/" "\\" dest)) "\\"))
      (or (vl-file-directory-p dest) (vl-mkdir dest))
      (setq fso  (vlax-create-object "Scripting.FileSystemObject"))
      (setq fob  (vlax-invoke fso 'getfile file))
    )
    (setq result (not (vl-catch-all-error-p (vl-catch-all-apply 'vlax-invoke (list fob 'Move dest)))))
  )
  (if fso (vlax-release-object  fso))
  (if fob (vlax-release-object  fob))
  result
)

[Lee Mac]

Or for moving files and folders:

Code: [Select]

(defun LM:Move ( target dest / fso fob result ) (vl-load-com)
  (if
    (and
      (setq target (findfile target))     
      (setq dest   (strcat (vl-string-right-trim "\\" (vl-string-translate "/" "\\" dest)) "\\"))
      (or (vl-file-directory-p dest) (vl-mkdir dest))
      (setq fso    (vlax-create-object "Scripting.FileSystemObject"))
      (setq fob    (vlax-invoke fso (if (vl-file-directory-p target) 'getfolder 'getfile) target))
    )
    (setq result (not (vl-catch-all-error-p (vl-catch-all-apply 'vlax-invoke (list fob 'Move dest)))))
  )
  (if fso (vlax-release-object  fso))
  (if fob (vlax-release-object  fob))
  result
)

Code: [Select]

(LM:Move "C:\\MyFile.txt" "C:\\MyFolder\\")

(LM:Move "C:\\NewFolder" "C:\\MyFolder\\")

[LE3]

something so easy like this:

Code: [Select]

(setq OriginalNamePath "E:\\TEST.TXT")
(setq NewNamePath "E:\\TEMP")
;; or change the name too
(setq NewNamePath "E:\\TEMP\\TEST1.TXT")
(defun MoveMyFile(OriginalNamePath NewNamePath)
    (command "SHELL" (strcat "MOVE " OriginalNamePath " " NewNamePath)))

[VovKa]

yep

Code: [Select]

(vl-file-rename old-fileorfoldername new-fileorfoldername)

[Lee Mac]

yep

Code: [Select]

(vl-file-rename old-fileorfoldername new-fileorfoldername)

lol, Trust you to find the easy way 

Oh well, at least I got some practice with the FSO 

[alanjt]

yep

Code: [Select]

(vl-file-rename old-fileorfoldername new-fileorfoldername)

Nicely done. :kewl:

[pBe]

Another.... CMD/DOS

Code: [Select]

(defun MoveDos ( File Fldr)
      (startapp "CMD /c" (strcat (vl-prin1-to-string "move /y ") (vl-princ-to-string File) " "
        (vl-princ-to-string Fldr)))
        )
(MoveDos "D:\\File.txt" "D:\\Folder\\")

[alanjt]

Lee, would you mind posting the direct link to the documentation you were reading for FSO?

[Lee Mac]

Lee, would you mind posting the direct link to the documentation you were reading for FSO?

Sure,

http://msdn.microsoft.com/en-us/library/kxtftw67%28v=VS.85%29.aspx

[alanjt]

Lee, would you mind posting the direct link to the documentation you were reading for FSO?

Sure,

http://msdn.microsoft.com/en-us/library/kxtftw67%28v=VS.85%29.aspx

Thanks.

[Dashmonkey]

Lee, would you mind posting the direct link to the documentation you were reading for FSO?

Sure,

http://msdn.microsoft.com/en-us/library/kxtftw67%28v=VS.85%29.aspx

Thanks.

Many thanks indeed!