Topic: (discussion) Costruct procedures with Lambda

[whdjr]

I really like using lambda however I rarely use it on it's own.  Here are two functions I used alot:

(defun *layout_list* (/ lst)
  (vlax-map-collection
    (vla-get-layouts
      (vla-get-activedocument (vlax-get-acad-object))
    )
    '(lambda (x) (setq lst (cons x lst)))
  )
  (cdr
    (*sort* lst 'vla-get-taborder)
  )
)

(defun *sort* (lst func)
  (vl-sort lst
      '(lambda (e1 e2)
         (< ((eval func) e1) ((eval func) e2))
       )
  )
)

[CAB]

How about this?

Code: [Select]

(defun sum-squares-lst (lst)
  (apply '+ (MAPCAR '(lambda (x) (* x x)) lst))
)

;;(sum-squares-lst '(2 3)); => 13
;;(sum-squares-lst '(2 3 4)); => 29
;;(sum-squares-lst '(1 2 3 4 5 6 7 8 9 10)); => 385

[whdjr]

WOOHOO!!!!

Finally someone used Mapcar, Lambda, and Apply all in the same routine.   





In case your wondering I do like your version.

[JohnK]

I will admit that I was going to respond with the same old "*sigh*" or a "What are you guys talking about" but instead; Ive thought, and thought about some of your responces. I was forced to read, and re-read. And I think I may finaly have an understanding. Are you ready for this. (This is what it all amounts down to.) I dosent matter. Not one bit. There is (or should be) any loss in prformance, speed, etc in the end.

As far as I can tell from my readings, the interpretor does not see a named abstraction as a 'name' during the evaluation process.

[Chuck Gabriel]

As far as I can tell from my readings, the interpretor does not see a named abstraction as a 'name' during the evaluation process.

Maybe not, but the reader/maintainer does, and THAT is where a great deal of its value lies.

[Kerry]

As far as I can tell from my readings, the interpretor does not see a named abstraction as a 'name' during the evaluation process.

Maybe not, but the reader/maintainer does, and THAT is where a great deal of its value lies.

[nodding.gif]

[JohnK]

STOP THE PRESS! I will have to do more thinking on this subject.



> Readability
So is that an agrement towards the use of lambda vs a name or visa-versa? Because one could argue both ways.

[Chuck Gabriel]

I suppose it comes down to personal preference in the end.  I generally find named abstractions to be easier to follow, though there is the disadvantage of having to flip back and forth between the function definition and the places where it is used.  However, for very short functions that are used only in one place, I can see the argument for using a lambda function inline.

[ElpanovEvgeniy]

How about this?

Code: [Select]

(defun sum-squares-lst (lst) (apply '+ (MAPCAR '(lambda (x) (* x x)) lst)))

Compare...

Code: [Select]

(defun sum-squares-lst (lst) (apply '+ (MAPCAR '* lst lst)))

[Kerry]

How about this?

Code: [Select]

(defun sum-squares-lst (lst) (apply '+ (MAPCAR '(lambda (x) (* x x)) lst)))

Compare...

Code: [Select]

(defun sum-squares-lst (lst) (apply '+ (MAPCAR '* lst lst)))

Hello ElpanovEvgeniy, Welcome to theSwamp !

Sorry, my English it is awful...

 Your LISP is VERY good ! Nice code.   

[ElpanovEvgeniy]

But here no LAMBDA 

[Kerry]

 

[ElpanovEvgeniy]

Here is lambda!

Code: [Select]

;| A library function
; Multiple changing one elements of a list
; On other.
; Function usables in all events when it is possible
; Check on correspondence, through "EQUAL"
; Writer Evgeniy Elpanov.
; ***********************************************************
; Arguments:
; lst - a list in which it is necessary to make changings
; lst-i - correspondences ((changed replacer)... ())
; ***********************************************************
; An example of a call
; (multi-subst '(1 2 3 4 5)' ((1 "a") (3 "b")))
; Function will return ("a" 2 "b" 45)
|;
(defun multi-subst (lst lst-i)
  (eval
    (list
      (function mapcar)
      (list
        (function function)
        (list
          (function lambda)
          '(a)
          (cons
            (function cond)
              (reverse
               (cons
                '(t a)
                  (mapcar
                    (function
                      (lambda (a)
                        (list
                          (list
                            (function equal)
                            (car a)
                            'a
                          ) ; _ list
                          (cadr a)
                        ) ; _ list
                      ) ; _ lambda
                    ) ; _ function
                    lst-i
                  ) ; _ mapcar
                ) ; _ cons
             ) ; _ reverse
          ) ; _ cons
        ) ; _ cons
      ) ; _ list
      'lst
    ) ; _ list
  ) ; _ eval
) ; _ defun

[Mark]

Here is lambda!

Indeed it is. 

Nice stuff Evgeniy, welcome to theswamp.

[Kerry]

good fun Evgeniy .. that will keep John < Se7en > busy