Here is an oldie that you pick um.
;;; Dim2Inches.lsp
;;;
;;; FUNCTION
;;; change Dimension units to Fractions and add " to override
;;;
;;;
;;; ARGUMENTS
;;; none
;;;
;;; USAGE
;;; d2i
;;;
;;; PLATFORMS
;;; 2000+
;;;
;;; AUTHOR
;;; Copyright© 2004-2008 Charles Alan Butler
;;; CAB at TheSwamp
;;;
;;; VERSION 1.0 Oct. 23, 2004
;;; YOU MAY USE THIS CODE ONLY FOR *NON-COMMERCIAL* PURPOSES AND ONLY
;;; IF YOU RETAIN THIS HEADER COMPLETE AND UNALTERED
;;;
;;; you must contact me if you want to use it commercially
;;;
;;; REVISED By VINCENT POON
;;; VERSION 1.1 Mar. 17, 2005
;;;
;;; REVISED By CAB
;;; VERSION 1.2 Mar. 23, 2005
;;; Changed to dimension to FRACTIONS & adds " to the suffix if empty
;;; else adds " to the override if empty else does nothing
;;;
(defun c:d2i (/ ent obj )
(vl-load-com)
(graphscr)
(while (setq ent (entsel "\n>>--> Select Dimension to convert to inches."))
(if (= (cdr (assoc 0 (setq elst (entget (car ent))))) "DIMENSION")
(progn
(setq ent (car ent)
obj (vlax-ename->vla-object ent))
(if (and (vlax-property-available-p obj 'primaryunitsprecision)
(vlax-property-available-p obj 'textoverride)
)
(progn
(vla-put-UnitsFormat obj 5) ; make Fractional
;; changed from vla-get-textoverride to vla-get-TextSuffix
(cond
((member (vla-get-TextSuffix obj) '("" "<>"))
(vla-put-TextSuffix obj "\"")
) ; Suffix
((member (vla-get-textoverride obj) '("" "<>"))
(vla-put-textoverride obj "<>\"")
(prompt "\n*-* Text Suffix already in use, created override. *-*")
)
(T
(prompt "\n*--* Text Suffix & Override in use, Change to Fractions.")
)
) ; end cond stmt
) ; progn
(prompt "\n**** Can not edit this Dimension Object, Canceled...")
) ; endif
(vlax-release-object obj)
) ; progn
(prompt "\n<<< Not a dimension >>>")
) ; endif
)
(princ)
)
;(prompt "\nDim to Inches loaded, Enter d2i to run.")
(princ)