Topic: Attribute lisp Request?

[hudster]

Does anyone have a lisp that will move the attributes of all blocks onto the same layer that the block is inserted?

I making DWF copies of drawings and the attibutes are all showing on layer 0 as well as the layers the blocks are inserted on.

[Jürg Menzi]

Not tested:

Code: [Select]

(defun C:ChgAttLays ( / AcaDoc AttLst CurEnt CurLay CurObj CurSet FltLst)
 (vl-load-com)
 (setq FltLst '((0 . "INSERT") (66 . 1))
       AcaDoc (vla-get-ActiveDocument (vlax-get-acad-object))
 )
 (vla-StartUndoMark AcaDoc)
 (princ "\nSelect blocks or <all>...")
 (if (setq CurSet (cond ((ssget FltLst)) ((ssget "_X" FltLst))))
  (while (setq CurEnt (ssname CurSet 0))
   (setq CurObj (vlax-ename->vla-object CurEnt)
         CurLay (vla-get-Layer CurObj)
         AttLst (append
                 (vlax-invoke CurObj 'GetAttributes)
                 (vlax-invoke CurObj 'GetConstantAttributes)
                )
   )
   (foreach memb AttLst (vla-put-Layer memb CurLay))
   (vla-Update CurObj)
   (ssdel CurEnt CurSet)
  )
 )
 (vla-EndUndoMark AcaDoc)
 (princ)
)

[hudster]

Brilliant.

Cheers mate.

[Jürg Menzi]

Glad to help you...