Topic: Drawing log application

[ElpanovEvgeniy]

Code: [Select]

(defun c:acad_log (/)
 (vlr-remove-all)
 (defun my_reac ()
  (vlr-command-reactor nil '((:vlr-commandended . st_com)))
 ) ;_  defun
 (defun st_com (a1 a2 / f)
  (setq f (open "D:\\acad_log.txt" "a"))
  (write-line (car a2) f)
  (close f)
 ) ;_  defun
  (my_reac)
)

[GDF]

Code: [Select]

(defun c:acad_log (/)
 (vlr-remove-all)
 (defun my_reac ()
  (vlr-command-reactor nil '((:vlr-commandended . st_com)))
 ) ;_  defun
 (defun st_com (a1 a2 / f)
  (setq f (open "D:\\acad_log.txt" "a"))
  (write-line (car a2) f)
  (close f)
 ) ;_  defun
  (my_reac)
)

You could add this to it.......

Code: [Select]

;;;Elpanov Evgeniy
(defun c:acad_log (/)
  (vlr-remove-all)
  (defun my_reac ()
    (vlr-command-reactor nil '((:vlr-commandended . st_com)))
  ) ;_  defun
  (defun st_com (a1 a2 / f xdate mo day yr hr mn dg us)
    (setq f (open "C:\\temp\\acad_log.txt" "a"))
    (setq  XDATE (rtos (getvar "cdate") 2 4)
MO   (substr XDATE 5 2)
DAY  (substr XDATE 7 2)
YR   (substr XDATE 1 4)
HR   (substr XDATE 10 2)
MN   (substr XDATE 12 2)
DG   (getvar "dwgname")
US   (substr (getvar "loginname") 1 5)      
    )
    (write-line (strcat MO "/" DAY "/" YR " " HR ":" MN " " DG " " US "\t" "Command-Line: " (car a2)) f)
    ;;(write-line (car a2) f)
    (close f)
  ) ;_  defun
  (my_reac)
)

Gary

[ElpanovEvgeniy]

You could add this to it.......

It is my old program.
Wrote for a forum...
http://www.autocad.ru/cgi-bin/f1/board.cgi?t=22492WX
OR
http://babelfish.altavista.com/babelfish/trurl_pagecontent?lp=ru_en&trurl=http://www.autocad.ru/cgi-bin/f1/board.cgi?t=22492WX

[ElpanovEvgeniy]

Code: [Select]

(defun c:acad_log (/)
  (vlr-remove-all)
  (defun my_reac ()
    (vlr-command-reactor nil '((:vlr-commandended . st_com)))
  ) ;_  defun
  (defun st_com (a1 a2 / f xdate mo day yr hr mn dg us)
    (setq f (open "D:\\TMP\\acad_log.xls" "a"))
    (write-line
      (strcat
(menucmd "M=$(edtime,$(getvar,date),MO.DD.YY\tHH:MM:SS\t)")
(getvar "dwgname")
"\t"
(getvar "loginname")
"\tCommand:\t"
(car a2)
      ) ;_  strcat
      f
    ) ;_  write-line
    (close f)
  ) ;_  defun
  (my_reac)
) ;_  defun

[GDF]

Thanks Elpanov

Here is another version:

Code: [Select]

;;;To record lisp commands typed in from key board.
;;;by Elpanov Evgeniy
(defun c:Record (/) 
  (defun padout  (word len / spaces)
    (repeat (- len (strlen word)) (setq spaces (cons 32 spaces)))
    (strcat word (vl-list->string spaces))
  ) ;;by Allen Butler
  ;;(vlr-remove-all)  <--don't want this!!
  (defun RecordCommands (a1 a2 / f tm dg us)
    (setq f (open "C:\\temp\\RecordCommands.txt" "a"))
    (setq    TM   (menucmd "M=$(edtime,$(getvar,date),MO/DD/YYYY\tHH:MM\t)")
DG   (strcat (getvar "dwgprefix")(getvar "dwgname"))
US   (substr (getvar "loginname") 1 7)
    )
    (write-line (strcat "Command: " (padout (car a2) 9) "\t\t" TM "\t" US "\t" DG) f)     
    (close f)
  )
  (vlr-command-reactor nil '((:vlr-commandended . RecordCommands)))
  (princ "\n*** --------- Recording Commands --------- ***") 
  (princ)
)

Gary

[ElpanovEvgeniy]

Thanks Gary
I has removed superfluous variables...

Code: [Select]

(defun c:Record (/)
 (defun padout (word len / spaces)
  (repeat (- len (strlen word)) (setq spaces (cons 32 spaces)))
  (strcat word (vl-list->string spaces))
 ) ;_  defun
 (vlr-remove-all)
 (defun RecordCommands (a1 a2 / f)
  (write-line
   (strcat
    "Command: "
    (padout (car a2) 9)
    "\t"
    (menucmd "M=$(edtime,$(getvar,date),MO/DD/YYYY\tHH:MM\t)")
    (substr (getvar "loginname") 1 7)
    "\t"
    (getvar "dwgprefix")
    (getvar "dwgname")
   ) ;_  strcat
   (setq f (open "D:\\TMP\\RecordCommands.txt" "a"))
  ) ;_  write-line
  (close f)
 ) ;_  defun
 (vlr-command-reactor nil '((:vlr-commandended . RecordCommands)))
 (princ "\n*** --------- Recording Commands --------- ***")
 (princ)
) ;_  defun
" ;;by Allen Butler"
Who it?

[JohnK]

Allen is CAB

[MP]

If I'm not mistaken Alan is CAB (Charles Alan Butler).

[CAB]

Yes, and I only provided this function for Gary some time back.

Code: [Select]

(defun padout  (word len / spaces)
    (repeat (- len (strlen word)) (setq spaces (cons 32 spaces)))
    (strcat word (vl-list->string spaces))
  ) ;;by Alan Butler
Here it is:
http://www.theswamp.org/index.php?topic=8661.msg110575#msg110575

[GDF]

Yes, and I only provided this function for Gary some time back.

Code: [Select]

(defun padout  (word len / spaces)
    (repeat (- len (strlen word)) (setq spaces (cons 32 spaces)))
    (strcat word (vl-list->string spaces))
  ) ;;by Alan Butler
Here it is:
http://www.theswamp.org/index.php?topic=8661.msg110575#msg110575

Sorry Alan <alais Allen> my spelling is not the beest.

Garry

[JohnK]

...
Sorry Alan <alais Allen> my spelling is not the beest.

Garry

Heh!? Apparently, neither is mine. Sorry man.

[CAB]

No problem, I even answer to 'Hey You'.
Although I'm not fond of Charlie.

[GDF]

No problem, I even answer to 'Hey You'.
Although I'm not fond of Charlie.

'Hey You' is probably taken...sounds like a forum screen name to me.

Gary