Topic: Need to lurn..

[Andrea]

Hi all..

I have created this simple routine...

Code: [Select]

;| ;;
Replace word in a layer ;;
By: Andrea Andreetti |;

(defun c:MCR (/ layer_list lfound ltell ls1 lr)
(setq layer_list (ai_table "layer" 4))
(setq lfound (getstring "Mot du calque à changer : ")
      ltell (getstring "Par le mot : "))
(foreach n layer_list
  (setq ls1 (vl-string-search lfound n))
  (if ls1
    (progn
    (setq lr (vl-string-subst ltell lfound n))
    (vl-cmdf "_.-rename" "_LA" n lr)
    )
  )
)
)  
But can anyone show me some other way to do similar with VLX or any other mode ?
Just curious to lurn..

[Kerry]

This will need some work on your part.

Do you know how to determine the Layers Collection.
Do you know how to iterate the collection.
Do you know how to determine the Name and/or Value of an object.

[Kerry]

.. but if you want to learn that shouldn't be an issue ..

[Adesu]

Hi Andrea,how about this

Code: [Select]

;| ;;
Replace word in a layer ;;
By: Andrea Andreetti |;

(defun c:MCR (/ layer_list lfound ltell ls1 lr)
  ;(setq layer_list (ai_table "layer" 4))
  (setq layer_list (table "layer"))
  (setq lfound (getstring "Mot du calque à changer : "))
  (setq ltell (getstring "Par le mot : "))
  (foreach n layer_list
    (setq ls1 (vl-string-search lfound n))
    (if ls1
      (progn
(setq lr (vl-string-subst ltell lfound n))
(vl-cmdf "_.-rename" "_LA" n lr)
)
      )
    )
  ) 

(defun table (s / d r)
  (while (setq d (tblnext s (null d)))
    (setq r (cons (cdr (assoc 2 d)) r))
  )
)



[Jürg Menzi]

In ActiveX:

Code: [Select]

