Public Class TypedValueList
Inherits List(Of TypedValue)
Public Sub New(ParamArray args As TypedValue())
AddRange(args)
End Sub
' Make it a bit easier to add items:
Public Sub Add(ByVal typecode As Integer, ByVal value As Object)
MyBase.Add(New TypedValue(typecode, value))
End Sub
' Implicit conversion to SelectionFilter
Public Shared Widening Operator CType(ByVal src As TypedValueList) As SelectionFilter
Return If(src IsNot Nothing, New SelectionFilter(src), Nothing)
End Operator
' Implicit conversion to ResultBuffer
Public Shared Widening Operator CType(ByVal src As TypedValueList) As ResultBuffer
Return If(src IsNot Nothing, New ResultBuffer(src), Nothing)
End Operator
' Implicit conversion to TypedValue[]
Public Shared Widening Operator CType(ByVal src As TypedValueList) As TypedValue()
Return If(src IsNot Nothing, src.ToArray(), Nothing)
End Operator
' Implicit conversion from TypedValue[]
Public Shared Widening Operator CType(ByVal src As TypedValue()) As TypedValueList
Return If(src IsNot Nothing, New TypedValueList(src), Nothing)
End Operator
' Implicit conversion from SelectionFilter
Public Shared Widening Operator CType(ByVal src As SelectionFilter) As TypedValueList
Return If(src IsNot Nothing, New TypedValueList(src.GetFilter()), Nothing)
End Operator
' Implicit conversion from ResultBuffer
Public Shared Widening Operator CType(ByVal src As ResultBuffer) As TypedValueList
Return If(src IsNot Nothing, New TypedValueList(src.AsArray()), Nothing)
End Operator
End Class