Author Topic: Triangulation (re-visited) (Read 317685 times)

ymg · « **Reply #375 on:** April 29, 2015, 03:59:52 PM »

Here a small video for the c:prof command

ymg

pedroantonio · « **Reply #376 on:** April 29, 2015, 04:49:22 PM »

Hi ymg !!This is the last version ? Did you add oasis in this version ?

Thanks !!

ymg · « **Reply #377 on:** April 29, 2015, 05:18:10 PM »

topographer,

Sorry, but not there yet!

ymg

ymg · « **Reply #378 on:** April 29, 2015, 06:20:31 PM »

Marko,

The idea of lofting is so we can overlap 2 surfaces
say one is existing ground, the other one projected.

If we loft both surfaces down to elevation 0,
we can calculate the cut and fill required.

The final volume is simply Volume of surface existing
minus the volume of the Projected.

I am oversimplifying here, as we must keep only
the overlapping part of both surfaces.

I did a bit of work on it, and could get the Volume.

Finding what is Cut and what is Fill however is trickier.

It's been a long time but I believe the below code was my latest.
Don't remember the status of it, so it needs to be checked.

Code - Auto/Visual Lisp: [Select]

(defun c:voltin (/ );*acaddoc* bmax bmin en en3 en4 en5 en6 h i layp layr
                    ;pins pmax pol rmax ss1 ss2 ssprop ssref v1 v2 v3 varl
                    ;volp volr vp vr y)
                  
   (vl-load-com)
  
   ;;; Error Handler by ElpanovEvgenyi                                        ;
   (defun *error* (msg)
        (mapcar 'eval varl)
        (if (and msg (not (wcmatch (strcase msg) "*BREAK*,*CANCEL*,*EXIT*")))
           (princ (strcat "\nError: " msg))
        )
        (and *AcadDoc* (vla-endundomark *AcadDoc*))
        (princ)
   )
     
   (setq varl '("CLAYER" "OSMODE" "CMDECHO" "DIMZIN")
         varl (mapcar (function (lambda (a) (list 'setvar a (getvar a)))) varl)
   )     
     
   (or *AcadDoc* (setq *AcadDoc* (vla-get-activedocument (vlax-get-acad-object))))
           
     
   (setvar 'CMDECHO 0)
   (setvar 'DIMZIN 0)
   (setvar 'OSMODE 0)
 
   (if (and (setq layr (cdr (assoc 8 (entget (car (entsel "\nPick a 3DFACE on Reference Layer: ")))))
                  ss1 (ssget "_X" (list '(0 . "3DFACE")(cons 8 layr)))
            )
            (setq layp (cdr (assoc 8 (entget (car (entsel "\nPick a 3DFACE on Proposed Layer: ")))))
                  ss2 (ssget "_X" (list '(0 . "3DFACE")(cons 8 layp)))
            )
       )     
      (progn
         (vla-startundomark *AcadDoc*)
 
         
         (setvar 'CLAYER layr)
         (setq ssref (ssadd))
         (repeat (setq i (sslength ss1))
              (setq   en (ssname ss1 (setq i (1- i)))
                   ssref (ssadd (3df2sol en) ssref) 
              )
          )
          (vl-cmdf "_UNION" ssref "")
          (setq en3 (entlast))
          (vl-cmdf "_COPY" en3 "" '(0 0) '(0 0))
          (setq enr (entlast))
          
          ;(vla-GetBoundingBox (vlax-eName->vla-Object en3) 'rmin 'rmax)
          ;(setq rmax (vlax-SafeArray->List rmax))
          
          
          (setvar 'CLAYER layp)
          (setq ssprop (ssadd))
          (repeat (setq i (sslength ss2))
              (setq en (ssname ss2 (setq i (1- i)))
                   ssprop (ssadd (3df2sol en) ssprop) 
              )
          )
          (vl-cmdf "_UNION" ssprop "")
          (setq en4 (entlast))
          (vl-cmdf "_COPY" en4 "" '(0 0) '(0 0))
          (setq enp (entlast))
          
          ;(vla-GetBoundingBox (vlax-eName->vla-Object en4) 'pmin 'pmax)
          ;(setq pmax (vlax-SafeArray->List pmax))
         
          (vl-cmdf "_-LAYER" "_M" "SUPERFICIES" "")
 
          (vl-cmdf "_-INTERFERE" en3 "" en4 "" "_Y")
          (setq en5 (entlast))
          (vl-cmdf "_COPY" en5 "" '(0 0) '(0 0))
          (setq en6 (entlast))
          (vl-cmdf "_COPY" en5 "" '(0 0) '(0 0))
          (setq enc (entlast))
          (setq vcom  (vlax-get-property (vlax-ename->vla-object en6)  'Volume))
          (vla-GetBoundingBox (vlax-eName->vla-Object en4) 'bmin 'bmax)
          (setq bmax (vlax-SafeArray->List bmax)
                bmin (vlax-SafeArray->List bmin)
          )
          
          (vl-cmdf "_SUBTRACT" en3 "" en5 "")
          (vl-cmdf "_SUBTRACT" en4 "" en6 "")
          
          (setq vref  (vlax-get-property (vlax-ename->vla-object enr)  'Volume)
                vprop (vlax-get-property (vlax-ename->vla-object enp)  'Volume)
                vcut  (vlax-get-property (vlax-ename->vla-object en3)  'Volume)
                vfill (vlax-get-property (vlax-ename->vla-object en4)  'Volume)
          )
          
          (setvar 'CLAYER layr)
          (setq y (cadr bmin)
                h (* (getvar 'TEXTSIZE) 1.5)
          )      
          (vl-cmdf "_text" "_J" "_MC" (list (car pins) y)           0 (strcat "Reference Volume: " (rtos vref 2 1) " m3"))
          (setq v1 (entlast))
          (setvar 'CLAYER layp)
          (vl-cmdf "_text" "_J" "_MC" (list (car pins) (- y h))     0 (strcat " Proposed Volume: " (rtos vprop 2 1) " m3"))
          (setq v2 (entlast))
          (vl-cmdf "_text" "_J" "_MC" (list (car pins) (- y h h))   0 (strcat "      Cut Volume: " (rtos vcut 2 1) " m3"))
          (setq v3 (entlast))
          (vl-cmdf "_text" "_J" "_MC" (list (car pins) (- y h h h)) 0 (strcat "     Fill Volume: " (rtos vfill 2 1) " m3"))
          (setq v4 (entlast))
          
          (vl-cmdf "_MOVE" en3 en4 v1 v2 v3 v4 "" pins pause)
          (vl-cmdf "_VSCURRENT" "_S" "")
      )      
   )  
   (*error* nil)
)
 
;; 3df2sol                                                                    ;
;; Given a 3DFACE Loft it Down to Elevation 0                                 ;
;; Returns the ename of the Solid created.                                    ;
 
(defun 3df2sol (en / en1 en2 p1 p2 p3 p4)
   (setq  ent (entget en)
           p1 (cdr (assoc 10 ent))
           p2 (cdr (assoc 11 ent))
           p3 (cdr (assoc 12 ent))
           p4 (cdr (assoc 13 ent))
   )
   
   (setq en1 (entmakex
                (list 
                  (cons 0 "3DFACE")  
                  (cons 10 (list (car p1) (cadr p1) 0.))
                  (cons 11 (list (car p2) (cadr p2) 0.))
                  (cons 12 (list (car p3) (cadr p3) 0.))
                  (cons 13 (list (car p4) (cadr p4) 0.))
                ) 
             )
   )
   (vl-cmdf "_loft" en  en1 "_MO" "_SOLID" "" "")
   (entlast)
)   
 

ymg

ymg · « **Reply #379 on:** April 30, 2015, 05:05:14 AM »

I had remove some necessary function during
the clean-up (Namely massoc-fuzz) so

I have corrected the attachment in post #374

ymg

ymg · « **Reply #380 on:** April 30, 2015, 03:36:33 PM »

Topographer,

Concerning the oasis, holes or island however we name them,
it can be done with the program as it is.

The holes is actually a polyline that encircles an area without
points.

This is actually a close breakline without any points inside.

Only thing missing is as you create the CDT, 3dfaces will be created
inside the breaklines. In other word the inside of your polyline
defining the breakline will be triangulated also.

All you need to do is to erase these inside triangles
manually upon completion. Should be easy if you
use the breakline as a selecting polygon.

ymg

ribarm · « **Reply #381 on:** May 01, 2015, 12:44:53 PM »

Here is my newest version of convex triangulation terrain modeling routine... It should be ab 5 times faster than LOFT variant... Only thing that now it uses SURFSCULPT command, so you should have ACAD that supports this...

Code - Auto/Visual Lisp: [Select]

(defun c:terrain ( / mid 3D->2D MR:Collinear-p MR:ListClockwise-p LM:Clockwise-p LM:ConvexHull triangulate ss i p pl ell tl och elmin elmax elevmin elevmax fuzz ss3f ent entl entll ti z )
 
  (defun mid ( p1 p2 )
    (mapcar '(lambda ( a b ) (/ (+ a b) 2.0)) p1 p2)
  )
 
  ;; 3D to 2D point  -  M.R.
  ;; Returns 2D point list from supplied 3D point list or returns supplied argument if it isn't 3D point list
 
  (defun 3D->2D ( p )
      (if (and (listp p) (vl-every '(lambda ( x ) (eq (type x) 'REAL)) p) (eq (length p) 3))
          (list (car p) (cadr p))
          p
      )
  )
 
  ;; Collinear-p  -  M.R.
  ;; Returns T if p1,p2,p3 are collinear
 
  (defun MR:Collinear-p ( p1 p2 p3 )
      (equal  (distance p1 p3)
              (+ (distance p1 p2) (distance p2 p3))
          1e-8
      )
  )
 
  ;; MR:ListClockwise-p
 
  (defun MR:ListClockwise-p ( lst / z vlst )
    (vl-catch-all-apply 'minusp 
      (list
        (if 
          (not 
            (equal 0.0
              (setq z
                (apply '+
                  (mapcar 
                    (function
                      (lambda ( u v )
                        (- (* (car  u) (cadr  v)) (* (car  v) (cadr  u)))
                      )
                    )
                    (setq vlst
                      (mapcar
                        (function
                          (lambda ( a b ) (mapcar '- b a))
                        )
                        (mapcar (function (lambda ( x ) (car lst))) lst) 
                        (cdr (reverse (cons (car lst) (reverse lst))))
                      )
                    )
                    (cdr (reverse (cons (car vlst) (reverse vlst))))
                  )
                )
              ) 1e-6
            )
          )
          z
          (progn
            (prompt "\n\nChecked vectors are colinear - unable to determine clockwise-p of list")
            nil
          )
        )
      )
    )
  )
 
  ;; Clockwise-p  -  Lee Mac
  ;; Returns T if p1,p2,p3 are clockwise oriented or collinear
 
  (defun LM:Clockwise-p ( p1 p2 p3 )
      (<  (-  (* (- (car  p2) (car  p1)) (- (cadr p3) (cadr p1)))
              (* (- (cadr p2) (cadr p1)) (- (car  p3) (car  p1)))
          )
          1e-8
      )
  )
 
  ;; Convex Hull  -  Lee Mac
  ;; Implements the Graham Scan Algorithm to return the Convex Hull of a list of points.
   
  (defun LM:ConvexHull ( lst / ch p0 )
      (cond
          (   (< (length lst) 4) lst)
          (   (setq p0 (car lst))
              (foreach p1 (cdr lst)
                  (if (or (< (cadr p1) (cadr p0))
                          (and (equal (cadr p1) (cadr p0) 1e-8) (< (car p1) (car p0)))
                      )
                      (setq p0 p1)
                  )
              )
              (setq lst (vl-remove p0 lst))
              (setq lst (append (list p0) lst))
              (setq lst
                  (vl-sort lst
                      (function
                          (lambda ( a b / c d )
                              (if (equal (setq c (angle p0 a)) (setq d (angle p0 b)) 1e-8)
                                  (< (distance p0 a) (distance p0 b))
                                  (< (if (equal c (* 2.0 pi) 1e-8) 0.0 c) (if (equal d (* 2.0 pi) 1e-8) 0.0 d))
                              )
                          )
                      )
                  )
              )
              (setq ch (list (caddr lst) (cadr lst) (car lst)))
              (foreach pt (cdddr lst)
                  (setq ch (cons pt ch))
                  (while (and (caddr ch) (LM:Clockwise-p (caddr ch) (cadr ch) pt) (not (MR:Collinear-p (3D->2D (caddr ch)) (3D->2D (cadr ch)) (3D->2D pt))))
                      (setq ch (cons pt (cddr ch)))
                  )
              )
              (reverse ch)
          )
      )
  )
 
  (defun triangulate ( pl factor / tl pll getcircumcircle xmin xmax ymin ymax cs pmin pmax t1 t2 t3 al p el tr l n str ich iche i )
 
    (defun getcircumcircle ( p el / circumcircle cp cr rr )
        
      (defun circumcircle ( p1 p2 p3 / ang c r )
        (if 
          (not
            (zerop
              (setq ang (- (angle p2 p3) (angle p2 p1)))
            )
          )
          (setq c (polar p3 (+ -1.570796326794896 (angle p3 p1) ang) (setq r (/ (distance p1 p3) (sin ang) 2.0)))
               r (abs r)
          )
        )
        (list c r)
      )
 
      (setq cp (car (setq cr (circumcircle (3D->2D p) (3D->2D (car el)) (3D->2D (cadr el))))) rr (cadr cr))
      (list (+ (car cp) rr) cp rr (list p (car el) (cadr el))) ;;; Added X max of circumscribed triangle circle as first element of (getcircumcircle) output list ;;;
    )
 
    (setq pll pl)
    (setq xmin (caar (setq pl (vl-sort pl '(lambda ( a b ) (< (car a) (car b))))))) ;;; Sorted pl by X ;;;
    (setq xmax (caar (vl-sort pl '(lambda ( a b ) (> (car a) (car b))))))
    (setq ymin (cadar (vl-sort pl '(lambda ( a b ) (< (cadr a) (cadr b))))))
    (setq ymax (cadar (vl-sort pl '(lambda ( a b ) (> (cadr a) (cadr b))))))
    (setq cs (list (+ xmin (/ (- xmax xmin) 2.0)) (+ ymin (/ (- ymax ymin) 2.0))))
    (setq pmin (list xmin ymin) pmax (list xmax ymax))
    (setq t1 (polar cs 0.0 (if (setq n (atoi (substr (setq str (rtos (distance pmin cs) 1 0)) (- (strlen str) 2)))) (setq rs (expt factor (+ n 2)))))) ;;; Added 0.0 in polar for rotating supertriangle t1 is max X apex ;;;
    ;;(setq t1 (polar cs 0.0 (setq rs (* 2.0 factor (distance pmin cs)))))
    (setq t2 (polar cs (+ 0.0 (/ (* 2.0 pi) 3.0)) rs))
    (setq t3 (polar cs (+ 0.0 (/ (* 4.0 pi) 3.0)) rs))
    (setq al (list (list (car t1) cs rs (list t1 t2 t3))))
    (while pl
      (setq p (car pl))
      (setq pl (cdr pl))
      (setq el nil)
      (while al
        (setq tr (car al))
        (setq al (cdr al))
        (cond
          ( (< (car tr) (car p)) ;;; Comparison of X values ;;;
            (setq tl (cons (cadddr tr) tl))
          )
          ( (< (distance p (cadr tr)) (caddr tr))
            (setq el (append (list 
                              (list (car (last tr)) (cadr (last tr))) 
                              (list (cadr (last tr)) (caddr (last tr))) 
                              (list (caddr (last tr)) (car (last tr)))
                            ) el
                    )
            )
          )
          ( t (setq l (cons tr l)) )
        )
      )
      (if l (setq al l l nil))
      (while el
        (if (or (member (reverse (car el)) el)
               (member (car el) (cdr el))
            )
            (setq el (vl-remove (reverse (car el)) el)
                  el (vl-remove (car el) el)
            )
            (setq al (cons (getcircumcircle p (car el)) al)
                  el (cdr el)
            ) 
        ) 
      )
    )
    (foreach tr al (setq tl (cons (cadddr tr) tl)))
    (setq tl (vl-remove-if '(lambda ( x ) (or (member t1 x) (member t2 x) (member t3 x))) tl))
    (setq pl pll)
    (if (null ell)
      (progn
        (setq el (mapcar '(lambda ( a b ) (list a b)) (setq och (LM:ConvexHull pll)) (cdr (reverse (cons (car och) (reverse och))))))
        (mapcar '(lambda ( x ) (setq pll (vl-remove x pll))) och)
        (setq ich (LM:ConvexHull pll))
      )
    )
    (if ich
      (progn
        (setq ell t)
        (foreach e el
          (if (not (vl-some '(lambda ( x ) (and (member (car e) x) (member (cadr e) x))) tl))
            (progn
              (setq ich (vl-sort ich '(lambda ( a b ) (< (distance a (mid (3D->2D (car e)) (3D->2D (cadr e)))) (distance b (mid (3D->2D (car e)) (3D->2D (cadr e))))))))
              (setq iche (vl-remove-if '(lambda ( x ) (> (distance x (mid (3D->2D (car e)) (3D->2D (cadr e)))) (distance (car e) (mid (3D->2D (car e)) (3D->2D (cadr e)))))) ich))
              (foreach p iche
                (if (or
                      (and
                        (vl-some '(lambda ( x ) (if (and (member (car e) x) (member p x)) (setq tr x))) tl)
                        (vl-some '(lambda ( x ) (and (member (car e) x) (member p x))) (vl-remove tr tl))
                      )
                      (and
                        (vl-some '(lambda ( x ) (if (and (member (cadr e) x) (member p x)) (setq tr x))) tl)
                        (vl-some '(lambda ( x ) (and (member (cadr e) x) (member p x))) (vl-remove tr tl))
                      )
                    )
                    (setq iche (vl-remove p iche))
                )
              )
              (setq i (length iche))
              (setq iche (cons (car e) iche) iche (cons (cadr e) iche))
              (if (null z)
                (setq z 10.0)
              )
              (setq z
                (cond
                  ( (<= i (length (car (triangulate iche 10.0))))
                    (if (>= z 10.0)
                      z
                      (setq z 10.0)
                    )
                  )
                  ( (<= i (length (car (triangulate iche 25.0))))
                    (if (>= z 25.0)
                      z
                      (setq z 25.0)
                    )
                  )
                  ( (<= i (length (car (triangulate iche 50.0))))
                    (if (>= z 50.0)
                      z
                      (setq z 50.0)
                    )
                  )
                  ( (<= i (length (car (triangulate iche 100.0))))
                    (if (>= z 100.0)
                      z
                      (setq z 100.0)
                    )
                  )
                  ( (<= i (length (car (triangulate iche 250.0))))
                    (if (>= z 250.0)
                      z
                      (setq z 250.0)
                    )
                  )
                  ( (<= i (length (car (triangulate iche 500.0))))
                    (if (>= z 500.0)
                      z
                      (setq z 500.0)
                    )
                  )
                  ( (<= i (length (car (triangulate iche 1000.0))))
                    (if (>= z 1000.0)
                      z
                      (setq z 1000.0)
                    )
                  )
                )
              )
            )
          )
        )
      )
    )
    (list tl z)
  ) ;;; end of triangulate
 
  (vl-load-com)
 
  (prompt "\n................................................")
  (prompt "\nTERRAIN TRIANGULATION IRREGULAR NETWORK MODELING")
  (prompt "\n................................................")
  (prompt "\n................................................")
  (prompt "\nSELECT RANDOM 3D POINTS...")
  (command "_.UCS" "_W")
  (setq ss (ssget '((0 . "POINT"))))
  (repeat (setq i (sslength ss))
    (setq p (cdr (assoc 10 (entget (ssname ss (setq i (1- i)))))))
    (setq pl (cons p pl))
  )
 
  (setq elevmin (caddar (setq pl (vl-sort pl '(lambda ( a b ) (< (caddr a) (caddr b)))))))
  (setq elevmax (caddr (last pl)))
  (setq elmin (getreal (strcat "\nInput base elevation of terrain (must be < " (rtos elevmin 2 15) " ) : ")))
  (while (>= elmin elevmin)
    (setq elmin (getreal (strcat "\nInput base elevation of terrain (must be < " (rtos elevmin 2 15) " ) : ")))
  )
  (setq elmax (getreal (strcat "\nInput top elevation of terrain (must be > " (rtos elevmax 2 15) " ) : ")))
  (while (<= elmax elevmax)
    (setq elmax (getreal (strcat "\nInput top elevation of terrain (must be > " (rtos elevmax 2 15) " ) : ")))
  )
  (initget 4)
  (setq fuzz (getreal "\nSpecify fuzz edge inaccuracy to make possible creation of 3DSOLID with SURFSCULPT command <0.0> : "))
  (if (null fuzz) (setq fuzz 0.0))
 
  (setq ti (car (_vl-times)))
  (setq ss3f (ssadd))
  (setq z (cadr (triangulate pl 10.0)))
  (foreach tr (car (triangulate pl z))
    (ssadd
      (entmakex 
        (list (cons 0 "3DFACE")
          (cons 10 (car tr))
          (cons 11 (cadr tr))
          (cons 12 (caddr tr))
          (cons 13 (car tr))
        ) 
      )
      ss3f
    ) 
  )
 
  (setq entl (entmakex
               (append
                 (list
                   '(0 . "LWPOLYLINE")
                   '(100 . "AcDbEntity")
                   '(100 . "AcDbPolyline")
                   (cons 90 (length och))
                   '(70 . 1)
                   (cons 38 elmin)                   
                 )
                 (mapcar '(lambda ( p ) (list 10 (car p) (cadr p))) och)
                 (list
                   (list 210 0.0 0.0 1.0)
                 )
               )
             )
  )
  (if (not (zerop fuzz))
    (progn
      (if (MR:ListClockwise-p och)
        (vla-offset (vlax-ename->vla-object entl) fuzz)
        (vla-offset (vlax-ename->vla-object entl) (- fuzz))
      )
      (vla-move (vlax-ename->vla-object entl) (vlax-3d-point (list 0.0 0.0 0.0)) (vlax-3d-point (list 0.0 0.0 fuzz)))
      (setq entll entl)
      (setq entl (entlast))
    )
  )
  (command "_.EXTRUDE" entl "" "_D" (list 0.0 0.0 elmin) (list 0.0 0.0 elmax))
  (command "_.EXPLODE" (entlast))
  (while (> (getvar 'cmdactive) 0) (command ""))
  (if (not (zerop fuzz))
    (progn
      (command "_.UCS" "_M" (list 0.0 0.0 elmin))
      (repeat (setq i (sslength (setq entl (ssget "_P"))))
        (setq ent (ssname entl (setq i (1- i))))
        (if (not (vl-catch-all-error-p (vl-catch-all-apply 'vla-get-centroid (list (vlax-ename->vla-object ent)))))
          (progn
            (ssdel ent entl)
            (entdel ent)
          )
        )
      )
      (command "_.UCS" "_P")
    )
  )
  (command "_.UCS" "_M" (list 0.0 0.0 elmax))
  (repeat (setq i (sslength (if (eq (type entl) 'PICKSET) entl (setq entl (ssget "_P")))))
    (setq ent (ssname entl (setq i (1- i))))
    (if (not (vl-catch-all-error-p (vl-catch-all-apply 'vla-get-centroid (list (vlax-ename->vla-object ent)))))
      (progn
        (ssdel ent entl)
        (entdel ent)
      )
    )
  )
  (if (not (zerop fuzz))
    (progn
      (command "_.REGION" entll "")
      (ssadd (setq ent (entlast)) entl)
    )
    (setq ent (entlast))
  )
 
  (command "_.REGION" ss3f "")
  (while (setq ent (entnext ent))
    (ssadd ent entl)
  )
 
  (command "_.UCS" "_P")
  (command "_.SURFSCULPT" entl "")
  (command "_.UCS" "_P")
 
  (prompt (strcat "\nElapsed time: " (rtos (/ (- (car (_vl-times)) ti) 1000.) 2 4) " secs."))
  (princ)
)
 

HTH, Regards, M.R.

ymg · « **Reply #382 on:** May 01, 2015, 04:12:54 PM »

Marko,

Looks good to me I am running 2012, so surfsculpt.

However I've not done a lot of 3d-modeling except
for the occasionnal simple model.

You are much more proficient at it than I am.

Is surfsculpt available to Briscad ?

Would like to keep thing compatible with it.

ymg

motee-z · « **Reply #383 on:** May 01, 2015, 05:37:11 PM »

Hello ymg
when executing the routine i got this message any reason for this i use autocad2013 version
Error: no function definition: MASSOC-FUZZ

ymg · « **Reply #384 on:** May 01, 2015, 06:50:07 PM »

motee-z,

Download the file again as I had removed the function
by mistakes.

Anyway in next revision probably tomorrow, this
function will no longer be required.

I hope to complete the automatic clean-up of
triangles inside holes of the triangulation in this
next revision.

A note of caution, there has been some revision to
the DCL. So if you had run any of the older version,
you need to erase the tin.dcl file that is in your temp directory.

ymg

ymg · « **Reply #385 on:** May 02, 2015, 01:29:56 PM »

As pledged, here is Revision 0.6.2.8 of triangulation
program.

Islands are now cleaned up after triangulation.

ymg

pedroantonio · « **Reply #386 on:** May 02, 2015, 02:05:00 PM »

Hi ymg nice update , but i have a bug. The problem is when the breaklines is in touch with the boundary. Look the test.dwg

pedroantonio · « **Reply #387 on:** May 02, 2015, 02:26:37 PM »

Hi ymg ,I havesome questions.
1)I draw a 2d polyline on the contours and then i write prof to draw a long section, and gives me this message Error: divide by zero.
With the previous versions i didn't have this error.
2)I use attribiute block for my insert survey points.With the previous versions i didn't have any problems.Now i need to turn off the layers of this block.Is this necessary

Look the test2.dwg with the 2d polyline and the layoff layers

Thanks

ymg · « **Reply #388 on:** May 02, 2015, 05:47:55 PM »

Topographer,

Seems to be a valid bug. I believe it has to do
when there is no triangle inside the closed breaklines.

Right now I'm tired, so I'll look more closely
tomorrow.

Ditto, for the second bug.

ymg

ymg · « **Reply #389 on:** May 03, 2015, 07:48:40 AM »

Topographer,

Corrected the first bug that you submitted.

For the second, the problem is that the insert point
of your block are 2d.

Your blocks must be inserted at the proper elevation (3D)

As it is Blocks are left on whatever layer there were inserted to.
We could change this behaviour and move them to the "Tin Point ..."
layers.

We do not need to create a "POINT" entity in order to triangulate
all I am using is the coordinates of insertion.

If we move the blocks to the "Tin Point ..." layers the c:tog command
could be used to make them appear or dissappear.

We could, as you go in command c:prof, turn "Off" layer "Tin Point ..."
to diminish the clutter on screen. Although it is not absolutely necessary.

ymg

News:

Author Topic: Triangulation (re-visited) (Read 317685 times)

ymg

Re: Triangulation (re-visited)

pedroantonio

Re: Triangulation (re-visited)

ymg

Re: Triangulation (re-visited)

ymg

Re: Triangulation (re-visited)

ymg

Re: Triangulation (re-visited)

ymg

Re: Triangulation (re-visited)

ribarm

Re: Triangulation (re-visited)

ymg

Re: Triangulation (re-visited)

motee-z

Re: Triangulation (re-visited)

ymg

Re: Triangulation (re-visited)

ymg

Re: Triangulation (re-visited)

pedroantonio

Re: Triangulation (re-visited)

pedroantonio

Re: Triangulation (re-visited)

ymg

Re: Triangulation (re-visited)

ymg

Re: Triangulation (re-visited)