Topic: AutoCAD text...to word..

[Andrea]

Hi all..

Is it possible to export AutoCAD "DTEXT" in a word or txt file ??

thanks.

[Kerry]

yes

[CottageCGirl]

yes

now, that's helpful...isn't it.....

[Kerry]

To open a file for writing;

Code: [Select]

(setq file_open (open "c:\\name.txt" "w"))then you want to write to it using;

Code: [Select]

(write-line "some string" file_open)when you're done make sure you close the file

Code: [Select]

(close file_open)
that's a start anyway.

[Kerry]

and because it's in my contract ..

Code: [Select]

(DEFUN c:txtexport (/ ss ent fh fn hnd index sslen txt)
   ;; codehimbelonga kwb@theSwamp
   (IF (SETQ ss (SSGET '((0 . "TEXT"))))
      (PROGN (SETQ index 0
                   sslen (SSLENGTH ss)
                   fn  (GETFILED "Text Export/Append to File" "" "txt" 1)
             )
             (IF  fn
                (PROGN (SETQ fh (OPEN fn "a"))
                       (WHILE (< index sslen)
                          (SETQ hnd (SSNAME ss index)
                                ent (ENTGET hnd)
                                txt (CDR (ASSOC 1 ent))
                                index (1+ index)
                          )
                          (PRINC (STRCAT txt "\n") fh)
                       )
                       (CLOSE fh)
                )
             )
      )
   )
   (PRINC)
)

[Mark]

and because it's in my contract ..

 

[Kerry]

or, a little more efficient, if it makes a difference ..

Code: [Select]

(DEFUN c:txtexport (/ ss  fh fn sslen index )
   ;; codehimbelonga kwb@theSwamp
   (IF (AND (SETQ ss (SSGET '((0 . "TEXT"))))
            (SETQ fn (GETFILED "Text Export/Append to File" "" "txt" 1))
       )
      (PROGN
         (SETQ fh    (OPEN fn "a")
               index -1
               sslen (SSLENGTH ss)
         )
         (WHILE (< (SETQ index (1+ index)) sslen)
            (PRINC (STRCAT (CDR (ASSOC 1 (ENTGET (SSNAME ss index)))) "\n") fh)
         )
         (CLOSE fh)
      )
   )
   (PRINC)
)


[LE]

For the $75 USD an hour Mark is paying.... you can also provide the way to do as RTF file no?

[Kerry]

hehehehe

with the right incentive, I can provide almost anything    

sometimes just having my sense of humour appreciated is enough.

[Slim©]

Sounds like someone is looking for a raise in pay.....

[Arizona]

hehehehe

with the right incentive, I can provide almost anything    

sometimes just having my sense of humour appreciated is enough.

You have a great sense of humor!!! Are you twice as funny in person? By that I mean, are we missing all the facial expressions, etc...

[Kerry]

don't believe the advertising Arizona, I'm really a grouch .. just sometimes act a little silly or see the rediculous is a situation that isn't there. There is a medical term for it, but the word is too hard to spell.

[Kerry]

 ... and you're welcome Andrea , any time.

[MickD]

 stop... your killing me