(defun c:MCR (/ lfound ltell AcaDoc LayCol LayNme LayObj NewNme)
 (setq lfound (getstring "\nMot du calque à changer : ")
       ltell  (getstring "Par le mot : ")
       AcaDoc (vla-get-ActiveDocument (vlax-get-acad-object))
       LayCol (vla-get-Layers AcaDoc)
 )
 (vlax-for Obj LayCol
  (setq LayNme (vla-get-Name Obj))
  (if (and
       (not (vl-position (strcase LayNme) '("0" "DEFPOINTS")))
       (vl-string-search lfound LayNme)
      )
;;; Note that the search is case-sensitive, and that vl-string-subst
;;; substitutes only the first occurrence it finds of the string.
   (setq NewNme (vl-string-subst ltell lfound LayNme)
         LayObj Obj
   )
  )
 )
 (cond
  ((not NewNme)
   (princ "Calque à changer n'existe pas.")
  )
  ((not
    (vl-catch-all-error-p
     (vl-catch-all-apply '(lambda () (vla-Item LayCol NewNme)))
    )
   )
   (princ "Le nouveaux nom du calque déjà existe.")
  )
  (T
   (vla-put-Name LayObj NewNme)
  )
 )
 (princ)
)

[Kerry]

Andrea wanted to test against bit 4 too Jürg.

;;; (ai_table <table name> <bit> )
;;;
;;; Returns a list of items in the specified table.  The bit values have the
;;; following meaning:
;;;  0  List all items in the specified table.
;;;  1  Do not list Layer 0 and Linetype CONTINUOUS.
;;;  2  Do not list anonymous blocks or anonymous groups.
;;;         A check against the 70 flag for the following bit:
;;;                  1  anonymous block/group
;;;  4  Do not list externally dependant items.
;;;         A check against the 70 flag is made for any of the following
;;;         bits, which add up to 48:
;;;                 16  externally dependant
;;;                 32  resolved external or dependant
;;;  8  Do not list Xrefs.
;;;         A check against the 70 flag for the following bit:
;;;                  4  external reference
;;;  16 Add BYBLOCK and BYLAYER items to list.
;;;

[Jürg Menzi]

Andrea wanted to test against bit 4 too Jürg.

AFAIK, there is no property in ActiveX to check for that...

[Andrea]

hmmm... interesting...

But I have found a little problem with this...
in fact if I have a layer named like    M-ALUMINUM-TEXT and need to change M- by E-

This will replace only the first string found in the layer name
like  E-ALUMINUM-TEXT  and not E-ALUMIUE-TEXT

see ?

[Andrea]

also..

why this is not working ??

Code: [Select]

(defun c:MCR ()(/ layer_list lfound ltell ls1 lr)
(setq layer_list (ai_table "layer" 0))
(setq lfound (strcase (getstring "Mot du calque à changer : "))
      ltell (getstring "Par le mot : "))
(foreach n layer_list
  (setq ls1 (vl-string-search lfound (strcase n)))
  (if ls1
    (progn
    (setq lr (vl-string-subst ltell lfound n))
    (vl-cmdf "_.-rename" "_LA" n lr)
    )
  )
)
)

[Kerry]

What have you done to debug it ?

[Jürg Menzi]

why this is not working ??

See comment in my code... For a function that replaces all occurrences of a pattern visit my homepage -> Free Stuff and search for 'VxStringSubst'

[Andrea]

What have you done to debug it ?

this....

Code: [Select]

(defun c:MCR ();;(/ repxok layer_list lfound ltell ls1 lr)
(setvar "CMDECHO" 0) 
  (check_repx)
(if repxok
  (progn
(setq layer_list (ai_table "layer" 0))
(setq lfound (strcase (getstring "Mot du calque à changer : "))
      ltell (getstring "Par le mot : "))
(foreach n layer_list
(setq TL (strcase n))
(alert (strcat TL "     " lfound))
  (setq ls1 (vl-string-search lfound TL))
  (if ls1
    (progn
    (setq lr (vl-string-subst ltell lfound n))
    (vl-cmdf "_.-rename" "_LA" n lr)
    )
  )
)
))
  (prompt "Calques mis à jour")(princ)
  )

[Andrea]

why this is not working ??

See comment in my code... For a function that replaces all occurrences of a pattern visit my homepage -> Free Stuff and search for 'VxStringSubst'

And your website is...!??

[LE]

Click in the WWW url link

[MP]

Or look at his sig.

[Andrea]

Oops, sorry..to much work i think..

by the way...

I have an error when trying to rename a layer who already exist..
I think I need to remake my routine...

[Royalchill]

I found this old lisp. I did not write it but it works perfect. Hope it is some help

;At the command line, type (load "c:/lispdir/RENLYR")
;where c:/ is the drive where RENLYR.lsp is contained
;where lispdir/ is the directory where RENLYR.lsp is contained

(Defun C:RENLYR (/ e e-inf e-lyr txtlist sstxt sse see-inf sse-txt)
  (prompt "\n")
  (princ)
  (while (= (setq e (car (entsel "\rSelect entity of layer to rename: "))) nil))
  (setq
    e-inf (entget e)
    e-lyr (cdr (assoc 8 e-inf))
  )
  (if (/= e-lyr "0")
    (progn
      (setq txtlist (list (cons 0 "TEXT") (cons 1 e-lyr) (cons 10 (getvar "viewctr")) (cons 40 0.000001) (cons 50 0.0)))
      (entmake txtlist)
      (setq sstxt (entlast))
      (command "ddedit" sstxt "")
      (setq
        sse (entlast)
        sse-inf (entget sse)
        sse-txt (cdr (assoc 1 sse-inf))
      )
      (if (and (/= (strcase sse-txt) (strcase e-lyr)) (/= sse-txt "") (= (wcmatch sse-txt "* *") nil))
        (command "rename" "layer" e-lyr sse-txt)
        (cond
          ((= (strcase sse-txt) (strcase e-lyr))
              (prompt "\nLayer name has not been modified, name is identical")
              (princ)
           )
          ((= sse-txt "")
              (prompt "\nLayer name has not been modified, nil length string")
              (princ)
           )
          ((/= (wcmatch sse-txt "* *") nil)
              (prompt "\nLayer name has not been modified, name has space")
              (princ)
           )
         )
      )
      (command "erase" sstxt "")
    )
    (progn
      (if (= e-lyr "0")
        (progn
          (prompt "\nCannot rename layer 0")
          (princ)
        )
      )
    )
  )
  (princ)
)