Topic: string substitution

[ronjonp]

How would one convert (in lisp) a string like:

"O:\\J2\\Gilbert\\Park P\\ASI 11-10-05\\"

to

"O:-J2-Gilbert-Park P-ASI 11-10-05-"

basically replace all \\ with - or some other character..

I took a look @ vl-string-subst but apparently it only replaces the first occurence.

Thanks,

Ron

[MP]

Perhaps --

Code: [Select]

(defun Replace ( oldText newText text / i )
    (if (/= oldText newText)
        (while (setq i (vl-string-search oldText text))
            (setq text
                (vl-string-subst
                    newText
                    oldText
                    text
                    i
                )
            )
        )
    )
    text
)
(replace "\\" "-" OriginalString)

[T.Willey]

Look at vl-string-translate.

Tim

[Fatty]

Hi Ron

Is there you want?

(vl-string-translate "\\\"" "-" "O:\\J2\\Gilbert\\Park P\\ASI 11-10-05\\")

Thank you

Fatty

[ronjonp]

vl-string-translate was it! Damn thing was right in front of me .

Thanks all.

Ron

[Andrea]

there is anothe way to do it..


(setq L1 "O:\\J2\\Gilbert\\Park P\\ASI 11-10-05\\")
(while (vl-string-search "\\" L1)
(setq L1 (vl-string-subst "-" "\\" L1))
)


Just let you know..

[ronjonp]

Thanks Andrea.
I ended up using this:

Code: [Select]

(setq dwgpath (strcat (vl-string-right-trim "_" (substr (vl-string-translate "\\\"" "_" (getvar 'dwgprefix))4))"/"))
Ron

[CAB]

Thanks Andrea.
I ended up using this:

Code: [Select]

(setq dwgpath (strcat (vl-string-right-trim "_" (substr (vl-string-translate "\\\"" "_" (getvar 'dwgprefix))4))"/"))
Ron

Hey, Whats wrong with this?

Code: [Select]

(setq dwgpath (vl-string-trim "C:_" (vl-string-translate "\\\"" "_" (getvar 'dwgprefix))))

[CAB]

Never mind, 
If the wanted string begins or ends with C it too will be removed.
Back to the drawing board.

PS this did it.

Code: [Select]

(setq dwgpath (vl-string-trim "_" (vl-string-translate "\\\"" "_" (vl-string-trim "C:"(getvar 'dwgprefix)))))

[ronjonp]

Hey Cab,

I'm using this for backup purposes. The folder the drawing resides in get replicated on my C: drive in this manner:



The drive part I am trimming varies so C:\ won't work all the time:

Here is the code I'm using that runs when a drawing is saved:

Code: [Select]

(defun copydwg (/ destdir dwgdir *date* hour dwgpath bkupdir)
(if (not (wcmatch (getvar 'DWGNAME) "Drawing*.dwg"))
  (progn
   (defun *date* (/ curdate curtime)
     (setq   curdate (rtos (fix (getvar 'cdate)) 2 0)
      curtime (strcat (substr curdate 5 2) "-" (substr curdate 7 2) "-" (substr curdate 1 4)"/"))
   )
(defun hour (/ ctime stime)
  (setq ctime (rtos (rem (getvar 'cdate) 1) 2 6)
        stime (strcat (substr ctime 3 2)"/"))
)
(setq bkupdir "C:/AutoCAD-BAK/")
(setq dwgpath (strcat (vl-string-right-trim "_" (substr (vl-string-translate "\\\"" "_" (getvar 'dwgprefix))4))"/"))

;Makes C:\AutoCAD-BAK\curdate\curhour\curdwgpath if it doesn't already exist
   (if (not
       (vl-file-directory-p bkupdir))
       (vl-mkdir bkupdir)
   )
   (if (not
       (vl-file-directory-p (strcat bkupdir (*date*))))
       (vl-mkdir (strcat bkupdir (*date*)))
   )
   (if (not
       (vl-file-directory-p (strcat bkupdir (*date*)(hour))))
       (vl-mkdir (strcat bkupdir (*date*)(hour)))
   )
   (if (not
       (vl-file-directory-p (strcat bkupdir (*date*)(hour) dwgpath)))
       (vl-mkdir (strcat bkupdir (*date*)(hour) dwgpath))
   )

;For some reason the files get huge if not deleted then saved on top of
   (if (findfile (strcat bkupdir (*date*)(hour) dwgpath (getvar 'dwgname)))
     (vl-file-delete (strcat bkupdir (*date*)(hour) dwgpath (getvar 'dwgname)))
   )
   (setq destdir (strcat bkupdir (*date*)(hour) dwgpath (getvar 'dwgname))
         dwgdir  (strcat (getvar 'dwgprefix) (getvar 'dwgname))
   )
   (vl-file-copy dwgdir destdir T)
      )
    )
  )
Ron

[CAB]

Ron,
Looks like you have it buttoned up.
Very nice.

BTW here is another way to code this section.
Just a FYI.

Code: [Select]

;Makes C:\AutoCAD-BAK\curdate\curhour\curdwgpath if it doesn't already exist
      (or (vl-file-directory-p bkupdir)
          (vl-mkdir bkupdir)
      )
      (or (vl-file-directory-p (strcat bkupdir (*date*)))
          (vl-mkdir (strcat bkupdir (*date*)))
      )
      (or (vl-file-directory-p (strcat bkupdir (*date*) (hour)))
          (vl-mkdir (strcat bkupdir (*date*) (hour)))
      )
      (or (vl-file-directory-p (strcat bkupdir (*date*) (hour) dwgpath))
          (vl-mkdir (strcat bkupdir (*date*) (hour) dwgpath))
      )

[ronjonp]

Thanks for the tip CAB .

[CAB]

BTW
Very cool graphics.
What program did you use to create the animation?

[ronjonp]

http://www.techsmith.com/

Very cool little application. Well worth the money.

Ron